basis/io/servers/servers.factor

   1 ! Copyright (C) 2003, 2010 Slava Pestov, Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays calendar combinators
   4 combinators.short-circuit concurrency.combinators
   5 concurrency.count-downs concurrency.flags
   6 concurrency.semaphores continuations debugger destructors fry
   7 io io.sockets io.sockets.secure io.streams.duplex io.styles
   8 io.timeouts kernel logging make math math.parser namespaces
   9 present prettyprint random sequences sets strings threads ;
  10 FROM: namespaces => set ;
  11 IN: io.servers
  12
  13 TUPLE: threaded-server < identity-tuple
  14 name
  15 log-level
  16 secure
  17 insecure
  18 secure-config
  19 servers
  20 max-connections
  21 semaphore
  22 timeout
  23 encoding
  24 handler
  25 server-stopped
  26 secure-context ;
  27
  28 SYMBOL: running-servers
  29 running-servers [ HS{ } clone ] initialize
  30
  31 ERROR: server-already-running threaded-server ;
  32
  33 ERROR: server-not-running threaded-server ;
  34
  35 <PRIVATE
  36
  37 : must-be-running ( threaded-server -- threaded-server )
  38     dup running-servers get in? [ server-not-running ] unless ;
  39
  40 : must-not-be-running ( threaded-server -- threaded-server )
  41     dup running-servers get in? [ server-already-running ] when ;
  42
  43 : add-running-server ( threaded-server -- )
  44     must-not-be-running
  45     running-servers get adjoin ;
  46
  47 : remove-running-server ( threaded-server -- )
  48     must-be-running
  49     running-servers get delete ;
  50
  51 PRIVATE>
  52
  53 : local-server ( port -- addrspec ) "localhost" swap <inet> ;
  54
  55 : internet-server ( port -- addrspec ) f swap <inet> ;
  56
  57 : new-threaded-server ( encoding class -- threaded-server )
  58     new
  59         "server" >>name
  60         DEBUG >>log-level
  61         <secure-config> >>secure-config
  62         1 minutes >>timeout
  63         [ "No handler quotation" throw ] >>handler
  64         swap >>encoding ;
  65
  66 : <threaded-server> ( encoding -- threaded-server )
  67     threaded-server new-threaded-server ;
  68
  69 GENERIC: handle-client* ( threaded-server -- )
  70
  71 <PRIVATE
  72
  73 GENERIC: >insecure ( obj -- obj )
  74
  75 M: inet >insecure 1array ;
  76 M: inet4 >insecure 1array ;
  77 M: inet6 >insecure 1array ;
  78 M: local >insecure 1array ;
  79 M: integer >insecure internet-server 1array ;
  80 M: string >insecure internet-server 1array ;
  81 M: array >insecure [ >insecure ] map ;
  82 M: f >insecure ;
  83
  84 : >secure ( addrspec -- addrspec' )
  85     >insecure
  86     [ dup secure? [ <secure> ] unless ] map ;
  87
  88 : listen-on ( threaded-server -- addrspecs )
  89     [ secure>> >secure ] [ insecure>> >insecure ] bi append
  90     [ resolve-host ] map concat ;
  91
  92 : accepted-connection ( remote local -- )
  93     [
  94         [ "remote: " % present % ", " % ]
  95         [ "local: " % present % ]
  96         bi*
  97     ] "" make
  98     \ accepted-connection NOTICE log-message ;
  99
 100 : log-connection ( remote local -- )
 101     [ accepted-connection ]
 102     [ [ remote-address set ] [ local-address set ] bi* ]
 103     2bi ;
 104
 105 M: threaded-server handle-client* handler>> call( -- ) ;
 106
 107 : handle-client ( client remote local -- )
 108     '[
 109         _ _ log-connection
 110         threaded-server get
 111         [ timeout>> timeouts ] [ handle-client* ] bi
 112     ] with-stream ;
 113
 114 \ handle-client NOTICE add-error-logging
 115
 116 : client-thread-name ( addrspec -- string )
 117     [ threaded-server get name>> ] dip
 118     unparse-short " connection from " glue ;
 119
 120 : (accept-connection) ( server -- )
 121     [ accept ] [ addr>> ] bi
 122     [ '[ _ _ _ handle-client ] ]
 123     [ drop client-thread-name ] 2bi
 124     spawn drop ;
 125
 126 : accept-connection ( server -- )
 127     threaded-server get semaphore>>
 128     [ [ (accept-connection) ] with-semaphore ]
 129     [ (accept-connection) ]
 130     if* ;
 131
 132 : with-existing-secure-context ( threaded-server quot -- )
 133     [ secure-context>> secure-context ] dip with-variable ; inline
 134
 135 : accept-loop ( server -- )
 136     [ accept-connection ] [ accept-loop ] bi ;
 137
 138 : start-accept-loop ( threaded-server server -- )
 139     '[ _ accept-loop ] with-existing-secure-context ;
 140
 141 \ start-accept-loop NOTICE add-error-logging
 142
 143 : create-secure-context ( threaded-server -- threaded-server )
 144     dup secure>> [
 145         dup secure-config>> <secure-context> >>secure-context
 146     ] when ;
 147
 148 : init-server ( threaded-server -- threaded-server )
 149     create-secure-context
 150     <flag> >>server-stopped
 151     dup semaphore>> [
 152         dup max-connections>> [
 153             <semaphore> >>semaphore
 154         ] when*
 155     ] unless ;
 156
 157 ERROR: no-ports-configured threaded-server ;
 158
 159 : (make-servers) ( theaded-server addrspecs -- servers )
 160     swap encoding>>
 161     '[ [ _ <server> |dispose ] map ] with-destructors ;
 162
 163 : set-servers ( threaded-server -- threaded-server )
 164     dup [
 165         dup dup listen-on
 166         [ no-ports-configured ] [ (make-servers) ] if-empty
 167         >>servers
 168     ] with-existing-secure-context ;
 169
 170 : server-thread-name ( threaded-server addrspec -- string )
 171     [ name>> ] [ addr>> present ] bi* " server on " glue ;
 172
 173 PRIVATE>
 174
 175 : start-server ( threaded-server -- threaded-server )
 176     init-server
 177     [
 178         dup threaded-server [
 179             [ ] [ name>> ] bi
 180             [
 181                 set-servers
 182                 dup add-running-server
 183                 dup servers>>
 184                 [
 185                     [ '[ _ _ [ start-accept-loop ] with-disposal ] ]
 186                     [ server-thread-name ] 2bi spawn drop
 187                 ] with each
 188             ] with-logging
 189         ] with-variable
 190     ] keep ;
 191
 192 : server-running? ( threaded-server -- ? )
 193     server-stopped>> [ value>> not ] [ f ] if* ;
 194
 195 : stop-server ( threaded-server -- )
 196     dup server-running? [
 197         [ remove-running-server ]
 198         [
 199             [
 200                 [ secure-context>> [ &dispose drop ] when* ]
 201                 [ [ f ] change-servers drop dispose-each ] bi
 202             ] with-destructors
 203         ]
 204         [ server-stopped>> raise-flag ] tri
 205     ] [
 206         drop
 207     ] if ;
 208
 209 : stop-this-server ( -- )
 210     threaded-server get stop-server ;
 211
 212 : wait-for-server ( threaded-server -- )
 213     server-stopped>> wait-for-flag ;
 214
 215 : with-threaded-server ( threaded-server quot -- )
 216     [ start-server ] dip over
 217     '[
 218         [ _ threaded-server _ with-variable ]
 219         [ _ stop-server ]
 220         [ ] cleanup
 221     ] call ; inline
 222
 223 <PRIVATE
 224
 225 GENERIC: connect-addr ( addrspec -- addrspec )
 226
 227 M: inet4 connect-addr [ "127.0.0.1" ] dip port>> <inet4> ;
 228
 229 M: inet6 connect-addr [ "::1" ] dip port>> <inet6> ;
 230
 231 M: secure connect-addr addrspec>> connect-addr <secure> ;
 232
 233 M: local connect-addr ;
 234
 235 PRIVATE>
 236
 237 : server-addrs ( -- addrspecs )
 238     threaded-server get servers>> [ addr>> connect-addr ] map ;
 239
 240 : secure-addr ( -- addrspec )
 241     server-addrs [ secure? ] filter random ;
 242
 243 : insecure-addr ( -- addrspec )
 244     server-addrs [ secure? not ] filter random ;
 245
 246 : server. ( threaded-server -- )
 247     [ [ "=== " write name>> ] [ ] bi write-object nl ]
 248     [ servers>> [ addr>> present print ] each ] bi ;
 249
 250 : all-servers ( -- sequence )
 251     running-servers get-global members ;
 252
 253 : get-servers-named ( string -- sequence )
 254     [ all-servers ] dip '[ name>> _ = ] filter ;
 255
 256 : servers. ( -- )
 257     all-servers [ server. ] each ;
 258
 259 : stop-all-servers ( -- )
 260     all-servers [ stop-server ] each ;