basis/io/files/info/windows/windows.factor

   1 ! Copyright (C) 2008 Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: byte-arrays math io.backend io.files.info
   4 io.files.windows io.files.windows.nt kernel windows.kernel32
   5 windows.time windows accessors alien.c-types combinators
   6 generalizations system alien.strings io.encodings.utf16n
   7 sequences splitting windows.errors fry continuations destructors
   8 calendar ascii combinators.short-circuit locals classes.struct ;
   9 IN: io.files.info.windows
  10
  11 :: round-up-to ( n multiple -- n' )
  12     n multiple rem [
  13         n
  14     ] [
  15         multiple swap - n +
  16     ] if-zero ;
  17
  18 TUPLE: windows-file-info < file-info attributes ;
  19
  20 : get-compressed-file-size ( path -- n )
  21     "DWORD" <c-object> [ GetCompressedFileSize ] keep
  22     over INVALID_FILE_SIZE = [
  23         win32-error-string throw
  24     ] [
  25         *uint >64bit
  26     ] if ;
  27
  28 : set-windows-size-on-disk ( file-info path -- file-info )
  29     over attributes>> +compressed+ swap member? [
  30         get-compressed-file-size
  31     ] [
  32         drop dup size>> 4096 round-up-to
  33     ] if >>size-on-disk ;
  34
  35 : WIN32_FIND_DATA>file-info ( WIN32_FIND_DATA -- file-info )
  36     [ \ windows-file-info new ] dip
  37     {
  38         [ WIN32_FIND_DATA-dwFileAttributes win32-file-type >>type ]
  39         [ WIN32_FIND_DATA-dwFileAttributes win32-file-attributes >>attributes ]
  40         [
  41             [ WIN32_FIND_DATA-nFileSizeLow ]
  42             [ WIN32_FIND_DATA-nFileSizeHigh ] bi >64bit >>size
  43         ]
  44         [ WIN32_FIND_DATA-dwFileAttributes >>permissions ]
  45         [ WIN32_FIND_DATA-ftCreationTime FILETIME>timestamp >>created ]
  46         [ WIN32_FIND_DATA-ftLastWriteTime FILETIME>timestamp >>modified ]
  47         [ WIN32_FIND_DATA-ftLastAccessTime FILETIME>timestamp >>accessed ]
  48     } cleave ;
  49
  50 : find-first-file-stat ( path -- WIN32_FIND_DATA )
  51     "WIN32_FIND_DATA" <c-object> [
  52         FindFirstFile
  53         [ INVALID_HANDLE_VALUE = [ win32-error ] when ] keep
  54         FindClose win32-error=0/f
  55     ] keep ;
  56
  57 : BY_HANDLE_FILE_INFORMATION>file-info ( HANDLE_FILE_INFORMATION -- file-info )
  58     [ \ windows-file-info new ] dip
  59     {
  60         [ dwFileAttributes>> win32-file-type >>type ]
  61         [ dwFileAttributes>> win32-file-attributes >>attributes ]
  62         [
  63             [ nFileSizeLow>> ]
  64             [ nFileSizeHigh>> ] bi >64bit >>size
  65         ]
  66         [ dwFileAttributes>> >>permissions ]
  67         [ ftCreationTime>> FILETIME>timestamp >>created ]
  68         [ ftLastWriteTime>> FILETIME>timestamp >>modified ]
  69         [ ftLastAccessTime>> FILETIME>timestamp >>accessed ]
  70         ! [ nNumberOfLinks>> ]
  71         ! [
  72           ! [ nFileIndexLow>> ]
  73           ! [ nFileIndexHigh>> ] bi >64bit
  74         ! ]
  75     } cleave ;
  76
  77 : get-file-information ( handle -- BY_HANDLE_FILE_INFORMATION )
  78     [
  79         BY_HANDLE_FILE_INFORMATION <struct>
  80         [ GetFileInformationByHandle win32-error=0/f ] keep
  81     ] keep CloseHandle win32-error=0/f ;
  82
  83 : get-file-information-stat ( path -- BY_HANDLE_FILE_INFORMATION )
  84     dup
  85     GENERIC_READ FILE_SHARE_READ f
  86     OPEN_EXISTING FILE_FLAG_BACKUP_SEMANTICS f
  87     CreateFileW dup INVALID_HANDLE_VALUE = [
  88         drop find-first-file-stat WIN32_FIND_DATA>file-info
  89     ] [
  90         nip
  91         get-file-information BY_HANDLE_FILE_INFORMATION>file-info
  92     ] if ;
  93
  94 M: windows file-info ( path -- info )
  95     normalize-path
  96     [ get-file-information-stat ]
  97     [ set-windows-size-on-disk ] bi ;
  98
  99 M: windows link-info ( path -- info )
 100     file-info ;
 101
 102 : volume-information ( normalized-path -- volume-name volume-serial max-component flags type )
 103     MAX_PATH 1 + [ <byte-array> ] keep
 104     "DWORD" <c-object>
 105     "DWORD" <c-object>
 106     "DWORD" <c-object>
 107     MAX_PATH 1 + [ <byte-array> ] keep
 108     [ GetVolumeInformation win32-error=0/f ] 7 nkeep
 109     drop 5 nrot drop
 110     [ utf16n alien>string ] 4 ndip
 111     utf16n alien>string ;
 112
 113 : file-system-space ( normalized-path -- available-space total-space free-space )
 114     "ULARGE_INTEGER" <c-object>
 115     "ULARGE_INTEGER" <c-object>
 116     "ULARGE_INTEGER" <c-object>
 117     [ GetDiskFreeSpaceEx win32-error=0/f ] 3keep ;
 118
 119 : calculate-file-system-info ( file-system-info -- file-system-info' )
 120     [ dup [ total-space>> ] [ free-space>> ] bi - >>used-space drop ] keep ;
 121
 122 TUPLE: win32-file-system-info < file-system-info max-component flags device-serial ;
 123
 124 ERROR: not-absolute-path ;
 125
 126 : root-directory ( string -- string' )
 127     unicode-prefix ?head drop
 128     dup {
 129         [ length 2 >= ]
 130         [ second CHAR: : = ]
 131         [ first Letter? ]
 132     } 1&& [ 2 head "\\" append ] [ not-absolute-path ] if ;
 133
 134 M: winnt file-system-info ( path -- file-system-info )
 135     normalize-path root-directory
 136     dup [ volume-information ] [ file-system-space ] bi
 137     \ win32-file-system-info new
 138         swap *ulonglong >>free-space
 139         swap *ulonglong >>total-space
 140         swap *ulonglong >>available-space
 141         swap >>type
 142         swap *uint >>flags
 143         swap *uint >>max-component
 144         swap *uint >>device-serial
 145         swap >>device-name
 146         swap >>mount-point
 147     calculate-file-system-info ;
 148
 149 : volume>paths ( string -- array )
 150     16384 "ushort" <c-array> tuck dup length
 151     0 <uint> dup [ GetVolumePathNamesForVolumeName 0 = ] dip swap [
 152         win32-error-string throw
 153     ] [
 154         *uint "ushort" heap-size * head
 155         utf16n alien>string CHAR: \0 split
 156     ] if ;
 157
 158 : find-first-volume ( -- string handle )
 159     MAX_PATH 1 + [ <byte-array> ] keep
 160     dupd
 161     FindFirstVolume dup win32-error=0/f
 162     [ utf16n alien>string ] dip ;
 163
 164 : find-next-volume ( handle -- string/f )
 165     MAX_PATH 1 + [ <byte-array> tuck ] keep
 166     FindNextVolume 0 = [
 167         GetLastError ERROR_NO_MORE_FILES =
 168         [ drop f ] [ win32-error-string throw ] if
 169     ] [
 170         utf16n alien>string
 171     ] if ;
 172
 173 : find-volumes ( -- array )
 174     find-first-volume
 175     [
 176         '[
 177             [ _ find-next-volume dup ] [ ] produce nip
 178             swap prefix
 179         ]
 180     ] [ '[ _ FindVolumeClose win32-error=0/f ] ] bi [ ] cleanup ;
 181
 182 M: winnt file-systems ( -- array )
 183     find-volumes [ volume>paths ] map
 184     concat [
 185         [ file-system-info ]
 186         [ drop \ file-system-info new swap >>mount-point ] recover
 187     ] map ;
 188
 189 : file-times ( path -- timestamp timestamp timestamp )
 190     [
 191         normalize-path open-read &dispose handle>>
 192         FILETIME <struct>
 193         FILETIME <struct>
 194         FILETIME <struct>
 195         [ GetFileTime win32-error=0/f ] 3keep
 196         [ FILETIME>timestamp >local-time ] tri@
 197     ] with-destructors ;
 198
 199 : set-file-times ( path timestamp/f timestamp/f timestamp/f -- )
 200     #! timestamp order: creation access write
 201     [
 202         [
 203             normalize-path open-existing &dispose handle>>
 204         ] 3dip (set-file-times)
 205     ] with-destructors ;
 206
 207 : set-file-create-time ( path timestamp -- )
 208     f f set-file-times ;
 209
 210 : set-file-access-time ( path timestamp -- )
 211     [ f ] dip f set-file-times ;
 212
 213 : set-file-write-time ( path timestamp -- )
 214     [ f f ] dip set-file-times ;