basis/io/backend/windows/nt/nt.factor

   1 USING: alien alien.c-types arrays assocs combinators continuations
   2 destructors io io.backend io.ports io.timeouts io.backend.windows
   3 io.files.windows io.files.windows.nt io.files io.pathnames io.buffers
   4 io.streams.c io.streams.null libc kernel math namespaces sequences
   5 threads windows windows.errors windows.kernel32 strings splitting
   6 ascii system accessors locals classes.struct combinators.short-circuit ;
   7 IN: io.backend.windows.nt
   8
   9 ! Global variable with assoc mapping overlapped to threads
  10 SYMBOL: pending-overlapped
  11
  12 TUPLE: io-callback port thread ;
  13
  14 C: <io-callback> io-callback
  15
  16 : (make-overlapped) ( -- overlapped-ext )
  17     OVERLAPPED malloc-struct &free ;
  18
  19 : make-overlapped ( port -- overlapped-ext )
  20     [ (make-overlapped) ] dip
  21     handle>> ptr>> [ >>offset ] when* ;
  22
  23 M: winnt FileArgs-overlapped ( port -- overlapped )
  24     make-overlapped ;
  25
  26 : <completion-port> ( handle existing -- handle )
  27      f 1 CreateIoCompletionPort dup win32-error=0/f ;
  28
  29 SYMBOL: master-completion-port
  30
  31 : <master-completion-port> ( -- handle )
  32     INVALID_HANDLE_VALUE f <completion-port> ;
  33
  34 M: winnt add-completion ( win32-handle -- )
  35     handle>> master-completion-port get-global <completion-port> drop ;
  36
  37 : eof? ( error -- ? )
  38     { [ ERROR_HANDLE_EOF = ] [ ERROR_BROKEN_PIPE = ] } 1|| ;
  39
  40 : twiddle-thumbs ( overlapped port -- bytes-transferred )
  41     [
  42         drop
  43         [ >c-ptr pending-overlapped get-global set-at ] curry "I/O" suspend
  44         {
  45             { [ dup integer? ] [ ] }
  46             { [ dup array? ] [
  47                 first dup eof?
  48                 [ drop 0 ] [ n>win32-error-string throw ] if
  49             ] }
  50         } cond
  51     ] with-timeout ;
  52
  53 :: wait-for-overlapped ( us -- bytes-transferred overlapped error? )
  54     master-completion-port get-global
  55     0 <int> [ ! bytes
  56         f <void*> ! key
  57         f <void*> [ ! overlapped
  58             us [ 1000 /i ] [ INFINITE ] if* ! timeout
  59             GetQueuedCompletionStatus zero?
  60         ] keep
  61         *void* dup [ OVERLAPPED memory>struct ] when
  62     ] keep *int spin ;
  63
  64 : resume-callback ( result overlapped -- )
  65     >c-ptr pending-overlapped get-global delete-at* drop resume-with ;
  66
  67 : handle-overlapped ( us -- ? )
  68     wait-for-overlapped [
  69         [
  70             [ drop GetLastError 1array ] dip resume-callback t
  71         ] [ drop f ] if*
  72     ] [ resume-callback t ] if ;
  73
  74 M: win32-handle cancel-operation
  75     [ check-disposed ] [ handle>> CancelIo drop ] bi ;
  76
  77 M: winnt io-multiplex ( us -- )
  78     handle-overlapped [ 0 io-multiplex ] when ;
  79
  80 M: winnt init-io ( -- )
  81     <master-completion-port> master-completion-port set-global
  82     H{ } clone pending-overlapped set-global ;
  83
  84 ERROR: invalid-file-size n ;
  85
  86 : handle>file-size ( handle -- n )
  87     0 <ulonglong> [ GetFileSizeEx win32-error=0/f ] keep *ulonglong ;
  88
  89 ERROR: seek-before-start n ;
  90
  91 : set-seek-ptr ( n handle -- )
  92     [ dup 0 < [ seek-before-start ] when ] dip (>>ptr) ;
  93
  94 M: winnt seek-handle ( n seek-type handle -- )
  95     swap {
  96         { seek-absolute [ set-seek-ptr ] }
  97         { seek-relative [ [ ptr>> + ] keep set-seek-ptr ] }
  98         { seek-end [ [ handle>> handle>file-size + ] keep set-seek-ptr ] }
  99         [ bad-seek-type ]
 100     } case ;
 101
 102 : file-error? ( n -- eof? )
 103     zero? [
 104         GetLastError {
 105             { [ dup expected-io-error? ] [ drop f ] }
 106             { [ dup eof? ] [ drop t ] }
 107             [ n>win32-error-string throw ]
 108         } cond
 109     ] [ f ] if ;
 110
 111 : wait-for-file ( FileArgs n port -- n )
 112     swap file-error?
 113     [ 2drop 0 ] [ [ lpOverlapped>> ] dip twiddle-thumbs ] if ;
 114
 115 : update-file-ptr ( n port -- )
 116     handle>> dup ptr>> [ rot + >>ptr drop ] [ 2drop ] if* ;
 117
 118 : finish-write ( n port -- )
 119     [ update-file-ptr ] [ buffer>> buffer-consume ] 2bi ;
 120
 121 M: winnt (wait-to-write)
 122     [
 123         [ make-FileArgs dup setup-write WriteFile ]
 124         [ wait-for-file ]
 125         [ finish-write ]
 126         tri
 127     ] with-destructors ;
 128
 129 : finish-read ( n port -- )
 130     [ update-file-ptr ] [ buffer>> n>buffer ] 2bi ;
 131
 132 M: winnt (wait-to-read) ( port -- )
 133     [
 134         [ make-FileArgs dup setup-read ReadFile ]
 135         [ wait-for-file ]
 136         [ finish-read ]
 137         tri
 138     ] with-destructors ;
 139
 140 : console-app? ( -- ? ) GetConsoleWindow >boolean ;
 141
 142 M: winnt init-stdio
 143     console-app?
 144     [ init-c-stdio ]
 145     [ null-reader null-writer null-writer set-stdio ] if ;
 146
 147 winnt set-io-backend