basis/io/servers/servers.factor

   1 ! Copyright (C) 2003, 2010 Slava Pestov, Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays calendar combinators
   4 combinators.short-circuit concurrency.combinators
   5 concurrency.count-downs concurrency.flags
   6 concurrency.semaphores continuations debugger destructors fry
   7 io io.sockets io.sockets.secure io.streams.duplex io.styles
   8 io.timeouts kernel logging make math math.parser namespaces
   9 present prettyprint random sequences sets strings threads ;
  10 FROM: namespaces => set ;
  11 IN: io.servers
  12
  13 TUPLE: threaded-server < identity-tuple
  14 name
  15 log-level
  16 secure
  17 insecure
  18 secure-config
  19 servers
  20 max-connections
  21 semaphore
  22 timeout
  23 encoding
  24 handler
  25 server-stopped
  26 secure-context ;
  27
  28 SYMBOL: running-servers
  29 running-servers [ HS{ } clone ] initialize
  30
  31 ERROR: server-already-running threaded-server ;
  32
  33 ERROR: server-not-running threaded-server ;
  34
  35 <PRIVATE
  36
  37 : must-be-running ( threaded-server -- threaded-server )
  38     dup running-servers get in? [ server-not-running ] unless ;
  39
  40 : must-not-be-running ( threaded-server -- threaded-server )
  41     dup running-servers get in? [ server-already-running ] when ;
  42
  43 : add-running-server ( threaded-server -- )
  44     must-not-be-running
  45     running-servers get adjoin ;
  46
  47 : remove-running-server ( threaded-server -- )
  48     must-be-running
  49     running-servers get delete ;
  50
  51 PRIVATE>
  52
  53 : local-server ( port -- addrspec ) "localhost" swap <inet> ;
  54
  55 : internet-server ( port -- addrspec ) f swap <inet> ;
  56
  57 : new-threaded-server ( encoding class -- threaded-server )
  58     new
  59         "server" >>name
  60         DEBUG >>log-level
  61         <secure-config> >>secure-config
  62         1 minutes >>timeout
  63         [ "No handler quotation" throw ] >>handler
  64         swap >>encoding ;
  65
  66 : <threaded-server> ( encoding -- threaded-server )
  67     threaded-server new-threaded-server ;
  68
  69 GENERIC: handle-client* ( threaded-server -- )
  70
  71 <PRIVATE
  72
  73 GENERIC: >insecure ( obj -- obj )
  74
  75 M: inet >insecure 1array ;
  76 M: inet4 >insecure 1array ;
  77 M: inet6 >insecure 1array ;
  78 M: local >insecure 1array ;
  79 M: integer >insecure internet-server 1array ;
  80 M: string >insecure internet-server 1array ;
  81 M: array >insecure [ >insecure ] map ;
  82 M: f >insecure ;
  83
  84 : >secure ( addrspec -- addrspec' )
  85     >insecure
  86     [ dup secure? [ <secure> ] unless ] map ;
  87
  88 : listen-on ( threaded-server -- addrspecs )
  89     [ secure>> >secure ] [ insecure>> >insecure ] bi append
  90     [ resolve-host ] map concat ;
  91
  92 : accepted-connection ( remote local -- )
  93     [
  94         [ "remote: " % present % ", " % ]
  95         [ "local: " % present % ]
  96         bi*
  97     ] "" make
  98     \ accepted-connection NOTICE log-message ;
  99
 100 : log-connection ( remote local -- )
 101     [ accepted-connection ]
 102     [ [ remote-address set ] [ local-address set ] bi* ]
 103     2bi ;
 104
 105 M: threaded-server handle-client* handler>> call( -- ) ;
 106
 107 : handle-client ( client remote local -- )
 108     '[
 109         _ _ log-connection
 110         threaded-server get
 111         [ timeout>> timeouts ] [ handle-client* ] bi
 112     ] with-stream ;
 113
 114 \ handle-client NOTICE add-error-logging
 115
 116 : client-thread-name ( addrspec -- string )
 117     [ threaded-server get name>> ] dip
 118     unparse-short " connection from " glue ;
 119
 120 : (accept-connection) ( server -- )
 121     [ accept ] [ addr>> ] bi
 122     [ '[ _ _ _ handle-client ] ]
 123     [ drop client-thread-name ] 2bi
 124     spawn drop ;
 125
 126 : accept-connection ( server -- )
 127     threaded-server get semaphore>>
 128     [ [ (accept-connection) ] with-semaphore ]
 129     [ (accept-connection) ]
 130     if* ;
 131
 132 : with-existing-secure-context ( threaded-server quot -- )
 133     [ secure-context>> secure-context ] dip with-variable ; inline
 134
 135 : accept-loop ( server -- )
 136     [ accept-connection ] [ accept-loop ] bi ;
 137
 138 : start-accept-loop ( threaded-server server -- )
 139     '[ _ accept-loop ] with-existing-secure-context ;
 140
 141 \ start-accept-loop NOTICE add-error-logging
 142
 143 : create-secure-context ( threaded-server -- threaded-server )
 144     dup secure>> [
 145         dup secure-config>> <secure-context> >>secure-context
 146     ] when ;
 147
 148 : init-server ( threaded-server -- threaded-server )
 149     create-secure-context
 150     <flag> >>server-stopped
 151     dup semaphore>> [
 152         dup max-connections>> [
 153             <semaphore> >>semaphore
 154         ] when*
 155     ] unless ;
 156
 157 ERROR: no-ports-configured threaded-server ;
 158
 159 : (make-servers) ( theaded-server addrspecs -- servers )
 160     swap encoding>>
 161     '[ [ _ <server> |dispose ] map ] with-destructors ;
 162
 163 : set-servers ( threaded-server -- threaded-server )
 164     dup [
 165         dup dup listen-on [ no-ports-configured ] [ (make-servers) ] if-empty
 166         >>servers
 167     ] with-existing-secure-context ;
 168
 169 : server-thread-name ( threaded-server addrspec -- string )
 170     [ name>> ] [ addr>> present ] bi* " server on " glue ;
 171
 172 PRIVATE>
 173
 174 : start-server ( threaded-server -- threaded-server )
 175     init-server
 176     [
 177         dup threaded-server [
 178             [ ] [ name>> ] bi
 179             [
 180                 set-servers
 181                 dup add-running-server
 182                 dup servers>>
 183                 [
 184                     [ '[ _ _ [ start-accept-loop ] with-disposal ] ]
 185                     [ server-thread-name ] 2bi spawn drop
 186                 ] with each
 187             ] with-logging
 188         ] with-variable
 189     ] keep ;
 190
 191 : server-running? ( threaded-server -- ? )
 192     server-stopped>> [ value>> not ] [ f ] if* ;
 193
 194 : stop-server ( threaded-server -- )
 195     dup server-running? [
 196         [ remove-running-server ]
 197         [
 198             [
 199                 [ secure-context>> [ &dispose drop ] when* ]
 200                 [ [ f ] change-servers drop dispose-each ] bi
 201             ] with-destructors
 202         ]
 203         [ server-stopped>> raise-flag ] tri
 204     ] [
 205         drop
 206     ] if ;
 207
 208 : stop-this-server ( -- )
 209     threaded-server get stop-server ;
 210
 211 : wait-for-server ( threaded-server -- )
 212     server-stopped>> wait-for-flag ;
 213
 214 : with-threaded-server ( threaded-server quot -- )
 215     [ start-server ] dip over
 216     '[
 217         [ _ threaded-server _ with-variable ]
 218         [ _ stop-server ]
 219         [ ] cleanup
 220     ] call ; inline
 221
 222 <PRIVATE
 223
 224 : first-port ( quot -- n/f )
 225     [ threaded-server get servers>> ] dip
 226     filter [ f ] [ first addr>> port>> ] if-empty ; inline
 227
 228 PRIVATE>
 229
 230 : secure-port ( -- n/f ) [ addr>> secure? ] first-port ;
 231
 232 : insecure-port ( -- n/f ) [ addr>> secure? not ] first-port ;
 233
 234 : secure-addr ( -- inet )
 235     threaded-server get servers>> [ addr>> secure? ] filter random ;
 236
 237 : insecure-addr ( -- inet )
 238     threaded-server get servers>> [ addr>> secure? not ] filter random addr>> ;
 239
 240 : server. ( threaded-server -- )
 241     [ [ "=== " write name>> ] [ ] bi write-object nl ]
 242     [ servers>> [ addr>> present print ] each ] bi ;
 243
 244 : all-servers ( -- sequence )
 245     running-servers get-global members ;
 246
 247 : get-servers-named ( string -- sequence )
 248     [ all-servers ] dip '[ name>> _ = ] filter ;
 249
 250 : servers. ( -- )
 251     all-servers [ server. ] each ;
 252
 253 : stop-all-servers ( -- )
 254     all-servers [ stop-server ] each ;