basis/io/sockets/sockets.factor

   1 ! Copyright (C) 2007, 2008 Slava Pestov, Doug Coleman,
   2 ! Daniel Ehrenberg.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: generic kernel io.backend namespaces continuations
   5 sequences arrays io.encodings io.ports io.streams.duplex
   6 io.encodings.ascii alien.strings io.binary accessors destructors
   7 classes debugger byte-arrays system combinators parser
   8 alien.c-types math.parser splitting grouping
   9 math assocs summary system vocabs.loader combinators ;
  10 IN: io.sockets
  11
  12 << {
  13     { [ os windows? ] [ "windows.winsock" ] }
  14     { [ os unix? ] [ "unix" ] }
  15 } cond use+ >>
  16
  17 ! Addressing
  18 GENERIC: protocol-family ( addrspec -- af )
  19
  20 GENERIC: sockaddr-type ( addrspec -- type )
  21
  22 GENERIC: make-sockaddr ( addrspec -- sockaddr )
  23
  24 GENERIC: address-size ( addrspec -- n )
  25
  26 GENERIC: inet-ntop ( data addrspec -- str )
  27
  28 GENERIC: inet-pton ( str addrspec -- data )
  29
  30 : make-sockaddr/size ( addrspec -- sockaddr size )
  31     [ make-sockaddr ] [ sockaddr-type heap-size ] bi ;
  32
  33 : empty-sockaddr/size ( addrspec -- sockaddr size )
  34     sockaddr-type [ <c-object> ] [ heap-size ] bi ;
  35
  36 GENERIC: parse-sockaddr ( sockaddr addrspec -- newaddrspec )
  37
  38 TUPLE: local path ;
  39
  40 : <local> ( path -- addrspec )
  41     normalize-path local boa ;
  42
  43 TUPLE: inet4 host port ;
  44
  45 C: <inet4> inet4
  46
  47 M: inet4 inet-ntop ( data addrspec -- str )
  48     drop 4 memory>byte-array [ number>string ] { } map-as "." join ;
  49
  50 ERROR: invalid-inet4 string reason ;
  51
  52 M: invalid-inet4 summary drop "Invalid IPv4 address" ;
  53
  54 M: inet4 inet-pton ( str addrspec -- data )
  55     drop
  56     [
  57         "." split dup length 4 = [
  58             "Must have four components" throw
  59         ] unless
  60         [
  61             string>number
  62             [ "Dotted component not a number" throw ] unless*
  63         ] B{ } map-as
  64     ] [ invalid-inet4 ] recover ;
  65
  66 M: inet4 address-size drop 4 ;
  67
  68 M: inet4 protocol-family drop PF_INET ;
  69
  70 M: inet4 sockaddr-type drop "sockaddr-in" c-type ;
  71
  72 M: inet4 make-sockaddr ( inet -- sockaddr )
  73     "sockaddr-in" <c-object>
  74     AF_INET over set-sockaddr-in-family
  75     over inet4-port htons over set-sockaddr-in-port
  76     over inet4-host
  77     "0.0.0.0" or
  78     rot inet-pton *uint over set-sockaddr-in-addr ;
  79
  80 <PRIVATE
  81
  82 SYMBOL: port-override
  83
  84 : (port) ( port -- port' ) port-override get swap or ;
  85
  86 PRIVATE>
  87
  88 M: inet4 parse-sockaddr
  89     >r dup sockaddr-in-addr <uint> r> inet-ntop
  90     swap sockaddr-in-port ntohs (port) <inet4> ;
  91
  92 TUPLE: inet6 host port ;
  93
  94 C: <inet6> inet6
  95
  96 M: inet6 inet-ntop ( data addrspec -- str )
  97     drop 16 memory>byte-array 2 <groups> [ be> >hex ] map ":" join ;
  98
  99 ERROR: invalid-inet6 string reason ;
 100
 101 M: invalid-inet6 summary drop "Invalid IPv6 address" ;
 102
 103 <PRIVATE
 104
 105 : parse-inet6 ( string -- seq )
 106     dup empty? [ drop f ] [
 107         ":" split [
 108             hex> [ "Component not a number" throw ] unless*
 109         ] B{ } map-as
 110     ] if ;
 111
 112 : pad-inet6 ( string1 string2 -- seq )
 113     2dup [ length ] bi@ + 8 swap -
 114     dup 0 < [ "More than 8 components" throw ] when
 115     <byte-array> swap 3append ;
 116
 117 : inet6-bytes ( seq -- bytes )
 118     [ 2 >be ] { } map-as concat >byte-array ;
 119
 120 PRIVATE>
 121
 122 M: inet6 inet-pton ( str addrspec -- data )
 123     drop
 124     [
 125         "::" split1 [ parse-inet6 ] bi@ pad-inet6 inet6-bytes
 126     ] [ invalid-inet6 ] recover ;
 127
 128 M: inet6 address-size drop 16 ;
 129
 130 M: inet6 protocol-family drop PF_INET6 ;
 131
 132 M: inet6 sockaddr-type drop "sockaddr-in6" c-type ;
 133
 134 M: inet6 make-sockaddr ( inet -- sockaddr )
 135     "sockaddr-in6" <c-object>
 136     AF_INET6 over set-sockaddr-in6-family
 137     over inet6-port htons over set-sockaddr-in6-port
 138     over inet6-host "::" or
 139     rot inet-pton over set-sockaddr-in6-addr ;
 140
 141 M: inet6 parse-sockaddr
 142     >r dup sockaddr-in6-addr r> inet-ntop
 143     swap sockaddr-in6-port ntohs (port) <inet6> ;
 144
 145 : addrspec-of-family ( af -- addrspec )
 146     {
 147         { AF_INET [ T{ inet4 } ] }
 148         { AF_INET6 [ T{ inet6 } ] }
 149         { AF_UNIX [ T{ local } ] }
 150         [ drop f ]
 151     } case ;
 152
 153 M: f parse-sockaddr nip ;
 154
 155 GENERIC: (get-local-address) ( handle remote -- sockaddr )
 156
 157 : get-local-address ( handle remote -- local )
 158     [ (get-local-address) ] keep parse-sockaddr ;
 159
 160 GENERIC: (get-remote-address) ( handle remote -- sockaddr )
 161
 162 : get-remote-address ( handle local -- remote )
 163     [ (get-remote-address) ] keep parse-sockaddr ;
 164
 165 : <ports> ( handle -- input-port output-port )
 166     [
 167         [ <input-port> |dispose ] [ <output-port> |dispose ] bi
 168     ] with-destructors ;
 169
 170 GENERIC: establish-connection ( client-out remote -- )
 171
 172 GENERIC: ((client)) ( remote -- handle )
 173
 174 GENERIC: (client) ( remote -- client-in client-out local )
 175
 176 M: array (client) [ (client) 3array ] attempt-all first3 ;
 177
 178 M: object (client) ( remote -- client-in client-out local )
 179     [
 180         [ ((client)) ] keep
 181         [
 182             >r <ports> [ |dispose ] bi@ dup r>
 183             establish-connection
 184         ]
 185         [ get-local-address ]
 186         2bi
 187     ] with-destructors ;
 188
 189 : <client> ( remote encoding -- stream local )
 190     >r (client) -rot r> <encoder-duplex> swap ;
 191
 192 SYMBOL: local-address
 193
 194 : with-client ( remote encoding quot -- )
 195     >r <client> [ local-address set ] curry
 196     r> compose with-stream ; inline
 197
 198 TUPLE: server-port < port addr encoding ;
 199
 200 : check-server-port ( port -- port )
 201     dup check-disposed
 202     dup server-port? [ "Not a server port" throw ] unless ; inline
 203
 204 GENERIC: (server) ( addrspec -- handle )
 205
 206 : <server> ( addrspec encoding -- server )
 207     >r
 208     [ (server) ] keep
 209     [ drop server-port <port> ] [ get-local-address ] 2bi
 210     >>addr r> >>encoding ;
 211
 212 GENERIC: (accept) ( server addrspec -- handle sockaddr )
 213
 214 : accept ( server -- client remote )
 215     [
 216         dup addr>>
 217         [ (accept) ] keep
 218         parse-sockaddr swap
 219         <ports>
 220     ] keep encoding>> <encoder-duplex> swap ;
 221
 222 TUPLE: datagram-port < port addr ;
 223
 224 HOOK: (datagram) io-backend ( addr -- datagram )
 225
 226 : <datagram> ( addrspec -- datagram )
 227     [
 228         [ (datagram) |dispose ] keep
 229         [ drop datagram-port <port> ] [ get-local-address ] 2bi
 230         >>addr
 231     ] with-destructors ;
 232
 233 : check-datagram-port ( port -- port )
 234     dup check-disposed
 235     dup datagram-port? [ "Not a datagram port" throw ] unless ; inline
 236
 237 HOOK: (receive) io-backend ( datagram -- packet addrspec )
 238
 239 : receive ( datagram -- packet addrspec )
 240     check-datagram-port
 241     [ (receive) ] [ addr>> ] bi parse-sockaddr ;
 242
 243 : check-datagram-send ( packet addrspec port -- packet addrspec port )
 244     check-datagram-port
 245     2dup addr>> [ class ] bi@ assert=
 246     pick class byte-array assert= ;
 247
 248 HOOK: (send) io-backend ( packet addrspec datagram -- )
 249
 250 : send ( packet addrspec datagram -- )
 251     check-datagram-send (send) ;
 252
 253 : addrinfo>addrspec ( addrinfo -- addrspec )
 254     [ addrinfo-addr ] [ addrinfo-family addrspec-of-family ] bi
 255     parse-sockaddr ;
 256
 257 : parse-addrinfo-list ( addrinfo -- seq )
 258     [ addrinfo-next ] follow
 259     [ addrinfo>addrspec ] map
 260     sift ;
 261
 262 : prepare-resolve-host ( addrspec -- host' serv' flags )
 263     #! If the port is a number, we resolve for 'http' then
 264     #! change it later. This is a workaround for a FreeBSD
 265     #! getaddrinfo() limitation -- on Windows, Linux and Mac,
 266     #! we can convert a number to a string and pass that as the
 267     #! service name, but on FreeBSD this gives us an unknown
 268     #! service error.
 269     [ host>> ]
 270     [ port>> dup integer? [ port-override set "http" ] when ] bi
 271     over 0 AI_PASSIVE ? ;
 272
 273 HOOK: addrinfo-error io-backend ( n -- )
 274
 275 GENERIC: resolve-host ( addrspec -- seq )
 276
 277 TUPLE: inet host port ;
 278
 279 C: <inet> inet
 280
 281 M: inet resolve-host
 282     [
 283         prepare-resolve-host
 284         "addrinfo" <c-object>
 285         [ set-addrinfo-flags ] keep
 286         PF_UNSPEC over set-addrinfo-family
 287         IPPROTO_TCP over set-addrinfo-protocol
 288         f <void*> [ getaddrinfo addrinfo-error ] keep *void*
 289         [ parse-addrinfo-list ] keep
 290         freeaddrinfo
 291     ] with-scope ;
 292
 293 M: f resolve-host drop { } ;
 294
 295 M: object resolve-host 1array ;
 296
 297 : host-name ( -- string )
 298     256 <byte-array> dup dup length gethostname
 299     zero? [ "gethostname failed" throw ] unless
 300     ascii alien>string ;
 301
 302 M: inet (client) resolve-host (client) ;
 303
 304 ERROR: invalid-inet-server addrspec ;
 305
 306 M: invalid-inet-server summary
 307     drop "Cannot use <server> with <inet>; use <inet4> or <inet6> instead" ;
 308
 309 M: inet (server)
 310     invalid-inet-server ;
 311
 312 {
 313     { [ os unix? ] [ "io.unix.sockets" require ] }
 314     { [ os winnt? ] [ "io.windows.nt.sockets" require ] }
 315     { [ os wince? ] [ "io.windows.ce.sockets" require ] }
 316 } cond