basis/io/servers/connection/connection.factor

   1 ! Copyright (C) 2003, 2010 Slava Pestov, Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays calendar combinators
   4 combinators.short-circuit concurrency.combinators
   5 concurrency.count-downs concurrency.flags
   6 concurrency.semaphores continuations debugger destructors fry
   7 io io.sockets io.sockets.secure io.streams.duplex io.styles
   8 io.timeouts kernel logging make math math.parser namespaces
   9 present prettyprint random sequences sets strings threads ;
  10 FROM: namespaces => set ;
  11 IN: io.servers.connection
  12
  13 TUPLE: threaded-server < identity-tuple
  14 name
  15 log-level
  16 secure
  17 insecure
  18 secure-config
  19 servers
  20 max-connections
  21 semaphore
  22 timeout
  23 encoding
  24 handler
  25 server-stopped ;
  26
  27 SYMBOL: running-servers
  28 running-servers [ HS{ } clone ] initialize
  29
  30 ERROR: server-already-running threaded-server ;
  31
  32 ERROR: server-not-running threaded-server ;
  33
  34 <PRIVATE
  35
  36 : must-be-running ( threaded-server -- threaded-server )
  37     dup running-servers get in? [ server-not-running ] unless ;
  38
  39 : must-not-be-running ( threaded-server -- threaded-server )
  40     dup running-servers get in? [ server-already-running ] when ;
  41
  42 : add-running-server ( threaded-server -- )
  43     must-not-be-running
  44     running-servers get adjoin ;
  45
  46 : remove-running-server ( threaded-server -- )
  47     must-be-running
  48     running-servers get delete ;
  49
  50 PRIVATE>
  51
  52 : local-server ( port -- addrspec ) "localhost" swap <inet> ;
  53
  54 : internet-server ( port -- addrspec ) f swap <inet> ;
  55
  56 : new-threaded-server ( encoding class -- threaded-server )
  57     new
  58         "server" >>name
  59         DEBUG >>log-level
  60         <secure-config> >>secure-config
  61         1 minutes >>timeout
  62         [ "No handler quotation" throw ] >>handler
  63         swap >>encoding ;
  64
  65 : <threaded-server> ( encoding -- threaded-server )
  66     threaded-server new-threaded-server ;
  67
  68 GENERIC: handle-client* ( threaded-server -- )
  69
  70 <PRIVATE
  71
  72 GENERIC: (>insecure) ( obj -- obj )
  73
  74 M: inet (>insecure) ;
  75 M: local (>insecure) ;
  76 M: integer (>insecure) internet-server ;
  77 M: string (>insecure) internet-server ;
  78 M: array (>insecure) [ (>insecure) ] map ;
  79 M: f (>insecure) ;
  80
  81 : >insecure ( obj -- seq )
  82     (>insecure) dup sequence? [ 1array ] unless ;
  83
  84 : >secure ( addrspec -- addrspec' )
  85     >insecure
  86     [ dup { [ secure? ] [ not ] } 1|| [ <secure> ] unless ] map ;
  87
  88 : listen-on ( threaded-server -- addrspecs )
  89     [ secure>> >secure ] [ insecure>> >insecure ] bi append
  90     [ resolve-host ] map concat ;
  91
  92 : accepted-connection ( remote local -- )
  93     [
  94         [ "remote: " % present % ", " % ]
  95         [ "local: " % present % ]
  96         bi*
  97     ] "" make
  98     \ accepted-connection NOTICE log-message ;
  99
 100 : log-connection ( remote local -- )
 101     [ accepted-connection ]
 102     [ [ remote-address set ] [ local-address set ] bi* ]
 103     2bi ;
 104
 105 M: threaded-server handle-client* handler>> call( -- ) ;
 106
 107 : handle-client ( client remote local -- )
 108     '[
 109         _ _ log-connection
 110         threaded-server get
 111         [ timeout>> timeouts ] [ handle-client* ] bi
 112     ] with-stream ;
 113
 114 \ handle-client NOTICE add-error-logging
 115
 116 : client-thread-name ( addrspec -- string )
 117     [ threaded-server get name>> ] dip
 118     unparse-short " connection from " glue ;
 119
 120 : (accept-connection) ( server -- )
 121     [ accept ] [ addr>> ] bi
 122     [ '[ _ _ _ handle-client ] ]
 123     [ drop client-thread-name ] 2bi
 124     spawn drop ;
 125
 126 : accept-connection ( server -- )
 127     threaded-server get semaphore>>
 128     [ [ (accept-connection) ] with-semaphore ]
 129     [ (accept-connection) ]
 130     if* ;
 131
 132 : accept-loop ( server -- )
 133     [ accept-connection ] [ accept-loop ] bi ;
 134
 135 : start-accept-loop ( server -- ) accept-loop ;
 136
 137 \ start-accept-loop NOTICE add-error-logging
 138
 139 : init-server ( threaded-server -- threaded-server )
 140     <flag> >>server-stopped
 141     dup semaphore>> [
 142         dup max-connections>> [
 143             <semaphore> >>semaphore
 144         ] when*
 145     ] unless ;
 146
 147 ERROR: no-ports-configured threaded-server ;
 148
 149 : (make-servers) ( theaded-server addrspecs -- servers )
 150     swap encoding>>
 151     '[ [ _ <server> |dispose ] map ] with-destructors ;
 152
 153 : set-servers ( threaded-server -- threaded-server )
 154     dup dup listen-on [ no-ports-configured ] [ (make-servers) ] if-empty
 155     >>servers ;
 156
 157 : server-thread-name ( threaded-server addrspec -- string )
 158     [ name>> ] [ addr>> present ] bi* " server on " glue ;
 159
 160 : (start-server) ( threaded-server -- )
 161     init-server
 162     dup threaded-server [
 163         [ ] [ name>> ] bi
 164         [
 165             set-servers
 166             dup add-running-server
 167             dup servers>>
 168             [
 169                 [ nip '[ _ [ start-accept-loop ] with-disposal ] ]
 170                 [ server-thread-name ] 2bi spawn drop
 171             ] with each
 172         ] with-logging
 173     ] with-variable ;
 174
 175 PRIVATE>
 176
 177 : start-server ( threaded-server -- threaded-server )
 178     #! Only create a secure-context if we want to listen on
 179     #! a secure port, otherwise start-server won't work at
 180     #! all if SSL is not available.
 181     dup dup secure>> [
 182         dup secure-config>> [
 183             (start-server)
 184         ] with-secure-context
 185     ] [
 186         (start-server)
 187     ] if ;
 188
 189 : server-running? ( threaded-server -- ? )
 190     server-stopped>> [ value>> not ] [ f ] if* ;
 191
 192 : stop-server ( threaded-server -- )
 193     dup server-running? [
 194         [ [ f ] change-servers drop dispose-each ]
 195         [ remove-running-server ]
 196         [ server-stopped>> raise-flag ] tri
 197     ] [
 198         drop
 199     ] if ;
 200
 201 : stop-this-server ( -- )
 202     threaded-server get stop-server ;
 203
 204 : wait-for-server ( threaded-server -- )
 205     server-stopped>> wait-for-flag ;
 206
 207 : with-threaded-server ( threaded-server quot -- )
 208     over
 209     '[
 210         [ _ start-server threaded-server _ with-variable ]
 211         [ _ stop-server ]
 212         [ ] cleanup
 213     ] call ; inline
 214
 215 <PRIVATE
 216
 217 : first-port ( quot -- n/f )
 218     [ threaded-server get servers>> ] dip
 219     filter [ f ] [ first addr>> port>> ] if-empty ; inline
 220
 221 PRIVATE>
 222
 223 : secure-port ( -- n/f ) [ addr>> secure? ] first-port ;
 224
 225 : insecure-port ( -- n/f ) [ addr>> secure? not ] first-port ;
 226
 227 : server. ( threaded-server -- )
 228     [ [ "=== " write name>> ] [ ] bi write-object nl ]
 229     [ servers>> [ addr>> present print ] each ] bi ;
 230
 231 : all-servers ( -- sequence )
 232     running-servers get-global members ;
 233
 234 : servers. ( -- )
 235     all-servers [ server. ] each ;
 236
 237 : stop-all-servers ( -- )
 238     all-servers [ stop-server ] each ;