basis/io/sockets/icmp/icmp.factor

   1 ! Copyright (C) 2010 John Benediktsson
   2 ! See http://factorcode.org/license.txt for BSD license
   3
   4 USING: accessors arrays combinators io.sockets
   5 io.sockets.private kernel sequences system
   6 vocabs.parser vocabs.platforms ;
   7
   8 IN: io.sockets.icmp
   9
  10 USE-WINDOWS: windows.winsock
  11 USE-UNIX: unix.ffi
  12
  13 <PRIVATE
  14
  15 MEMO: IPPROTO_ICMP4 ( -- protocol )
  16     "icmp" getprotobyname proto>> ;
  17
  18 MEMO: IPPROTO_ICMP6 ( -- protocol )
  19     "ipv6-icmp" getprotobyname proto>> ;
  20
  21 GENERIC: with-icmp ( addrspec -- addrspec )
  22
  23 PRIVATE>
  24
  25
  26 TUPLE: icmp4 < ipv4 ;
  27
  28 C: <icmp4> icmp4
  29
  30 M: ipv4 with-icmp host>> <icmp4> ;
  31
  32 M: icmp4 protocol drop IPPROTO_ICMP4 ;
  33
  34 M: icmp4 port>> drop 0 ;
  35
  36 M: icmp4 parse-sockaddr call-next-method with-icmp ;
  37
  38 M: icmp4 resolve-host 1array ;
  39
  40
  41 TUPLE: icmp6 < ipv6 ;
  42
  43 : <icmp6> ( host -- icmp6 ) 0 icmp6 boa ;
  44
  45 M: ipv6 with-icmp host>> <icmp6> ;
  46
  47 M: icmp6 protocol drop IPPROTO_ICMP6 ;
  48
  49 M: icmp6 port>> drop 0 ;
  50
  51 M: icmp6 parse-sockaddr call-next-method with-icmp ;
  52
  53 M: icmp6 resolve-host 1array ;
  54
  55
  56 TUPLE: icmp < hostname ;
  57
  58 C: <icmp> icmp
  59
  60 M: icmp resolve-host call-next-method [ with-icmp ] map ;