basis/io/encodings/utf16/utf16.factor

   1 ! Copyright (C) 2006, 2008 Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: math kernel sequences sbufs vectors namespaces io.binary
   4 io.encodings combinators splitting io byte-arrays ;
   5 IN: io.encodings.utf16
   6
   7 SINGLETON: utf16be
   8
   9 SINGLETON: utf16le
  10
  11 SINGLETON: utf16
  12
  13 ERROR: missing-bom ;
  14
  15 <PRIVATE
  16
  17 ! UTF-16BE decoding
  18
  19 : append-nums ( byte ch -- ch )
  20     over [ 8 shift bitor ] [ 2drop replacement-char ] if ;
  21
  22 : double-be ( stream byte -- stream char )
  23     over stream-read1 swap append-nums ;
  24
  25 : quad-be ( stream byte -- stream char )
  26     double-be over stream-read1 [
  27         dup -2 shift BIN: 110111 number= [
  28             >r 2 shift r> BIN: 11 bitand bitor
  29             over stream-read1 swap append-nums HEX: 10000 +
  30         ] [ 2drop dup stream-read1 drop replacement-char ] if
  31     ] when* ;
  32
  33 : ignore ( stream -- stream char )
  34     dup stream-read1 drop replacement-char ;
  35
  36 : begin-utf16be ( stream byte -- stream char )
  37     dup -3 shift BIN: 11011 number= [
  38         dup BIN: 00000100 bitand zero?
  39         [ BIN: 11 bitand quad-be ]
  40         [ drop ignore ] if
  41     ] [ double-be ] if ;
  42
  43 M: utf16be decode-char
  44     drop dup stream-read1 dup [ begin-utf16be ] when nip ;
  45
  46 ! UTF-16LE decoding
  47
  48 : quad-le ( stream ch -- stream char )
  49     over stream-read1 swap 10 shift bitor
  50     over stream-read1 dup -2 shift BIN: 110111 = [
  51         BIN: 11 bitand append-nums HEX: 10000 +
  52     ] [ 2drop replacement-char ] if ;
  53
  54 : double-le ( stream byte1 byte2 -- stream char )
  55     dup -3 shift BIN: 11011 = [
  56         dup BIN: 100 bitand 0 number=
  57         [ BIN: 11 bitand 8 shift bitor quad-le ]
  58         [ 2drop replacement-char ] if
  59     ] [ append-nums ] if ;
  60
  61 : begin-utf16le ( stream byte -- stream char )
  62     over stream-read1 [ double-le ] [ drop replacement-char ] if* ;
  63
  64 M: utf16le decode-char
  65     drop dup stream-read1 dup [ begin-utf16le ] when nip ;
  66
  67 ! UTF-16LE/BE encoding
  68
  69 : encode-first ( char -- byte1 byte2 )
  70     -10 shift
  71     dup -8 shift BIN: 11011000 bitor
  72     swap HEX: FF bitand ;
  73
  74 : encode-second ( char -- byte3 byte4 )
  75     BIN: 1111111111 bitand
  76     dup -8 shift BIN: 11011100 bitor
  77     swap BIN: 11111111 bitand ;
  78
  79 : stream-write2 ( stream char1 char2 -- )
  80     rot [ stream-write1 ] curry bi@ ;
  81
  82 : char>utf16be ( stream char -- )
  83     dup HEX: FFFF > [
  84         HEX: 10000 -
  85         2dup encode-first stream-write2
  86         encode-second stream-write2
  87     ] [ h>b/b swap stream-write2 ] if ;
  88
  89 M: utf16be encode-char ( char stream encoding -- )
  90     drop swap char>utf16be ;
  91
  92 : char>utf16le ( char stream -- )
  93     dup HEX: FFFF > [
  94         HEX: 10000 -
  95         2dup encode-first swap stream-write2
  96         encode-second swap stream-write2
  97     ] [ h>b/b stream-write2 ] if ;
  98
  99 M: utf16le encode-char ( char stream encoding -- )
 100     drop swap char>utf16le ;
 101
 102 ! UTF-16
 103
 104 : bom-le B{ HEX: ff HEX: fe } ; inline
 105
 106 : bom-be B{ HEX: fe HEX: ff } ; inline
 107
 108 : start-utf16le? ( seq1 -- seq2 ? ) bom-le ?head ;
 109
 110 : start-utf16be? ( seq1 -- seq2 ? ) bom-be ?head ;
 111
 112 : bom>le/be ( bom -- le/be )
 113     dup bom-le sequence= [ drop utf16le ] [
 114         bom-be sequence= [ utf16be ] [ missing-bom ] if
 115     ] if ;
 116
 117 M: utf16 <decoder> ( stream utf16 -- decoder )
 118     drop 2 over stream-read bom>le/be <decoder> ;
 119
 120 M: utf16 <encoder> ( stream utf16 -- encoder )
 121     drop bom-le over stream-write utf16le <encoder> ;
 122
 123 PRIVATE>