basis/io/sockets/sockets.factor

   1 ! Copyright (C) 2007, 2008 Slava Pestov, Doug Coleman,
   2 ! Daniel Ehrenberg.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: generic kernel io.backend namespaces continuations
   5 sequences arrays io.encodings io.ports io.streams.duplex
   6 io.encodings.ascii alien.strings io.binary accessors destructors
   7 classes debugger byte-arrays system combinators parser
   8 alien.c-types math.parser splitting grouping math assocs summary
   9 system vocabs.loader combinators present ;
  10 IN: io.sockets
  11
  12 << {
  13     { [ os windows? ] [ "windows.winsock" ] }
  14     { [ os unix? ] [ "unix" ] }
  15 } cond use+ >>
  16
  17 ! Addressing
  18 GENERIC: protocol-family ( addrspec -- af )
  19
  20 GENERIC: sockaddr-size ( addrspec -- n )
  21
  22 GENERIC: make-sockaddr ( addrspec -- sockaddr )
  23
  24 GENERIC: empty-sockaddr ( addrspec -- sockaddr )
  25
  26 GENERIC: address-size ( addrspec -- n )
  27
  28 GENERIC: inet-ntop ( data addrspec -- str )
  29
  30 GENERIC: inet-pton ( str addrspec -- data )
  31
  32 : make-sockaddr/size ( addrspec -- sockaddr size )
  33     [ make-sockaddr ] [ sockaddr-size ] bi ;
  34
  35 : empty-sockaddr/size ( addrspec -- sockaddr size )
  36     [ empty-sockaddr ] [ sockaddr-size ] bi ;
  37
  38 GENERIC: parse-sockaddr ( sockaddr addrspec -- newaddrspec )
  39
  40 TUPLE: local path ;
  41
  42 : <local> ( path -- addrspec )
  43     normalize-path local boa ;
  44
  45 M: local present path>> "Unix domain socket: " prepend ;
  46
  47 TUPLE: abstract-inet host port ;
  48
  49 M: abstract-inet present
  50     [ host>> ":" ] [ port>> number>string ] bi 3append ;
  51
  52 TUPLE: inet4 < abstract-inet ;
  53
  54 C: <inet4> inet4
  55
  56 M: inet4 inet-ntop ( data addrspec -- str )
  57     drop 4 memory>byte-array [ number>string ] { } map-as "." join ;
  58
  59 ERROR: invalid-inet4 string reason ;
  60
  61 M: invalid-inet4 summary drop "Invalid IPv4 address" ;
  62
  63 M: inet4 inet-pton ( str addrspec -- data )
  64     drop
  65     [
  66         "." split dup length 4 = [
  67             "Must have four components" throw
  68         ] unless
  69         [
  70             string>number
  71             [ "Dotted component not a number" throw ] unless*
  72         ] B{ } map-as
  73     ] [ invalid-inet4 ] recover ;
  74
  75 M: inet4 address-size drop 4 ;
  76
  77 M: inet4 protocol-family drop PF_INET ;
  78
  79 M: inet4 sockaddr-size drop "sockaddr-in" heap-size ;
  80
  81 M: inet4 empty-sockaddr drop "sockaddr-in" <c-object> ;
  82
  83 M: inet4 make-sockaddr ( inet -- sockaddr )
  84     "sockaddr-in" <c-object>
  85     AF_INET over set-sockaddr-in-family
  86     over port>> htons over set-sockaddr-in-port
  87     over host>>
  88     "0.0.0.0" or
  89     rot inet-pton *uint over set-sockaddr-in-addr ;
  90
  91 M: inet4 parse-sockaddr
  92     >r dup sockaddr-in-addr <uint> r> inet-ntop
  93     swap sockaddr-in-port ntohs <inet4> ;
  94
  95 TUPLE: inet6 < abstract-inet ;
  96
  97 C: <inet6> inet6
  98
  99 M: inet6 inet-ntop ( data addrspec -- str )
 100     drop 16 memory>byte-array 2 <groups> [ be> >hex ] map ":" join ;
 101
 102 ERROR: invalid-inet6 string reason ;
 103
 104 M: invalid-inet6 summary drop "Invalid IPv6 address" ;
 105
 106 <PRIVATE
 107
 108 : parse-inet6 ( string -- seq )
 109     [ f ] [
 110         ":" split [
 111             hex> [ "Component not a number" throw ] unless*
 112         ] B{ } map-as
 113     ] if-empty ;
 114
 115 : pad-inet6 ( string1 string2 -- seq )
 116     2dup [ length ] bi@ + 8 swap -
 117     dup 0 < [ "More than 8 components" throw ] when
 118     <byte-array> swap 3append ;
 119
 120 : inet6-bytes ( seq -- bytes )
 121     [ 2 >be ] { } map-as concat >byte-array ;
 122
 123 PRIVATE>
 124
 125 M: inet6 inet-pton ( str addrspec -- data )
 126     drop
 127     [
 128         "::" split1 [ parse-inet6 ] bi@ pad-inet6 inet6-bytes
 129     ] [ invalid-inet6 ] recover ;
 130
 131 M: inet6 address-size drop 16 ;
 132
 133 M: inet6 protocol-family drop PF_INET6 ;
 134
 135 M: inet6 sockaddr-size drop "sockaddr-in6" heap-size ;
 136
 137 M: inet6 empty-sockaddr drop "sockaddr-in6" <c-object> ;
 138
 139 M: inet6 make-sockaddr ( inet -- sockaddr )
 140     "sockaddr-in6" <c-object>
 141     AF_INET6 over set-sockaddr-in6-family
 142     over port>> htons over set-sockaddr-in6-port
 143     over host>> "::" or
 144     rot inet-pton over set-sockaddr-in6-addr ;
 145
 146 M: inet6 parse-sockaddr
 147     >r dup sockaddr-in6-addr r> inet-ntop
 148     swap sockaddr-in6-port ntohs <inet6> ;
 149
 150 : addrspec-of-family ( af -- addrspec )
 151     {
 152         { AF_INET [ T{ inet4 } ] }
 153         { AF_INET6 [ T{ inet6 } ] }
 154         { AF_UNIX [ T{ local } ] }
 155         [ drop f ]
 156     } case ;
 157
 158 M: f parse-sockaddr nip ;
 159
 160 GENERIC: (get-local-address) ( handle remote -- sockaddr )
 161
 162 : get-local-address ( handle remote -- local )
 163     [ (get-local-address) ] keep parse-sockaddr ;
 164
 165 GENERIC: (get-remote-address) ( handle remote -- sockaddr )
 166
 167 : get-remote-address ( handle local -- remote )
 168     [ (get-remote-address) ] keep parse-sockaddr ;
 169
 170 : <ports> ( handle -- input-port output-port )
 171     [
 172         [ <input-port> |dispose ] [ <output-port> |dispose ] bi
 173     ] with-destructors ;
 174
 175 GENERIC: establish-connection ( client-out remote -- )
 176
 177 GENERIC: ((client)) ( remote -- handle )
 178
 179 GENERIC: (client) ( remote -- client-in client-out local )
 180
 181 M: array (client) [ (client) 3array ] attempt-all first3 ;
 182
 183 M: object (client) ( remote -- client-in client-out local )
 184     [
 185         [ ((client)) ] keep
 186         [
 187             >r <ports> [ |dispose ] bi@ dup r>
 188             establish-connection
 189         ]
 190         [ get-local-address ]
 191         2bi
 192     ] with-destructors ;
 193
 194 : <client> ( remote encoding -- stream local )
 195     >r (client) -rot r> <encoder-duplex> swap ;
 196
 197 SYMBOL: local-address
 198
 199 : with-client ( remote encoding quot -- )
 200     >r <client> [ local-address set ] curry
 201     r> compose with-stream ; inline
 202
 203 TUPLE: server-port < port addr encoding ;
 204
 205 : check-server-port ( port -- port )
 206     dup check-disposed
 207     dup server-port? [ "Not a server port" throw ] unless ; inline
 208
 209 GENERIC: (server) ( addrspec -- handle )
 210
 211 : <server> ( addrspec encoding -- server )
 212     >r
 213     [ (server) ] keep
 214     [ drop server-port <port> ] [ get-local-address ] 2bi
 215     >>addr r> >>encoding ;
 216
 217 GENERIC: (accept) ( server addrspec -- handle sockaddr )
 218
 219 : accept ( server -- client remote )
 220     [
 221         dup addr>>
 222         [ (accept) ] keep
 223         parse-sockaddr swap
 224         <ports>
 225     ] keep encoding>> <encoder-duplex> swap ;
 226
 227 TUPLE: datagram-port < port addr ;
 228
 229 HOOK: (datagram) io-backend ( addr -- datagram )
 230
 231 : <datagram> ( addrspec -- datagram )
 232     [
 233         [ (datagram) |dispose ] keep
 234         [ drop datagram-port <port> ] [ get-local-address ] 2bi
 235         >>addr
 236     ] with-destructors ;
 237
 238 : check-datagram-port ( port -- port )
 239     dup check-disposed
 240     dup datagram-port? [ "Not a datagram port" throw ] unless ; inline
 241
 242 HOOK: (receive) io-backend ( datagram -- packet addrspec )
 243
 244 : receive ( datagram -- packet addrspec )
 245     check-datagram-port
 246     [ (receive) ] [ addr>> ] bi parse-sockaddr ;
 247
 248 : check-datagram-send ( packet addrspec port -- packet addrspec port )
 249     check-datagram-port
 250     2dup addr>> [ class ] bi@ assert=
 251     pick class byte-array assert= ;
 252
 253 HOOK: (send) io-backend ( packet addrspec datagram -- )
 254
 255 : send ( packet addrspec datagram -- )
 256     check-datagram-send (send) ;
 257
 258 : addrinfo>addrspec ( addrinfo -- addrspec )
 259     [ addrinfo-addr ] [ addrinfo-family addrspec-of-family ] bi
 260     parse-sockaddr ;
 261
 262 : parse-addrinfo-list ( addrinfo -- seq )
 263     [ addrinfo-next ] follow
 264     [ addrinfo>addrspec ] map
 265     sift ;
 266
 267 HOOK: addrinfo-error io-backend ( n -- )
 268
 269 GENERIC: resolve-host ( addrspec -- seq )
 270
 271 TUPLE: inet < abstract-inet ;
 272
 273 C: <inet> inet
 274
 275 : resolve-passive-host ( -- addrspecs )
 276     { T{ inet6 f "::" f } T{ inet4 f "0.0.0.0" f } } [ clone ] map ;
 277
 278 : prepare-addrinfo ( -- addrinfo )
 279     "addrinfo" <c-object>
 280     PF_UNSPEC over set-addrinfo-family
 281     IPPROTO_TCP over set-addrinfo-protocol ;
 282
 283 : fill-in-ports ( addrspecs port -- addrspecs )
 284     [ >>port ] curry map ;
 285
 286 M: inet resolve-host
 287     [ port>> ] [ host>> ] bi [
 288         f prepare-addrinfo f <void*>
 289         [ getaddrinfo addrinfo-error ] keep *void*
 290         [ parse-addrinfo-list ] keep freeaddrinfo
 291     ] [ resolve-passive-host ] if*
 292     swap fill-in-ports ;
 293
 294 M: f resolve-host drop { } ;
 295
 296 M: object resolve-host 1array ;
 297
 298 : host-name ( -- string )
 299     256 <byte-array> dup dup length gethostname
 300     zero? [ "gethostname failed" throw ] unless
 301     ascii alien>string ;
 302
 303 M: inet (client) resolve-host (client) ;
 304
 305 ERROR: invalid-inet-server addrspec ;
 306
 307 M: invalid-inet-server summary
 308     drop "Cannot use <server> with <inet>; use <inet4> or <inet6> instead" ;
 309
 310 M: inet (server)
 311     invalid-inet-server ;
 312
 313 {
 314     { [ os unix? ] [ "io.unix.sockets" require ] }
 315     { [ os winnt? ] [ "io.windows.nt.sockets" require ] }
 316     { [ os wince? ] [ "io.windows.ce.sockets" require ] }
 317 } cond