basis/io/sockets/sockets.factor

   1 ! Copyright (C) 2007, 2008 Slava Pestov, Doug Coleman,
   2 ! Daniel Ehrenberg.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: generic kernel io.backend namespaces continuations sequences
   5 arrays io.encodings io.ports io.streams.duplex io.encodings.ascii
   6 alien.strings io.binary accessors destructors classes byte-arrays
   7 parser alien.c-types math.parser splitting grouping math assocs
   8 summary system vocabs.loader combinators present fry vocabs.parser ;
   9 IN: io.sockets
  10
  11 << {
  12     { [ os windows? ] [ "windows.winsock" ] }
  13     { [ os unix? ] [ "unix" ] }
  14 } cond use-vocab >>
  15
  16 ! Addressing
  17 GENERIC: protocol-family ( addrspec -- af )
  18
  19 GENERIC: sockaddr-size ( addrspec -- n )
  20
  21 GENERIC: make-sockaddr ( addrspec -- sockaddr )
  22
  23 GENERIC: empty-sockaddr ( addrspec -- sockaddr )
  24
  25 GENERIC: address-size ( addrspec -- n )
  26
  27 GENERIC: inet-ntop ( data addrspec -- str )
  28
  29 GENERIC: inet-pton ( str addrspec -- data )
  30
  31 : make-sockaddr/size ( addrspec -- sockaddr size )
  32     [ make-sockaddr ] [ sockaddr-size ] bi ;
  33
  34 : empty-sockaddr/size ( addrspec -- sockaddr size )
  35     [ empty-sockaddr ] [ sockaddr-size ] bi ;
  36
  37 GENERIC: parse-sockaddr ( sockaddr addrspec -- newaddrspec )
  38
  39 TUPLE: local path ;
  40
  41 : <local> ( path -- addrspec )
  42     normalize-path local boa ;
  43
  44 M: local present path>> "Unix domain socket: " prepend ;
  45
  46 TUPLE: abstract-inet host port ;
  47
  48 M: abstract-inet present
  49     [ host>> ":" ] [ port>> number>string ] bi 3append ;
  50
  51 TUPLE: inet4 < abstract-inet ;
  52
  53 C: <inet4> inet4
  54
  55 M: inet4 inet-ntop ( data addrspec -- str )
  56     drop 4 memory>byte-array [ number>string ] { } map-as "." join ;
  57
  58 ERROR: invalid-inet4 string reason ;
  59
  60 M: invalid-inet4 summary drop "Invalid IPv4 address" ;
  61
  62 M: inet4 inet-pton ( str addrspec -- data )
  63     drop
  64     [
  65         "." split dup length 4 = [
  66             "Must have four components" throw
  67         ] unless
  68         [
  69             string>number
  70             [ "Dotted component not a number" throw ] unless*
  71         ] B{ } map-as
  72     ] [ invalid-inet4 ] recover ;
  73
  74 M: inet4 address-size drop 4 ;
  75
  76 M: inet4 protocol-family drop PF_INET ;
  77
  78 M: inet4 sockaddr-size drop "sockaddr-in" heap-size ;
  79
  80 M: inet4 empty-sockaddr drop "sockaddr-in" <c-object> ;
  81
  82 M: inet4 make-sockaddr ( inet -- sockaddr )
  83     "sockaddr-in" <c-object>
  84     AF_INET over set-sockaddr-in-family
  85     over port>> htons over set-sockaddr-in-port
  86     over host>>
  87     "0.0.0.0" or
  88     rot inet-pton *uint over set-sockaddr-in-addr ;
  89
  90 M: inet4 parse-sockaddr
  91     [ dup sockaddr-in-addr <uint> ] dip inet-ntop
  92     swap sockaddr-in-port ntohs <inet4> ;
  93
  94 TUPLE: inet6 < abstract-inet ;
  95
  96 C: <inet6> inet6
  97
  98 M: inet6 inet-ntop ( data addrspec -- str )
  99     drop 16 memory>byte-array 2 <groups> [ be> >hex ] map ":" join ;
 100
 101 ERROR: invalid-inet6 string reason ;
 102
 103 M: invalid-inet6 summary drop "Invalid IPv6 address" ;
 104
 105 <PRIVATE
 106
 107 : parse-inet6 ( string -- seq )
 108     [ f ] [
 109         ":" split [
 110             hex> [ "Component not a number" throw ] unless*
 111         ] { } map-as
 112     ] if-empty ;
 113
 114 : pad-inet6 ( string1 string2 -- seq )
 115     2dup [ length ] bi@ + 8 swap -
 116     dup 0 < [ "More than 8 components" throw ] when
 117     <byte-array> glue ;
 118
 119 : inet6-bytes ( seq -- bytes )
 120     [ 2 >be ] { } map-as B{ } concat-as ;
 121
 122 PRIVATE>
 123
 124 M: inet6 inet-pton ( str addrspec -- data )
 125     drop
 126     [
 127         "::" split1 [ parse-inet6 ] bi@ pad-inet6 inet6-bytes
 128     ] [ invalid-inet6 ] recover ;
 129
 130 M: inet6 address-size drop 16 ;
 131
 132 M: inet6 protocol-family drop PF_INET6 ;
 133
 134 M: inet6 sockaddr-size drop "sockaddr-in6" heap-size ;
 135
 136 M: inet6 empty-sockaddr drop "sockaddr-in6" <c-object> ;
 137
 138 M: inet6 make-sockaddr ( inet -- sockaddr )
 139     "sockaddr-in6" <c-object>
 140     AF_INET6 over set-sockaddr-in6-family
 141     over port>> htons over set-sockaddr-in6-port
 142     over host>> "::" or
 143     rot inet-pton over set-sockaddr-in6-addr ;
 144
 145 M: inet6 parse-sockaddr
 146     [ dup sockaddr-in6-addr ] dip inet-ntop
 147     swap sockaddr-in6-port ntohs <inet6> ;
 148
 149 : addrspec-of-family ( af -- addrspec )
 150     {
 151         { AF_INET [ T{ inet4 } ] }
 152         { AF_INET6 [ T{ inet6 } ] }
 153         { AF_UNIX [ T{ local } ] }
 154         [ drop f ]
 155     } case ;
 156
 157 M: f parse-sockaddr nip ;
 158
 159 GENERIC: (get-local-address) ( handle remote -- sockaddr )
 160
 161 : get-local-address ( handle remote -- local )
 162     [ (get-local-address) ] keep parse-sockaddr ;
 163
 164 GENERIC: (get-remote-address) ( handle remote -- sockaddr )
 165
 166 : get-remote-address ( handle local -- remote )
 167     [ (get-remote-address) ] keep parse-sockaddr ;
 168
 169 : <ports> ( handle -- input-port output-port )
 170     [
 171         [ <input-port> |dispose ] [ <output-port> |dispose ] bi
 172     ] with-destructors ;
 173
 174 GENERIC: establish-connection ( client-out remote -- )
 175
 176 GENERIC: ((client)) ( remote -- handle )
 177
 178 GENERIC: (client) ( remote -- client-in client-out local )
 179
 180 M: array (client) [ (client) 3array ] attempt-all first3 ;
 181
 182 M: object (client) ( remote -- client-in client-out local )
 183     [
 184         [ ((client)) ] keep
 185         [
 186             [ <ports> [ |dispose ] bi@ dup ] dip
 187             establish-connection
 188         ]
 189         [ get-local-address ]
 190         2bi
 191     ] with-destructors ;
 192
 193 : <client> ( remote encoding -- stream local )
 194     [ (client) ] dip swap [ <encoder-duplex> ] dip ;
 195
 196 SYMBOL: local-address
 197
 198 SYMBOL: remote-address
 199
 200 : with-client ( remote encoding quot -- )
 201     [
 202         [
 203             over remote-address set
 204             <client> local-address set
 205         ] dip with-stream
 206     ] with-scope ; inline
 207
 208 TUPLE: server-port < port addr encoding ;
 209
 210 : check-server-port ( port -- port )
 211     dup check-disposed
 212     dup server-port? [ "Not a server port" throw ] unless ; inline
 213
 214 GENERIC: (server) ( addrspec -- handle )
 215
 216 : <server> ( addrspec encoding -- server )
 217     [
 218         [ (server) ] keep
 219         [ drop server-port <port> ] [ get-local-address ] 2bi
 220         >>addr
 221     ] dip >>encoding ;
 222
 223 GENERIC: (accept) ( server addrspec -- handle sockaddr )
 224
 225 : accept ( server -- client remote )
 226     [
 227         dup addr>>
 228         [ (accept) ] keep
 229         parse-sockaddr swap
 230         <ports>
 231     ] keep encoding>> <encoder-duplex> swap ;
 232
 233 TUPLE: datagram-port < port addr ;
 234
 235 HOOK: (datagram) io-backend ( addr -- datagram )
 236
 237 : <datagram> ( addrspec -- datagram )
 238     [
 239         [ (datagram) |dispose ] keep
 240         [ drop datagram-port <port> ] [ get-local-address ] 2bi
 241         >>addr
 242     ] with-destructors ;
 243
 244 : check-datagram-port ( port -- port )
 245     dup check-disposed
 246     dup datagram-port? [ "Not a datagram port" throw ] unless ; inline
 247
 248 HOOK: (receive) io-backend ( datagram -- packet addrspec )
 249
 250 : receive ( datagram -- packet addrspec )
 251     check-datagram-port
 252     [ (receive) ] [ addr>> ] bi parse-sockaddr ;
 253
 254 : check-datagram-send ( packet addrspec port -- packet addrspec port )
 255     check-datagram-port
 256     2dup addr>> [ class ] bi@ assert=
 257     pick class byte-array assert= ;
 258
 259 HOOK: (send) io-backend ( packet addrspec datagram -- )
 260
 261 : send ( packet addrspec datagram -- )
 262     check-datagram-send (send) ;
 263
 264 : addrinfo>addrspec ( addrinfo -- addrspec )
 265     [ addrinfo-addr ] [ addrinfo-family addrspec-of-family ] bi
 266     parse-sockaddr ;
 267
 268 : parse-addrinfo-list ( addrinfo -- seq )
 269     [ addrinfo-next ] follow
 270     [ addrinfo>addrspec ] map
 271     sift ;
 272
 273 HOOK: addrinfo-error io-backend ( n -- )
 274
 275 GENERIC: resolve-host ( addrspec -- seq )
 276
 277 TUPLE: inet < abstract-inet ;
 278
 279 C: <inet> inet
 280
 281 : resolve-passive-host ( -- addrspecs )
 282     { T{ inet6 f "::" f } T{ inet4 f "0.0.0.0" f } } [ clone ] map ;
 283
 284 : prepare-addrinfo ( -- addrinfo )
 285     "addrinfo" <c-object>
 286     PF_UNSPEC over set-addrinfo-family
 287     IPPROTO_TCP over set-addrinfo-protocol ;
 288
 289 : fill-in-ports ( addrspecs port -- addrspecs )
 290     '[ _ >>port ] map ;
 291
 292 M: inet resolve-host
 293     [ port>> ] [ host>> ] bi [
 294         f prepare-addrinfo f <void*>
 295         [ getaddrinfo addrinfo-error ] keep *void*
 296         [ parse-addrinfo-list ] keep freeaddrinfo
 297     ] [ resolve-passive-host ] if*
 298     swap fill-in-ports ;
 299
 300 M: f resolve-host drop { } ;
 301
 302 M: object resolve-host 1array ;
 303
 304 : host-name ( -- string )
 305     256 <byte-array> dup dup length gethostname
 306     zero? [ "gethostname failed" throw ] unless
 307     ascii alien>string ;
 308
 309 M: inet (client) resolve-host (client) ;
 310
 311 ERROR: invalid-inet-server addrspec ;
 312
 313 M: invalid-inet-server summary
 314     drop "Cannot use <server> with <inet>; use <inet4> or <inet6> instead" ;
 315
 316 M: inet (server)
 317     invalid-inet-server ;
 318
 319 {
 320     { [ os unix? ] [ "io.sockets.unix" require ] }
 321     { [ os winnt? ] [ "io.sockets.windows.nt" require ] }
 322 } cond