basis/io/sockets/sockets.factor

   1 ! Copyright (C) 2007, 2010 Slava Pestov, Doug Coleman,
   2 ! Daniel Ehrenberg.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: generic kernel io.backend namespaces continuations sequences
   5 arrays io.encodings io.ports io.streams.duplex io.encodings.ascii
   6 alien.strings io.binary accessors destructors classes byte-arrays
   7 parser alien.c-types math.parser splitting grouping math assocs
   8 summary system vocabs.loader combinators present fry vocabs.parser
   9 classes.struct alien.data strings ;
  10 IN: io.sockets
  11
  12 << {
  13     { [ os windows? ] [ "windows.winsock" ] }
  14     { [ os unix? ] [ "unix.ffi" ] }
  15 } cond use-vocab >>
  16
  17 ! Addressing
  18 <PRIVATE
  19
  20 UNION: ?string string POSTPONE: f ;
  21
  22 GENERIC: protocol-family ( addrspec -- af )
  23
  24 GENERIC: sockaddr-size ( addrspec -- n )
  25
  26 GENERIC: make-sockaddr ( addrspec -- sockaddr )
  27
  28 GENERIC: empty-sockaddr ( addrspec -- sockaddr )
  29
  30 GENERIC: address-size ( addrspec -- n )
  31
  32 GENERIC: inet-ntop ( data addrspec -- str )
  33
  34 GENERIC: inet-pton ( str addrspec -- data )
  35
  36 GENERIC# with-port 1 ( addrspec port -- addrspec )
  37
  38 : make-sockaddr/size ( addrspec -- sockaddr size )
  39     [ make-sockaddr ] [ sockaddr-size ] bi ;
  40
  41 : empty-sockaddr/size ( addrspec -- sockaddr size )
  42     [ empty-sockaddr ] [ sockaddr-size ] bi ;
  43
  44 GENERIC: parse-sockaddr ( sockaddr addrspec -- newaddrspec )
  45
  46 M: f parse-sockaddr nip ;
  47
  48 HOOK: sockaddr-of-family os ( alien af -- sockaddr )
  49
  50 HOOK: addrspec-of-family os ( af -- addrspec )
  51
  52 PRIVATE>
  53
  54 TUPLE: local { path read-only } ;
  55
  56 : <local> ( path -- addrspec )
  57     normalize-path local boa ;
  58
  59 M: local present path>> "Unix domain socket: " prepend ;
  60
  61 SLOT: port
  62
  63 TUPLE: ipv4 { host ?string read-only } ;
  64
  65 C: <ipv4> ipv4
  66
  67 M: ipv4 inet-ntop ( data addrspec -- str )
  68     drop 4 memory>byte-array [ number>string ] { } map-as "." join ;
  69
  70 <PRIVATE
  71
  72 ERROR: malformed-ipv4 sequence ;
  73
  74 ERROR: bad-ipv4-component string ;
  75
  76 : parse-ipv4 ( string -- seq )
  77     "." split dup length 4 = [ malformed-ipv4 ] unless
  78     [ dup string>number [ ] [ bad-ipv4-component ] ?if ] B{ } map-as ;
  79
  80 ERROR: invalid-ipv4 string reason ;
  81
  82 M: invalid-ipv4 summary drop "Invalid IPv4 address" ;
  83
  84 PRIVATE>
  85
  86 M: ipv4 inet-pton ( str addrspec -- data )
  87     drop [ parse-ipv4 ] [ invalid-ipv4 ] recover ;
  88
  89 M: ipv4 address-size drop 4 ;
  90
  91 M: ipv4 protocol-family drop PF_INET ;
  92
  93 M: ipv4 sockaddr-size drop sockaddr-in heap-size ;
  94
  95 M: ipv4 empty-sockaddr drop sockaddr-in <struct> ;
  96
  97 M: ipv4 make-sockaddr ( inet -- sockaddr )
  98     sockaddr-in <struct>
  99         AF_INET >>family
 100         swap
 101         [ port>> htons >>port ]
 102         [ host>> "0.0.0.0" or ]
 103         [ inet-pton *uint >>addr ] tri ;
 104
 105 M: ipv4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
 106     [ addr>> <uint> ] dip inet-ntop <ipv4> ;
 107
 108 TUPLE: inet4 < ipv4 { port integer read-only } ;
 109
 110 C: <inet4> inet4
 111
 112 M: ipv4 with-port [ host>> ] dip <inet4> ;
 113
 114 M: inet4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
 115     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 116
 117 M: inet4 present
 118     [ host>> ] [ port>> number>string ] bi ":" glue ;
 119
 120 TUPLE: ipv6 { host ?string read-only } ;
 121
 122 C: <ipv6> ipv6
 123
 124 M: ipv6 inet-ntop ( data addrspec -- str )
 125     drop 16 memory>byte-array 2 <groups> [ be> >hex ] map ":" join ;
 126
 127 ERROR: invalid-ipv6 string reason ;
 128
 129 <PRIVATE
 130
 131 ERROR: bad-ipv6-component obj ;
 132
 133 ERROR: bad-ipv4-embedded-prefix obj ;
 134
 135 ERROR: more-than-8-components ;
 136
 137 : parse-ipv6-component ( seq -- seq' )
 138     [ dup hex> [ nip ] [ bad-ipv6-component ] if* ] { } map-as ;
 139
 140 : parse-ipv6 ( string -- seq )
 141     [ f ] [
 142         ":" split CHAR: . over last member? [
 143             unclip-last
 144             [ parse-ipv6-component ] [ parse-ipv4 ] bi* append
 145         ] [
 146             parse-ipv6-component
 147         ] if
 148     ] if-empty ;
 149
 150 : pad-ipv6 ( string1 string2 -- seq )
 151     2dup [ length ] bi@ + 8 swap -
 152     dup 0 < [ more-than-8-components ] when
 153     <byte-array> glue ;
 154
 155 : ipv6-bytes ( seq -- bytes )
 156     [ 2 >be ] { } map-as B{ } concat-as ;
 157
 158 PRIVATE>
 159
 160 M: ipv6 inet-pton ( str addrspec -- data )
 161     drop
 162     [ "::" split1 [ parse-ipv6 ] bi@ pad-ipv6 ipv6-bytes ]
 163     [ invalid-ipv6 ]
 164     recover ;
 165
 166 M: ipv6 address-size drop 16 ;
 167
 168 M: ipv6 protocol-family drop PF_INET6 ;
 169
 170 M: ipv6 sockaddr-size drop sockaddr-in6 heap-size ;
 171
 172 M: ipv6 empty-sockaddr drop sockaddr-in6 <struct> ;
 173
 174 M: ipv6 make-sockaddr ( inet -- sockaddr )
 175     sockaddr-in6 <struct>
 176         AF_INET6 >>family
 177         swap
 178         [ port>> htons >>port ]
 179         [ host>> "::" or ]
 180         [ inet-pton >>addr ] tri ;
 181
 182 M: ipv6 parse-sockaddr
 183     [ addr>> ] dip inet-ntop <ipv6> ;
 184
 185 TUPLE: inet6 < ipv6 { port integer read-only } ;
 186
 187 C: <inet6> inet6
 188
 189 M: ipv6 with-port [ host>> ] dip <inet6> ;
 190
 191 M: inet6 parse-sockaddr
 192     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 193
 194 M: inet6 present
 195     [ host>> ] [ port>> number>string ] bi ":" glue ;
 196
 197 <PRIVATE
 198
 199 GENERIC: (get-local-address) ( handle remote -- sockaddr )
 200
 201 : get-local-address ( handle remote -- local )
 202     [ (get-local-address) ] keep parse-sockaddr ;
 203
 204 GENERIC: (get-remote-address) ( handle remote -- sockaddr )
 205
 206 : get-remote-address ( handle local -- remote )
 207     [ (get-remote-address) ] keep parse-sockaddr ;
 208
 209 : <ports> ( handle -- input-port output-port )
 210     [
 211         [ <input-port> |dispose ] [ <output-port> |dispose ] bi
 212     ] with-destructors ;
 213
 214 SYMBOL: bind-local-address
 215
 216 GENERIC: establish-connection ( client-out remote -- )
 217
 218 GENERIC: ((client)) ( remote -- handle )
 219
 220 GENERIC: (client) ( remote -- client-in client-out local )
 221
 222 M: array (client) [ (client) 3array ] attempt-all first3 ;
 223
 224 M: object (client) ( remote -- client-in client-out local )
 225     [
 226         [ ((client)) ] keep
 227         [
 228             [ <ports> [ |dispose ] bi@ dup ] dip
 229             establish-connection
 230         ]
 231         [ get-local-address ]
 232         2bi
 233     ] with-destructors ;
 234
 235 TUPLE: server-port < port addr encoding ;
 236
 237 : check-server-port ( port -- port )
 238     dup check-disposed
 239     dup server-port? [ "Not a server port" throw ] unless ; inline
 240
 241 GENERIC: (server) ( addrspec -- handle )
 242
 243 GENERIC: (accept) ( server addrspec -- handle sockaddr )
 244
 245 TUPLE: datagram-port < port addr ;
 246
 247 HOOK: (datagram) io-backend ( addr -- datagram )
 248
 249 : check-datagram-port ( port -- port )
 250     dup check-disposed
 251     dup datagram-port? [ "Not a datagram port" throw ] unless ; inline
 252
 253 HOOK: (receive) io-backend ( datagram -- packet addrspec )
 254
 255 : check-datagram-send ( packet addrspec port -- packet addrspec port )
 256     check-datagram-port
 257     2dup addr>> [ class ] bi@ assert=
 258     pick class byte-array assert= ;
 259
 260 HOOK: (send) io-backend ( packet addrspec datagram -- )
 261
 262 : addrinfo>addrspec ( addrinfo -- addrspec )
 263     [ [ addr>> ] [ family>> ] bi sockaddr-of-family ]
 264     [ family>> addrspec-of-family ] bi
 265     parse-sockaddr ;
 266
 267 : parse-addrinfo-list ( addrinfo -- seq )
 268     [ next>> ] follow
 269     [ addrinfo>addrspec ] map
 270     sift ;
 271
 272 HOOK: addrinfo-error io-backend ( n -- )
 273
 274 : prepare-addrinfo ( -- addrinfo )
 275     addrinfo <struct>
 276         PF_UNSPEC >>family
 277         IPPROTO_TCP >>protocol ;
 278
 279 PRIVATE>
 280
 281 : <client> ( remote encoding -- stream local )
 282     [ (client) ] dip swap [ <encoder-duplex> ] dip ;
 283
 284 SYMBOL: local-address
 285
 286 SYMBOL: remote-address
 287
 288 : with-client ( remote encoding quot -- )
 289     [
 290         [
 291             over remote-address set
 292             <client> local-address set
 293         ] dip with-stream
 294     ] with-scope ; inline
 295
 296 : <server> ( addrspec encoding -- server )
 297     [
 298         [ (server) ] keep
 299         [ drop server-port <port> ] [ get-local-address ] 2bi
 300         >>addr
 301     ] dip >>encoding ;
 302
 303 : accept ( server -- client remote )
 304     [
 305         dup addr>>
 306         [ (accept) ] keep
 307         parse-sockaddr swap
 308         <ports>
 309     ] keep encoding>> <encoder-duplex> swap ;
 310
 311 : <datagram> ( addrspec -- datagram )
 312     [
 313         [ (datagram) |dispose ] keep
 314         [ drop datagram-port <port> ] [ get-local-address ] 2bi
 315         >>addr
 316     ] with-destructors ;
 317
 318 : receive ( datagram -- packet addrspec )
 319     check-datagram-port
 320     [ (receive) ] [ addr>> ] bi parse-sockaddr ;
 321
 322 : send ( packet addrspec datagram -- )
 323     check-datagram-send (send) ;
 324
 325 GENERIC: resolve-host ( addrspec -- seq )
 326
 327 TUPLE: hostname { host ?string read-only } ;
 328
 329 TUPLE: inet < hostname port ;
 330
 331 M: inet present
 332     [ host>> ] [ port>> number>string ] bi ":" glue ;
 333
 334 C: <inet> inet
 335
 336 M: string resolve-host
 337     f prepare-addrinfo f <void*>
 338     [ getaddrinfo addrinfo-error ] keep *void* addrinfo memory>struct
 339     [ parse-addrinfo-list ] keep freeaddrinfo ;
 340
 341 M: hostname resolve-host
 342     host>> resolve-host ;
 343
 344 M: inet resolve-host
 345     [ call-next-method ] [ port>> ] bi '[ _ with-port ] map ;
 346
 347 M: inet4 resolve-host 1array ;
 348
 349 M: inet6 resolve-host 1array ;
 350
 351 M: local resolve-host 1array ;
 352
 353 M: f resolve-host
 354     drop { T{ ipv6 f "::" } T{ ipv4 f "0.0.0.0" } } ;
 355
 356 : host-name ( -- string )
 357     256 <byte-array> dup dup length gethostname
 358     zero? [ "gethostname failed" throw ] unless
 359     ascii alien>string ;
 360
 361 M: inet (client) resolve-host (client) ;
 362
 363 ERROR: invalid-inet-server addrspec ;
 364
 365 M: invalid-inet-server summary
 366     drop "Cannot use <server> with <inet>; use <inet4> or <inet6> instead" ;
 367
 368 M: inet (server)
 369     invalid-inet-server ;
 370
 371 ERROR: invalid-local-address addrspec ;
 372
 373 M: invalid-local-address summary
 374     drop "Cannot use with-local-address with <inet>; use <inet4> or <inet6> instead" ;
 375
 376 : with-local-address ( addr quot -- )
 377     [
 378         [ ] [ inet4? ] [ inet6? ] tri or
 379         [ bind-local-address ]
 380         [ invalid-local-address ] if
 381     ] dip with-variable ; inline
 382
 383 {
 384     { [ os unix? ] [ "io.sockets.unix" require ] }
 385     { [ os winnt? ] [ "io.sockets.windows.nt" require ] }
 386 } cond