basis/io/sockets/sockets-tests.factor

   1 IN: io.sockets.tests
   2 USING: io.sockets io.sockets.private sequences math tools.test
   3 namespaces accessors kernel destructors calendar io.timeouts
   4 io.encodings.utf8 io concurrency.promises threads
   5 io.streams.string ;
   6
   7 [ B{ 1 2 3 4 } ]
   8 [ "1.2.3.4" T{ inet4 } inet-pton ] unit-test
   9
  10 [ "1.2.3.4" ]
  11 [ B{ 1 2 3 4 } T{ inet4 } inet-ntop ] unit-test
  12
  13 [ "255.255.255.255" ]
  14 [ B{ 255 255 255 255 } T{ inet4 } inet-ntop ] unit-test
  15
  16 [ B{ 255 255 255 255 } ]
  17 [ "255.255.255.255" T{ inet4 } inet-pton ] unit-test
  18
  19 [ B{ 0 1 0 2 0 3 0 4 0 5 0 6 0 7 0 8 } ]
  20 [ "1:2:3:4:5:6:7:8" T{ inet6 } inet-pton ] unit-test
  21
  22 [ "1:2:3:4:5:6:7:8" ]
  23 [ B{ 0 1 0 2 0 3 0 4 0 5 0 6 0 7 0 8 } T{ inet6 } inet-ntop ] unit-test
  24
  25 [ B{ 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 } ]
  26 [ "::" T{ inet6 } inet-pton ] unit-test
  27
  28 [ "0:0:0:0:0:0:0:0" ]
  29 [ B{ 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 } T{ inet6 } inet-ntop ] unit-test
  30
  31 [ B{ 0 1 0 0 0 0 0 0 0 0 0 0 0 0 0 0 } ]
  32 [ "1::" T{ inet6 } inet-pton ] unit-test
  33
  34 [ B{ 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 1 } ]
  35 [ "::1" T{ inet6 } inet-pton ] unit-test
  36
  37 [ B{ 0 0 0 0 0 0 0 0 0 0 0 0 0 0 1 0 } ]
  38 [ "::100" T{ inet6 } inet-pton ] unit-test
  39
  40 [ B{ 0 1 0 0 0 0 0 0 0 0 0 0 0 0 0 2 } ]
  41 [ "1::2" T{ inet6 } inet-pton ] unit-test
  42
  43 [ B{ 0 1 0 0 0 0 0 0 0 0 0 0 0 2 0 3 } ]
  44 [ "1::2:3" T{ inet6 } inet-pton ] unit-test
  45
  46 [ B{ 0 1 0 2 0 0 0 0 0 0 0 0 0 3 0 4 } ]
  47 [ "1:2::3:4" T{ inet6 } inet-pton ] unit-test
  48
  49 [ "1:2:0:0:0:0:3:4" ]
  50 [ B{ 0 1 0 2 0 0 0 0 0 0 0 0 0 3 0 4 } T{ inet6 } inet-ntop ] unit-test
  51
  52 [ "2001:6f8:37a:5:0:0:0:1" ]
  53 [ "2001:6f8:37a:5::1" T{ inet6 } [ inet-pton ] [ inet-ntop ] bi ] unit-test
  54
  55 [ t ] [ "localhost" 80 <inet> resolve-host length 1 >= ] unit-test
  56
  57 ! Smoke-test UDP
  58 [ ] [ "127.0.0.1" 0 <inet4> <datagram> "datagram1" set ] unit-test
  59 [ ] [ "datagram1" get addr>> "addr1" set ] unit-test
  60 [ f ] [ "addr1" get port>> 0 = ] unit-test
  61
  62 [ ] [ "127.0.0.1" 0 <inet4> <datagram> "datagram2" set ] unit-test
  63 [ ] [ "datagram2" get addr>> "addr2" set ] unit-test
  64 [ f ] [ "addr2" get port>> 0 = ] unit-test
  65
  66 [ ] [ B{ 1 2 3 4 } "addr2" get "datagram1" get send ] unit-test
  67 [ B{ 1 2 3 4 } ] [ "datagram2" get receive "from" set ] unit-test
  68 [ ] [ B{ 4 3 2 1 } "from" get "datagram2" get send ] unit-test
  69 [ B{ 4 3 2 1 } t ] [ "datagram1" get receive "addr2" get = ] unit-test
  70
  71 [ ] [ "datagram1" get dispose ] unit-test
  72 [ ] [ "datagram2" get dispose ] unit-test
  73
  74 ! Test timeouts
  75 [ ] [ "127.0.0.1" 0 <inet4> <datagram> "datagram3" set ] unit-test
  76
  77 [ ] [ 1 seconds "datagram3" get set-timeout ] unit-test
  78 [ "datagram3" get receive ] must-fail
  79
  80 ! See what happens if other end is closed
  81 [ ] [ <promise> "port" set ] unit-test
  82
  83 [ ] [ "datagram3" get dispose ] unit-test
  84
  85 [ ] [
  86     [
  87         "127.0.0.1" 0 <inet4> utf8 <server>
  88         dup addr>> "port" get fulfill
  89         [
  90             accept drop
  91             dup stream-readln drop
  92             "hello" <string-reader> swap stream-copy
  93         ] with-disposal
  94     ] "Socket close test" spawn drop
  95 ] unit-test
  96
  97 [ "hello" f ] [
  98     "port" get ?promise utf8 [
  99         1 seconds input-stream get set-timeout
 100         1 seconds output-stream get set-timeout
 101         "hi\n" write flush readln readln
 102     ] with-client
 103 ] unit-test