basis/io/files/info/unix/unix.factor

   1 ! Copyright (C) 2008 Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel system math math.bitwise strings arrays
   4 sequences combinators combinators.short-circuit alien.c-types
   5 vocabs.loader calendar calendar.unix io.files.info
   6 io.files.types io.backend unix unix.stat unix.time unix.users
   7 unix.groups ;
   8 IN: io.files.info.unix
   9
  10 TUPLE: unix-file-system-info < file-system-info
  11 block-size preferred-block-size
  12 blocks blocks-free blocks-available
  13 files files-free files-available
  14 name-max flags id ;
  15
  16 HOOK: new-file-system-info os ( --  file-system-info )
  17
  18 M: unix new-file-system-info ( -- ) unix-file-system-info new ;
  19
  20 HOOK: file-system-statfs os ( path -- statfs )
  21
  22 M: unix file-system-statfs drop f ;
  23
  24 HOOK: file-system-statvfs os ( path -- statvfs )
  25
  26 M: unix file-system-statvfs drop f ;
  27
  28 HOOK: statfs>file-system-info os ( file-system-info statfs -- file-system-info' )
  29
  30 M: unix statfs>file-system-info drop ;
  31
  32 HOOK: statvfs>file-system-info os ( file-system-info statvfs -- file-system-info' )
  33
  34 M: unix statvfs>file-system-info drop ;
  35
  36 : file-system-calculations ( file-system-info -- file-system-info' )
  37     dup [ blocks-available>> ] [ block-size>> ] bi * >>available-space
  38     dup [ blocks-free>> ] [ block-size>> ] bi * >>free-space
  39     dup [ blocks>> ] [ block-size>> ] bi * >>total-space
  40     dup [ total-space>> ] [ free-space>> ] bi - >>used-space ;
  41
  42 M: unix file-system-info
  43     normalize-path
  44     [ new-file-system-info ] dip
  45     [ file-system-statfs statfs>file-system-info ]
  46     [ file-system-statvfs statvfs>file-system-info ] bi
  47     file-system-calculations ;
  48
  49 TUPLE: unix-file-info < file-info uid gid dev ino
  50 nlink rdev blocks blocksize ;
  51
  52 HOOK: new-file-info os ( -- file-info )
  53
  54 HOOK: stat>file-info os ( stat -- file-info )
  55
  56 HOOK: stat>type os ( stat -- file-info )
  57
  58 M: unix file-info ( path -- info )
  59     normalize-path file-status stat>file-info ;
  60
  61 M: unix link-info ( path -- info )
  62     normalize-path link-status stat>file-info ;
  63
  64 M: unix new-file-info ( -- class ) unix-file-info new ;
  65
  66 M: unix stat>file-info ( stat -- file-info )
  67     [ new-file-info ] dip
  68     {
  69         [ stat>type >>type ]
  70         [ stat-st_size >>size ]
  71         [ stat-st_mode >>permissions ]
  72         [ stat-st_ctimespec timespec>unix-time >>created ]
  73         [ stat-st_mtimespec timespec>unix-time >>modified ]
  74         [ stat-st_atimespec timespec>unix-time >>accessed ]
  75         [ stat-st_uid >>uid ]
  76         [ stat-st_gid >>gid ]
  77         [ stat-st_dev >>dev ]
  78         [ stat-st_ino >>ino ]
  79         [ stat-st_nlink >>nlink ]
  80         [ stat-st_rdev >>rdev ]
  81         [ stat-st_blocks >>blocks ]
  82         [ stat-st_blksize >>blocksize ]
  83     } cleave ;
  84
  85 : n>file-type ( n -- type )
  86     S_IFMT bitand {
  87         { S_IFREG [ +regular-file+ ] }
  88         { S_IFDIR [ +directory+ ] }
  89         { S_IFCHR [ +character-device+ ] }
  90         { S_IFBLK [ +block-device+ ] }
  91         { S_IFIFO [ +fifo+ ] }
  92         { S_IFLNK [ +symbolic-link+ ] }
  93         { S_IFSOCK [ +socket+ ] }
  94         [ drop +unknown+ ]
  95     } case ;
  96
  97 M: unix stat>type ( stat -- type )
  98     stat-st_mode n>file-type ;
  99
 100 <PRIVATE
 101
 102 : stat-mode ( path -- mode )
 103     normalize-path file-status stat-st_mode ;
 104
 105 : chmod-set-bit ( path mask ? -- )
 106     [ dup stat-mode ] 2dip
 107     [ bitor ] [ unmask ] if chmod io-error ;
 108
 109 GENERIC# file-mode? 1 ( obj mask -- ? )
 110
 111 M: integer file-mode? mask? ;
 112 M: string file-mode? [ stat-mode ] dip mask? ;
 113 M: file-info file-mode? [ permissions>> ] dip mask? ;
 114
 115 PRIVATE>
 116
 117 CONSTANT: UID           OCT: 0004000
 118 CONSTANT: GID           OCT: 0002000
 119 CONSTANT: STICKY        OCT: 0001000
 120 CONSTANT: USER-ALL      OCT: 0000700
 121 CONSTANT: USER-READ     OCT: 0000400
 122 CONSTANT: USER-WRITE    OCT: 0000200
 123 CONSTANT: USER-EXECUTE  OCT: 0000100
 124 CONSTANT: GROUP-ALL     OCT: 0000070
 125 CONSTANT: GROUP-READ    OCT: 0000040
 126 CONSTANT: GROUP-WRITE   OCT: 0000020
 127 CONSTANT: GROUP-EXECUTE OCT: 0000010
 128 CONSTANT: OTHER-ALL     OCT: 0000007
 129 CONSTANT: OTHER-READ    OCT: 0000004
 130 CONSTANT: OTHER-WRITE   OCT: 0000002
 131 CONSTANT: OTHER-EXECUTE OCT: 0000001
 132
 133 : uid? ( obj -- ? ) UID file-mode? ;
 134 : gid? ( obj -- ? ) GID file-mode? ;
 135 : sticky? ( obj -- ? ) STICKY file-mode? ;
 136 : user-read? ( obj -- ? ) USER-READ file-mode? ;
 137 : user-write? ( obj -- ? ) USER-WRITE file-mode? ;
 138 : user-execute? ( obj -- ? ) USER-EXECUTE file-mode? ;
 139 : group-read? ( obj -- ? ) GROUP-READ file-mode? ;
 140 : group-write? ( obj -- ? ) GROUP-WRITE file-mode? ;
 141 : group-execute? ( obj -- ? ) GROUP-EXECUTE file-mode? ;
 142 : other-read? ( obj -- ? ) OTHER-READ file-mode? ;
 143 : other-write? ( obj -- ? ) OTHER-WRITE file-mode? ;
 144 : other-execute? ( obj -- ? ) OTHER-EXECUTE file-mode? ;
 145
 146 : any-read? ( obj -- ? )
 147     { [ user-read? ] [ group-read? ] [ other-read? ] } 1|| ;
 148
 149 : any-write? ( obj -- ? )
 150     { [ user-write? ] [ group-write? ] [ other-write? ] } 1|| ;
 151
 152 : any-execute? ( obj -- ? )
 153     { [ user-execute? ] [ group-execute? ] [ other-execute? ] } 1|| ;
 154
 155 : set-uid ( path ? -- ) UID swap chmod-set-bit ;
 156 : set-gid ( path ? -- ) GID swap chmod-set-bit ;
 157 : set-sticky ( path ? -- ) STICKY swap chmod-set-bit ;
 158 : set-user-read ( path ? -- ) USER-READ swap chmod-set-bit ;
 159 : set-user-write ( path ? -- ) USER-WRITE swap chmod-set-bit ;
 160 : set-user-execute ( path ? -- ) USER-EXECUTE swap chmod-set-bit ;
 161 : set-group-read ( path ? -- ) GROUP-READ swap chmod-set-bit ;
 162 : set-group-write ( path ? -- ) GROUP-WRITE swap chmod-set-bit ;
 163 : set-group-execute ( path ? -- ) GROUP-EXECUTE swap chmod-set-bit ;
 164 : set-other-read ( path ? -- ) OTHER-READ swap chmod-set-bit ;
 165 : set-other-write ( path ? -- ) OTHER-WRITE swap chmod-set-bit ;
 166 : set-other-execute ( path ? -- ) OTHER-EXECUTE swap chmod-set-bit ;
 167
 168 : set-file-permissions ( path n -- )
 169     [ normalize-path ] dip chmod io-error ;
 170
 171 : file-permissions ( path -- n )
 172     normalize-path file-info permissions>> ;
 173
 174 <PRIVATE
 175
 176 : make-timeval-array ( array -- byte-array )
 177     [ [ "timeval" <c-object> ] unless* ] map concat ;
 178
 179 : timestamp>timeval ( timestamp -- timeval )
 180     unix-1970 time- duration>microseconds make-timeval ;
 181
 182 : timestamps>byte-array ( timestamps -- byte-array )
 183     [ dup [ timestamp>timeval ] when ] map make-timeval-array ;
 184
 185 PRIVATE>
 186
 187 : set-file-times ( path timestamps -- )
 188     #! set access, write
 189     [ normalize-path ] dip
 190     timestamps>byte-array utimes io-error ;
 191
 192 : set-file-access-time ( path timestamp -- )
 193     f 2array set-file-times ;
 194
 195 : set-file-modified-time ( path timestamp -- )
 196     f swap 2array set-file-times ;
 197
 198 : set-file-ids ( path uid gid -- )
 199     [ normalize-path ] 2dip
 200     [ [ -1 ] unless* ] bi@ chown io-error ;
 201
 202 GENERIC: set-file-user ( path string/id -- )
 203
 204 GENERIC: set-file-group ( path string/id -- )
 205
 206 M: integer set-file-user ( path uid -- )
 207     f set-file-ids ;
 208
 209 M: string set-file-user ( path string -- )
 210     user-id f set-file-ids ;
 211
 212 M: integer set-file-group ( path gid -- )
 213     f swap set-file-ids ;
 214
 215 M: string set-file-group ( path string -- )
 216     group-id
 217     f swap set-file-ids ;
 218
 219 : file-user-id ( path -- uid )
 220     normalize-path file-info uid>> ;
 221
 222 : file-user-name ( path -- string )
 223     file-user-id user-name ;
 224
 225 : file-group-id ( path -- gid )
 226     normalize-path file-info gid>> ;
 227
 228 : file-group-name ( path -- string )
 229     file-group-id group-name ;
 230
 231 : ch>file-type ( ch -- type )
 232     {
 233         { CHAR: b [ +block-device+ ] }
 234         { CHAR: c [ +character-device+ ] }
 235         { CHAR: d [ +directory+ ] }
 236         { CHAR: l [ +symbolic-link+ ] }
 237         { CHAR: s [ +socket+ ] }
 238         { CHAR: p [ +fifo+ ] }
 239         { CHAR: - [ +regular-file+ ] }
 240         [ drop +unknown+ ]
 241     } case ;
 242
 243 : file-type>ch ( type -- ch )
 244     {
 245         { +block-device+ [ CHAR: b ] }
 246         { +character-device+ [ CHAR: c ] }
 247         { +directory+ [ CHAR: d ] }
 248         { +symbolic-link+ [ CHAR: l ] }
 249         { +socket+ [ CHAR: s ] }
 250         { +fifo+ [ CHAR: p ] }
 251         { +regular-file+ [ CHAR: - ] }
 252         [ drop CHAR: - ]
 253     } case ;
 254
 255 <PRIVATE
 256
 257 : file-type>executable ( directory-entry -- string )
 258     name>> any-execute? "*" "" ? ;
 259
 260 PRIVATE>
 261
 262 : file-type>trailing ( directory-entry -- string )
 263     dup type>>
 264     {
 265         { +directory+ [ drop "/" ] }
 266         { +symbolic-link+ [ drop "@" ] }
 267         { +fifo+ [ drop "|" ] }
 268         { +socket+ [ drop "=" ] }
 269         { +whiteout+ [ drop "%" ] }
 270         { +unknown+ [ file-type>executable ] }
 271         { +regular-file+ [ file-type>executable ] }
 272         [ drop file-type>executable ]
 273     } case ;