basis/io/mmap/mmap.factor

   1 ! Copyright (C) 2007, 2008 Doug Coleman, Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: continuations destructors io.files io.files.info
   4 io.backend kernel quotations system alien alien.accessors
   5 accessors vocabs.loader combinators alien.c-types
   6 math ;
   7 IN: io.mmap
   8
   9 TUPLE: mapped-file address handle length disposed ;
  10
  11 HOOK: (mapped-file-reader) os ( path length -- address handle )
  12 HOOK: (mapped-file-r/w) os ( path length -- address handle )
  13
  14 ERROR: bad-mmap-size path size ;
  15
  16 <PRIVATE
  17
  18 : prepare-mapped-file ( path -- path' n )
  19     [ normalize-path ] [ file-info size>> ] bi
  20     dup 0 <= [ bad-mmap-size ] when ;
  21
  22 PRIVATE>
  23
  24 : <mapped-file-reader> ( path -- mmap )
  25     prepare-mapped-file
  26     [ (mapped-file-reader) ] keep
  27     f mapped-file boa ;
  28
  29 : <mapped-file> ( path -- mmap )
  30     prepare-mapped-file
  31     [ (mapped-file-r/w) ] keep
  32     f mapped-file boa ;
  33
  34 HOOK: close-mapped-file io-backend ( mmap -- )
  35
  36 M: mapped-file dispose* ( mmap -- ) close-mapped-file ;
  37
  38 : with-mapped-file ( path quot -- )
  39     [ <mapped-file> ] dip with-disposal ; inline
  40
  41 : with-mapped-file-reader ( path quot -- )
  42     [ <mapped-file-reader> ] dip with-disposal ; inline
  43
  44 {
  45     { [ os unix? ] [ "io.mmap.unix" require ] }
  46     { [ os winnt? ] [ "io.mmap.windows" require ] }
  47 } cond