basis/io/sockets/sockets.factor

   1 ! Copyright (C) 2007, 2011 Slava Pestov, Doug Coleman,
   2 ! Daniel Ehrenberg.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: accessors alien.c-types alien.data alien.strings arrays
   5 byte-arrays classes classes.struct combinators
   6 combinators.short-circuit continuations destructors fry
   7 grouping init io.backend io.binary io.encodings.ascii
   8 io.encodings.binary io.pathnames io.ports io.streams.duplex
   9 kernel locals math math.parser memoize namespaces present
  10 sequences sequences.private splitting strings summary system
  11 vocabs vocabs.parser ;
  12 IN: io.sockets
  13
  14 << {
  15     { [ os windows? ] [ "windows.winsock" ] }
  16     { [ os unix? ] [ "unix.ffi" ] }
  17 } cond use-vocab >>
  18
  19 GENERIC# with-port 1 ( addrspec port -- addrspec )
  20
  21 ! Addressing
  22 <PRIVATE
  23
  24 GENERIC: protocol ( addrspec -- n )
  25
  26 GENERIC: protocol-family ( addrspec -- af )
  27
  28 GENERIC: sockaddr-size ( addrspec -- n )
  29
  30 GENERIC: make-sockaddr ( addrspec -- sockaddr )
  31
  32 GENERIC: empty-sockaddr ( addrspec -- sockaddr )
  33
  34 GENERIC: address-size ( addrspec -- n )
  35
  36 GENERIC: inet-ntop ( data addrspec -- str )
  37
  38 GENERIC: inet-pton ( str addrspec -- data )
  39
  40 : make-sockaddr/size ( addrspec -- sockaddr size )
  41     [ make-sockaddr ] [ sockaddr-size ] bi ;
  42
  43 : empty-sockaddr/size ( addrspec -- sockaddr size )
  44     [ empty-sockaddr ] [ sockaddr-size ] bi ;
  45
  46 GENERIC: parse-sockaddr ( sockaddr addrspec -- newaddrspec )
  47
  48 M: f parse-sockaddr nip ;
  49
  50 HOOK: sockaddr-of-family os ( alien af -- sockaddr )
  51
  52 HOOK: addrspec-of-family os ( af -- addrspec )
  53
  54 PRIVATE>
  55
  56 TUPLE: local { path string read-only } ;
  57
  58 : <local> ( path -- addrspec )
  59     absolute-path local boa ;
  60
  61 M: local present path>> "Unix domain socket: " prepend ;
  62
  63 M: local protocol drop 0 ;
  64
  65 SLOT: port
  66
  67 TUPLE: ipv4 { host maybe{ string } read-only } ;
  68
  69 <PRIVATE
  70
  71 ERROR: invalid-ipv4 string reason ;
  72
  73 M: invalid-ipv4 summary drop "Invalid IPv4 address" ;
  74
  75 ERROR: malformed-ipv4 sequence ;
  76
  77 ERROR: bad-ipv4-component string ;
  78
  79 : parse-ipv4 ( string -- seq )
  80     [ f ] [
  81         "." split dup length 4 = [ throw-malformed-ipv4 ] unless
  82         [ dup string>number [ ] [ throw-bad-ipv4-component ] ?if ] B{ } map-as
  83     ] if-empty ;
  84
  85 : check-ipv4 ( string -- )
  86     [ parse-ipv4 drop ] [ throw-invalid-ipv4 ] recover ;
  87
  88 PRIVATE>
  89
  90 : <ipv4> ( host -- ipv4 ) dup check-ipv4 ipv4 boa ;
  91
  92 M: ipv4 inet-ntop ( data addrspec -- str )
  93     drop 4 memory>byte-array [ number>string ] { } map-as "." join ;
  94
  95 M: ipv4 inet-pton ( str addrspec -- data )
  96     drop [ parse-ipv4 ] [ throw-invalid-ipv4 ] recover ;
  97
  98 M: ipv4 address-size drop 4 ;
  99
 100 M: ipv4 protocol-family drop PF_INET ;
 101
 102 M: ipv4 sockaddr-size drop sockaddr-in heap-size ;
 103
 104 M: ipv4 empty-sockaddr drop sockaddr-in <struct> ;
 105
 106 M: ipv4 make-sockaddr ( inet -- sockaddr )
 107     sockaddr-in <struct>
 108         AF_INET >>family
 109         swap
 110         [ port>> htons >>port ]
 111         [ host>> "0.0.0.0" or ]
 112         [ inet-pton uint deref >>addr ] tri ;
 113
 114 M: ipv4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
 115     [ addr>> uint <ref> ] dip inet-ntop <ipv4> ;
 116
 117 TUPLE: inet4 < ipv4 { port integer read-only } ;
 118
 119 : <inet4> ( host port -- inet4 )
 120     over check-ipv4 inet4 boa ;
 121
 122 M: ipv4 with-port [ host>> ] dip <inet4> ;
 123
 124 M: inet4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
 125     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 126
 127 M: inet4 present
 128     [ host>> ] [ port>> number>string ] bi ":" glue ;
 129
 130 M: inet4 protocol drop 0 ;
 131
 132 TUPLE: ipv6
 133 { host maybe{ string } read-only }
 134 { scope-id integer read-only } ;
 135
 136 <PRIVATE
 137
 138 ERROR: invalid-ipv6 host reason ;
 139
 140 M: invalid-ipv6 summary drop "Invalid IPv6 address" ;
 141
 142 ERROR: bad-ipv6-component obj ;
 143
 144 ERROR: bad-ipv4-embedded-prefix obj ;
 145
 146 ERROR: more-than-8-components ;
 147
 148 : parse-ipv6-component ( seq -- seq' )
 149     [ dup hex> [ nip ] [ throw-bad-ipv6-component ] if* ] { } map-as ;
 150
 151 : parse-ipv6 ( string -- seq )
 152     [ f ] [
 153         ":" split CHAR: . over last member? [
 154             unclip-last
 155             [ parse-ipv6-component ] [ parse-ipv4 ] bi* append
 156         ] [
 157             parse-ipv6-component
 158         ] if
 159     ] if-empty ;
 160
 161 : check-ipv6 ( string -- )
 162     [ "::" split1 [ parse-ipv6 ] bi@ 2drop ] [ throw-invalid-ipv6 ] recover ;
 163
 164 PRIVATE>
 165
 166 : <ipv6> ( host -- ipv6 ) dup check-ipv6 0 ipv6 boa ;
 167
 168 M: ipv6 inet-ntop ( data addrspec -- str )
 169     drop 16 memory>byte-array 2 <groups> [ be> >hex ] map ":" join ;
 170
 171 <PRIVATE
 172
 173 : pad-ipv6 ( string1 string2 -- seq )
 174     2dup [ length ] bi@ + 8 swap -
 175     dup 0 < [ throw-more-than-8-components ] when
 176     <byte-array> glue ;
 177
 178 : ipv6-bytes ( seq -- bytes )
 179     [ 2 >be ] { } map-as B{ } concat-as ;
 180
 181 PRIVATE>
 182
 183 M: ipv6 inet-pton ( str addrspec -- data )
 184     drop
 185     [ "::" split1 [ parse-ipv6 ] bi@ pad-ipv6 ipv6-bytes ]
 186     [ throw-invalid-ipv6 ]
 187     recover ;
 188
 189 M: ipv6 address-size drop 16 ;
 190
 191 M: ipv6 protocol-family drop PF_INET6 ;
 192
 193 M: ipv6 sockaddr-size drop sockaddr-in6 heap-size ;
 194
 195 M: ipv6 empty-sockaddr drop sockaddr-in6 <struct> ;
 196
 197 M: ipv6 make-sockaddr ( inet -- sockaddr )
 198     sockaddr-in6 <struct>
 199         AF_INET6 >>family
 200         swap
 201         [ port>> htons >>port ]
 202         [ [ host>> "::" or ] keep inet-pton >>addr ]
 203         [ scope-id>> >>scopeid ]
 204         tri ;
 205
 206 M: ipv6 parse-sockaddr
 207     [ [ addr>> ] dip inet-ntop ] [ drop scopeid>> ] 2bi
 208     ipv6 boa ;
 209
 210 M: ipv6 present
 211     [ host>> ] [ scope-id>> ] bi
 212     [ number>string "%" glue ] unless-zero ;
 213
 214 TUPLE: inet6 < ipv6 { port integer read-only } ;
 215
 216 : <inet6> ( host port -- inet6 )
 217     [ dup check-ipv6 0 ] dip inet6 boa ;
 218
 219 M: ipv6 with-port
 220     [ [ host>> ] [ scope-id>> ] bi ] dip
 221     inet6 boa ;
 222
 223 M: inet6 parse-sockaddr
 224     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 225
 226 M: inet6 present
 227     [ call-next-method ] [ port>> number>string ] bi ":" glue ;
 228
 229 M: inet6 protocol drop 0 ;
 230
 231 ERROR: addrinfo-error n string ;
 232
 233 <PRIVATE
 234
 235 GENERIC: (get-local-address) ( handle remote -- sockaddr )
 236
 237 : get-local-address ( handle remote -- local )
 238     [ (get-local-address) ] keep parse-sockaddr ;
 239
 240 GENERIC: (get-remote-address) ( handle remote -- sockaddr )
 241
 242 : get-remote-address ( handle local -- remote )
 243     [ (get-remote-address) ] keep parse-sockaddr ;
 244
 245 : <ports> ( handle -- input-port output-port )
 246     [
 247         [ <input-port> |dispose ] [ <output-port> |dispose ] bi
 248     ] with-destructors ;
 249
 250 SYMBOL: bind-local-address
 251
 252 GENERIC: establish-connection ( client-out remote -- )
 253
 254 GENERIC: ((client)) ( remote -- handle )
 255
 256 GENERIC: (client) ( remote -- client-in client-out local )
 257
 258 M: array (client) [ (client) 3array ] attempt-all first3 ;
 259
 260 M: object (client) ( remote -- client-in client-out local )
 261     [
 262         [ ((client)) ] keep
 263         [
 264             [ <ports> [ |dispose ] bi@ dup ] dip
 265             establish-connection
 266         ]
 267         [ get-local-address ]
 268         2bi
 269     ] with-destructors ;
 270
 271 TUPLE: server-port < port addr encoding ;
 272
 273 GENERIC: (server) ( addrspec -- handle )
 274
 275 GENERIC: (accept) ( server addrspec -- handle sockaddr )
 276
 277 TUPLE: datagram-port < port addr ;
 278
 279 HOOK: (datagram) io-backend ( addr -- datagram )
 280
 281 TUPLE: raw-port < port addr ;
 282
 283 HOOK: (raw) io-backend ( addr -- raw )
 284
 285 HOOK: (broadcast) io-backend ( datagram -- datagram )
 286
 287 HOOK: (receive-unsafe) io-backend ( n buf datagram -- count addrspec )
 288
 289 ERROR: invalid-port object ;
 290
 291 : check-port ( packet addrspec port -- packet addrspec port )
 292     2dup addr>> [ class-of ] bi@ assert=
 293     pick class-of byte-array assert= ;
 294
 295 : check-connectionless-port ( port -- port )
 296     dup { [ datagram-port? ] [ raw-port? ] } 1|| [ throw-invalid-port ] unless ;
 297
 298 : check-send ( packet addrspec port -- packet addrspec port )
 299     check-connectionless-port check-disposed check-port ;
 300
 301 : check-receive ( port -- port )
 302     check-connectionless-port check-disposed ;
 303
 304 HOOK: (send) io-backend ( packet addrspec datagram -- )
 305
 306 : addrinfo>addrspec ( addrinfo -- addrspec )
 307     [ [ addr>> ] [ family>> ] bi sockaddr-of-family ]
 308     [ family>> addrspec-of-family ] bi
 309     parse-sockaddr ;
 310
 311 : parse-addrinfo-list ( addrinfo -- seq )
 312     [ next>> ] follow
 313     [ addrinfo>addrspec ] map
 314     sift ;
 315
 316 HOOK: addrinfo-error-string io-backend ( n -- string )
 317
 318 : prepare-addrinfo ( -- addrinfo )
 319     addrinfo <struct>
 320         PF_UNSPEC >>family
 321         IPPROTO_TCP >>protocol ;
 322
 323 PRIVATE>
 324
 325 : <client> ( remote encoding -- stream local )
 326     [ (client) ] dip swap [ <encoder-duplex> ] dip ;
 327
 328 SYMBOL: local-address
 329
 330 SYMBOL: remote-address
 331
 332 : with-client ( remote encoding quot -- )
 333     [
 334         [
 335             over remote-address set
 336             <client> local-address set
 337         ] dip with-stream
 338     ] with-scope ; inline
 339
 340 : <server> ( addrspec encoding -- server )
 341     [
 342         [ (server) ] keep
 343         [ drop server-port <port> ] [ get-local-address ] 2bi
 344         >>addr
 345     ] dip >>encoding ;
 346
 347 : accept ( server -- client remote )
 348     [
 349         dup addr>>
 350         [ (accept) ] keep
 351         parse-sockaddr swap
 352         <ports>
 353     ] [ encoding>> ] bi <encoder-duplex> swap ;
 354
 355 : <datagram> ( addrspec -- datagram )
 356     [
 357         [ (datagram) |dispose ] keep
 358         [ drop datagram-port <port> ] [ get-local-address ] 2bi
 359         >>addr
 360     ] with-destructors ;
 361
 362 : <raw> ( addrspec -- datagram )
 363     [
 364         [ (raw) |dispose ] keep
 365         [ drop raw-port <port> ] [ get-local-address ] 2bi
 366         >>addr
 367     ] with-destructors ;
 368
 369 : <broadcast> ( addrspec -- datagram )
 370     <datagram> (broadcast) ;
 371
 372 : receive-unsafe ( n buf datagram -- count addrspec )
 373     check-receive
 374     [ (receive-unsafe) ] [ addr>> ] bi parse-sockaddr ; inline
 375
 376 CONSTANT: datagram-size 65536
 377
 378 :: receive ( datagram -- packet addrspec )
 379     datagram-size (byte-array) :> buf
 380     datagram-size buf datagram
 381     receive-unsafe :> ( count addrspec )
 382     count buf resize addrspec ; inline
 383
 384 :: receive-into ( buf datagram -- buf-slice addrspec )
 385     buf length :> n
 386     n buf datagram receive-unsafe :> ( count addrspec )
 387     buf count head-slice addrspec ; inline
 388
 389 : send ( packet addrspec datagram -- )
 390     check-send (send) ; inline
 391
 392 MEMO: ipv6-supported? ( -- ? )
 393     [ "::1" 0 <inet6> binary <server> dispose t ] [ drop f ] recover ;
 394
 395 [ \ ipv6-supported? reset-memoized ]
 396 "io.sockets:ipv6-supported?" add-startup-hook
 397
 398 GENERIC: resolve-host ( addrspec -- seq )
 399
 400 HOOK: resolve-localhost os ( -- obj )
 401
 402 TUPLE: hostname { host maybe{ string } read-only } ;
 403
 404 TUPLE: inet < hostname port ;
 405
 406 M: inet present
 407     [ host>> ] [ port>> number>string ] bi ":" glue ;
 408
 409 C: <inet> inet
 410
 411 M: string resolve-host
 412     f prepare-addrinfo f void* <ref> [
 413         getaddrinfo [
 414             dup addrinfo-error-string throw-addrinfo-error
 415         ] unless-zero
 416     ] keep void* deref addrinfo memory>struct
 417     [ parse-addrinfo-list ] keep freeaddrinfo ;
 418
 419 M: string with-port <inet> ;
 420
 421 M: hostname resolve-host
 422     host>> resolve-host ;
 423
 424 M: hostname with-port
 425     [ host>> ] dip <inet> ;
 426
 427 M: inet resolve-host
 428     [ call-next-method ] [ port>> ] bi '[ _ with-port ] map ;
 429
 430 M: inet4 resolve-host 1array ;
 431
 432 M: inet6 resolve-host 1array ;
 433
 434 M: local resolve-host 1array ;
 435
 436 M: f resolve-host
 437     drop resolve-localhost ;
 438
 439 M: object resolve-localhost
 440     ipv6-supported?
 441     { T{ ipv4 f "0.0.0.0" } T{ ipv6 f "::" } }
 442     { T{ ipv4 f "0.0.0.0" } }
 443     ? ;
 444
 445 HOOK: host-name os ( -- string )
 446
 447 M: inet (client) resolve-host (client) ;
 448
 449 ERROR: invalid-inet-server addrspec ;
 450
 451 M: invalid-inet-server summary
 452     drop "Cannot use <server> with <inet>; use <inet4> or <inet6> instead" ;
 453
 454 M: inet (server)
 455     throw-invalid-inet-server ;
 456
 457 ERROR: invalid-local-address addrspec ;
 458
 459 M: invalid-local-address summary
 460     drop "Cannot use with-local-address with <inet>; use <inet4> or <inet6> instead" ;
 461
 462 : with-local-address ( addr quot -- )
 463     [
 464         [ ] [ inet4? ] [ inet6? ] tri or
 465         [ bind-local-address ]
 466         [ throw-invalid-local-address ] if
 467     ] dip with-variable ; inline
 468
 469 : protocol-port ( protocol -- port )
 470     [ f getservbyname [ port>> htons ] [ f ] if* ] [ f ] if* ;
 471
 472 {
 473     { [ os unix? ] [ "io.sockets.unix" require ] }
 474     { [ os windows? ] [ "io.sockets.windows" require ] }
 475 } cond