basis/io/sockets/sockets.factor

   1 ! Copyright (C) 2007, 2008 Slava Pestov, Doug Coleman,
   2 ! Daniel Ehrenberg.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: generic kernel io.backend namespaces continuations sequences
   5 arrays io.encodings io.ports io.streams.duplex io.encodings.ascii
   6 alien.strings io.binary accessors destructors classes byte-arrays
   7 parser alien.c-types math.parser splitting grouping math assocs
   8 summary system vocabs.loader combinators present fry vocabs.parser
   9 classes.struct alien.data ;
  10 IN: io.sockets
  11
  12 << {
  13     { [ os windows? ] [ "windows.winsock" ] }
  14     { [ os unix? ] [ "unix" ] }
  15 } cond use-vocab >>
  16
  17 ! Addressing
  18 <PRIVATE
  19
  20 GENERIC: protocol-family ( addrspec -- af )
  21
  22 GENERIC: sockaddr-size ( addrspec -- n )
  23
  24 GENERIC: make-sockaddr ( addrspec -- sockaddr )
  25
  26 GENERIC: empty-sockaddr ( addrspec -- sockaddr )
  27
  28 GENERIC: address-size ( addrspec -- n )
  29
  30 GENERIC: inet-ntop ( data addrspec -- str )
  31
  32 GENERIC: inet-pton ( str addrspec -- data )
  33
  34 : make-sockaddr/size ( addrspec -- sockaddr size )
  35     [ make-sockaddr ] [ sockaddr-size ] bi ;
  36
  37 : empty-sockaddr/size ( addrspec -- sockaddr size )
  38     [ empty-sockaddr ] [ sockaddr-size ] bi ;
  39
  40 GENERIC: parse-sockaddr ( sockaddr addrspec -- newaddrspec )
  41
  42 HOOK: sockaddr-of-family os ( alien af -- sockaddr )
  43
  44 HOOK: addrspec-of-family os ( af -- addrspec )
  45
  46 PRIVATE>
  47
  48 TUPLE: abstract-inet host port ;
  49
  50 M: abstract-inet present
  51     [ host>> ":" ] [ port>> number>string ] bi 3append ;
  52
  53 TUPLE: local path ;
  54
  55 : <local> ( path -- addrspec )
  56     normalize-path local boa ;
  57
  58 M: local present path>> "Unix domain socket: " prepend ;
  59
  60 TUPLE: inet4 < abstract-inet ;
  61
  62 C: <inet4> inet4
  63
  64 M: inet4 inet-ntop ( data addrspec -- str )
  65     drop 4 memory>byte-array [ number>string ] { } map-as "." join ;
  66
  67 ERROR: invalid-inet4 string reason ;
  68
  69 M: invalid-inet4 summary drop "Invalid IPv4 address" ;
  70
  71 M: inet4 inet-pton ( str addrspec -- data )
  72     drop
  73     [
  74         "." split dup length 4 = [
  75             "Must have four components" throw
  76         ] unless
  77         [
  78             string>number
  79             [ "Dotted component not a number" throw ] unless*
  80         ] B{ } map-as
  81     ] [ invalid-inet4 ] recover ;
  82
  83 M: inet4 address-size drop 4 ;
  84
  85 M: inet4 protocol-family drop PF_INET ;
  86
  87 M: inet4 sockaddr-size drop sockaddr-in heap-size ;
  88
  89 M: inet4 empty-sockaddr drop sockaddr-in <struct> ;
  90
  91 M: inet4 make-sockaddr ( inet -- sockaddr )
  92     sockaddr-in <struct>
  93         AF_INET >>family
  94         swap [ port>> htons >>port ]
  95             [ host>> "0.0.0.0" or ]
  96             [ inet-pton *uint >>addr ] tri ;
  97
  98 M: inet4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
  99     [ [ addr>> <uint> ] dip inet-ntop ]
 100     [ drop port>> ntohs ] 2bi <inet4> ;
 101
 102 TUPLE: inet6 < abstract-inet ;
 103
 104 C: <inet6> inet6
 105
 106 M: inet6 inet-ntop ( data addrspec -- str )
 107     drop 16 memory>byte-array 2 <groups> [ be> >hex ] map ":" join ;
 108
 109 ERROR: invalid-inet6 string reason ;
 110
 111 M: invalid-inet6 summary drop "Invalid IPv6 address" ;
 112
 113 <PRIVATE
 114
 115 : parse-inet6 ( string -- seq )
 116     [ f ] [
 117         ":" split [
 118             hex> [ "Component not a number" throw ] unless*
 119         ] { } map-as
 120     ] if-empty ;
 121
 122 : pad-inet6 ( string1 string2 -- seq )
 123     2dup [ length ] bi@ + 8 swap -
 124     dup 0 < [ "More than 8 components" throw ] when
 125     <byte-array> glue ;
 126
 127 : inet6-bytes ( seq -- bytes )
 128     [ 2 >be ] { } map-as B{ } concat-as ;
 129
 130 PRIVATE>
 131
 132 M: inet6 inet-pton ( str addrspec -- data )
 133     drop
 134     [
 135         "::" split1 [ parse-inet6 ] bi@ pad-inet6 inet6-bytes
 136     ] [ invalid-inet6 ] recover ;
 137
 138 M: inet6 address-size drop 16 ;
 139
 140 M: inet6 protocol-family drop PF_INET6 ;
 141
 142 M: inet6 sockaddr-size drop sockaddr-in6 heap-size ;
 143
 144 M: inet6 empty-sockaddr drop sockaddr-in6 <struct> ;
 145
 146 M: inet6 make-sockaddr ( inet -- sockaddr )
 147     sockaddr-in6 <struct>
 148         AF_INET6 >>family
 149         swap [ port>> htons >>port ]
 150             [ host>> "::" or ]
 151             [ inet-pton >>addr ] tri ;
 152
 153 M: inet6 parse-sockaddr
 154     [ [ addr>> ] dip inet-ntop ]
 155     [ drop port>> ntohs ] 2bi <inet6> ;
 156
 157 M: f parse-sockaddr nip ;
 158
 159 <PRIVATE
 160
 161 GENERIC: (get-local-address) ( handle remote -- sockaddr )
 162
 163 : get-local-address ( handle remote -- local )
 164     [ (get-local-address) ] keep parse-sockaddr ;
 165
 166 GENERIC: (get-remote-address) ( handle remote -- sockaddr )
 167
 168 : get-remote-address ( handle local -- remote )
 169     [ (get-remote-address) ] keep parse-sockaddr ;
 170
 171 : <ports> ( handle -- input-port output-port )
 172     [
 173         [ <input-port> |dispose ] [ <output-port> |dispose ] bi
 174     ] with-destructors ;
 175
 176 SYMBOL: bind-local-address
 177
 178 GENERIC: establish-connection ( client-out remote -- )
 179
 180 GENERIC: ((client)) ( remote -- handle )
 181
 182 GENERIC: (client) ( remote -- client-in client-out local )
 183
 184 M: array (client) [ (client) 3array ] attempt-all first3 ;
 185
 186 M: object (client) ( remote -- client-in client-out local )
 187     [
 188         [ ((client)) ] keep
 189         [
 190             [ <ports> [ |dispose ] bi@ dup ] dip
 191             establish-connection
 192         ]
 193         [ get-local-address ]
 194         2bi
 195     ] with-destructors ;
 196
 197 TUPLE: server-port < port addr encoding ;
 198
 199 : check-server-port ( port -- port )
 200     dup check-disposed
 201     dup server-port? [ "Not a server port" throw ] unless ; inline
 202
 203 GENERIC: (server) ( addrspec -- handle )
 204
 205 GENERIC: (accept) ( server addrspec -- handle sockaddr )
 206
 207 TUPLE: datagram-port < port addr ;
 208
 209 HOOK: (datagram) io-backend ( addr -- datagram )
 210
 211 : check-datagram-port ( port -- port )
 212     dup check-disposed
 213     dup datagram-port? [ "Not a datagram port" throw ] unless ; inline
 214
 215 HOOK: (receive) io-backend ( datagram -- packet addrspec )
 216
 217 : check-datagram-send ( packet addrspec port -- packet addrspec port )
 218     check-datagram-port
 219     2dup addr>> [ class ] bi@ assert=
 220     pick class byte-array assert= ;
 221
 222 HOOK: (send) io-backend ( packet addrspec datagram -- )
 223
 224 : addrinfo>addrspec ( addrinfo -- addrspec )
 225     [ [ addr>> ] [ family>> ] bi sockaddr-of-family ]
 226     [ family>> addrspec-of-family ] bi
 227     parse-sockaddr ;
 228
 229 : parse-addrinfo-list ( addrinfo -- seq )
 230     [ next>> dup [ addrinfo memory>struct ] when ] follow
 231     [ addrinfo>addrspec ] map
 232     sift ;
 233
 234 HOOK: addrinfo-error io-backend ( n -- )
 235
 236 : resolve-passive-host ( -- addrspecs )
 237     { T{ inet6 f "::" f } T{ inet4 f "0.0.0.0" f } } [ clone ] map ;
 238
 239 : prepare-addrinfo ( -- addrinfo )
 240     addrinfo <struct>
 241         PF_UNSPEC >>family
 242         IPPROTO_TCP >>protocol ;
 243
 244 : fill-in-ports ( addrspecs port -- addrspecs )
 245     '[ _ >>port ] map ;
 246
 247 PRIVATE>
 248
 249 : <client> ( remote encoding -- stream local )
 250     [ (client) ] dip swap [ <encoder-duplex> ] dip ;
 251
 252 SYMBOL: local-address
 253
 254 SYMBOL: remote-address
 255
 256 : with-client ( remote encoding quot -- )
 257     [
 258         [
 259             over remote-address set
 260             <client> local-address set
 261         ] dip with-stream
 262     ] with-scope ; inline
 263
 264 : <server> ( addrspec encoding -- server )
 265     [
 266         [ (server) ] keep
 267         [ drop server-port <port> ] [ get-local-address ] 2bi
 268         >>addr
 269     ] dip >>encoding ;
 270
 271 : accept ( server -- client remote )
 272     [
 273         dup addr>>
 274         [ (accept) ] keep
 275         parse-sockaddr swap
 276         <ports>
 277     ] keep encoding>> <encoder-duplex> swap ;
 278
 279 : <datagram> ( addrspec -- datagram )
 280     [
 281         [ (datagram) |dispose ] keep
 282         [ drop datagram-port <port> ] [ get-local-address ] 2bi
 283         >>addr
 284     ] with-destructors ;
 285
 286 : receive ( datagram -- packet addrspec )
 287     check-datagram-port
 288     [ (receive) ] [ addr>> ] bi parse-sockaddr ;
 289
 290 : send ( packet addrspec datagram -- )
 291     check-datagram-send (send) ;
 292
 293 GENERIC: resolve-host ( addrspec -- seq )
 294
 295 TUPLE: inet < abstract-inet ;
 296
 297 C: <inet> inet
 298
 299 M: inet resolve-host
 300     [ port>> ] [ host>> ] bi [
 301         f prepare-addrinfo f <void*>
 302         [ getaddrinfo addrinfo-error ] keep *void* addrinfo memory>struct
 303         [ parse-addrinfo-list ] keep freeaddrinfo
 304     ] [ resolve-passive-host ] if*
 305     swap fill-in-ports ;
 306
 307 M: f resolve-host drop { } ;
 308
 309 M: object resolve-host 1array ;
 310
 311 : host-name ( -- string )
 312     256 <byte-array> dup dup length gethostname
 313     zero? [ "gethostname failed" throw ] unless
 314     ascii alien>string ;
 315
 316 M: inet (client) resolve-host (client) ;
 317
 318 ERROR: invalid-inet-server addrspec ;
 319
 320 M: invalid-inet-server summary
 321     drop "Cannot use <server> with <inet>; use <inet4> or <inet6> instead" ;
 322
 323 M: inet (server)
 324     invalid-inet-server ;
 325
 326 ERROR: invalid-local-address addrspec ;
 327
 328 M: invalid-local-address summary
 329     drop "Cannot use with-local-address with <inet>; use <inet4> or <inet6> instead" ;
 330
 331 : with-local-address ( addr quot -- )
 332     [
 333         [ ] [ inet4? ] [ inet6? ] tri or
 334         [ bind-local-address ]
 335         [ invalid-local-address ] if
 336     ] dip with-variable ; inline
 337
 338 {
 339     { [ os unix? ] [ "io.sockets.unix" require ] }
 340     { [ os winnt? ] [ "io.sockets.windows.nt" require ] }
 341 } cond