basis/io/sockets/sockets.factor

   1 ! Copyright (C) 2007, 2008 Slava Pestov, Doug Coleman,
   2 ! Daniel Ehrenberg.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: generic kernel io.backend namespaces continuations sequences
   5 arrays io.encodings io.ports io.streams.duplex io.encodings.ascii
   6 alien.strings io.binary accessors destructors classes byte-arrays
   7 parser alien.c-types math.parser splitting grouping math assocs
   8 summary system vocabs.loader combinators present fry vocabs.parser
   9 classes.struct ;
  10 IN: io.sockets
  11
  12 << {
  13     { [ os windows? ] [ "windows.winsock" ] }
  14     { [ os unix? ] [ "unix" ] }
  15 } cond use-vocab >>
  16
  17 ! Addressing
  18 GENERIC: protocol-family ( addrspec -- af )
  19
  20 GENERIC: sockaddr-size ( addrspec -- n )
  21
  22 GENERIC: make-sockaddr ( addrspec -- sockaddr )
  23
  24 GENERIC: empty-sockaddr ( addrspec -- sockaddr )
  25
  26 GENERIC: address-size ( addrspec -- n )
  27
  28 GENERIC: inet-ntop ( data addrspec -- str )
  29
  30 GENERIC: inet-pton ( str addrspec -- data )
  31
  32 : make-sockaddr/size ( addrspec -- sockaddr size )
  33     [ make-sockaddr ] [ sockaddr-size ] bi ;
  34
  35 : empty-sockaddr/size ( addrspec -- sockaddr size )
  36     [ empty-sockaddr ] [ sockaddr-size ] bi ;
  37
  38 GENERIC: parse-sockaddr ( sockaddr addrspec -- newaddrspec )
  39
  40 TUPLE: local path ;
  41
  42 : <local> ( path -- addrspec )
  43     normalize-path local boa ;
  44
  45 M: local present path>> "Unix domain socket: " prepend ;
  46
  47 TUPLE: abstract-inet host port ;
  48
  49 M: abstract-inet present
  50     [ host>> ":" ] [ port>> number>string ] bi 3append ;
  51
  52 TUPLE: inet4 < abstract-inet ;
  53
  54 C: <inet4> inet4
  55
  56 M: inet4 inet-ntop ( data addrspec -- str )
  57     drop 4 memory>byte-array [ number>string ] { } map-as "." join ;
  58
  59 ERROR: invalid-inet4 string reason ;
  60
  61 M: invalid-inet4 summary drop "Invalid IPv4 address" ;
  62
  63 M: inet4 inet-pton ( str addrspec -- data )
  64     drop
  65     [
  66         "." split dup length 4 = [
  67             "Must have four components" throw
  68         ] unless
  69         [
  70             string>number
  71             [ "Dotted component not a number" throw ] unless*
  72         ] B{ } map-as
  73     ] [ invalid-inet4 ] recover ;
  74
  75 M: inet4 address-size drop 4 ;
  76
  77 M: inet4 protocol-family drop PF_INET ;
  78
  79 M: inet4 sockaddr-size drop sockaddr-in heap-size ;
  80
  81 M: inet4 empty-sockaddr drop sockaddr-in <struct> ;
  82
  83 M: inet4 make-sockaddr ( inet -- sockaddr )
  84     sockaddr-in <struct>
  85         AF_INET >>family
  86         swap [ port>> htons >>port ]
  87             [ host>> "0.0.0.0" or ]
  88             [ inet-pton *uint >>addr ] tri ;
  89
  90 M: inet4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
  91     [ [ addr>> <uint> ] dip inet-ntop ]
  92     [ drop port>> ntohs ] 2bi <inet4> ;
  93
  94 TUPLE: inet6 < abstract-inet ;
  95
  96 C: <inet6> inet6
  97
  98 M: inet6 inet-ntop ( data addrspec -- str )
  99     drop 16 memory>byte-array 2 <groups> [ be> >hex ] map ":" join ;
 100
 101 ERROR: invalid-inet6 string reason ;
 102
 103 M: invalid-inet6 summary drop "Invalid IPv6 address" ;
 104
 105 <PRIVATE
 106
 107 : parse-inet6 ( string -- seq )
 108     [ f ] [
 109         ":" split [
 110             hex> [ "Component not a number" throw ] unless*
 111         ] { } map-as
 112     ] if-empty ;
 113
 114 : pad-inet6 ( string1 string2 -- seq )
 115     2dup [ length ] bi@ + 8 swap -
 116     dup 0 < [ "More than 8 components" throw ] when
 117     <byte-array> glue ;
 118
 119 : inet6-bytes ( seq -- bytes )
 120     [ 2 >be ] { } map-as B{ } concat-as ;
 121
 122 PRIVATE>
 123
 124 M: inet6 inet-pton ( str addrspec -- data )
 125     drop
 126     [
 127         "::" split1 [ parse-inet6 ] bi@ pad-inet6 inet6-bytes
 128     ] [ invalid-inet6 ] recover ;
 129
 130 M: inet6 address-size drop 16 ;
 131
 132 M: inet6 protocol-family drop PF_INET6 ;
 133
 134 M: inet6 sockaddr-size drop sockaddr-in6 heap-size ;
 135
 136 M: inet6 empty-sockaddr drop sockaddr-in6 <struct> ;
 137
 138 M: inet6 make-sockaddr ( inet -- sockaddr )
 139     sockaddr-in6 <struct>
 140         AF_INET6 >>family
 141         swap [ port>> htons >>port ]
 142             [ host>> "::" or ]
 143             [ inet-pton >>addr ] tri ;
 144
 145 M: inet6 parse-sockaddr
 146     [ [ addr>> ] dip inet-ntop ]
 147     [ drop port>> ntohs ] 2bi <inet6> ;
 148
 149 : addrspec-of-family ( af -- addrspec )
 150     {
 151         { AF_INET [ T{ inet4 } ] }
 152         { AF_INET6 [ T{ inet6 } ] }
 153         { AF_UNIX [ T{ local } ] }
 154         [ drop f ]
 155     } case ;
 156
 157 : sockaddr-of-family ( af -- addrspec )
 158     {
 159         { AF_INET [ sockaddr-in ] }
 160         { AF_INET6 [ sockaddr-in6 ] }
 161         { AF_UNIX [ sockaddr-un ] }
 162         [ drop f ]
 163     } case ;
 164
 165 M: f parse-sockaddr nip ;
 166
 167 GENERIC: (get-local-address) ( handle remote -- sockaddr )
 168
 169 : get-local-address ( handle remote -- local )
 170     [ (get-local-address) ] keep parse-sockaddr ;
 171
 172 GENERIC: (get-remote-address) ( handle remote -- sockaddr )
 173
 174 : get-remote-address ( handle local -- remote )
 175     [ (get-remote-address) ] keep parse-sockaddr ;
 176
 177 : <ports> ( handle -- input-port output-port )
 178     [
 179         [ <input-port> |dispose ] [ <output-port> |dispose ] bi
 180     ] with-destructors ;
 181
 182 GENERIC: establish-connection ( client-out remote -- )
 183
 184 GENERIC: ((client)) ( remote -- handle )
 185
 186 GENERIC: (client) ( remote -- client-in client-out local )
 187
 188 M: array (client) [ (client) 3array ] attempt-all first3 ;
 189
 190 M: object (client) ( remote -- client-in client-out local )
 191     [
 192         [ ((client)) ] keep
 193         [
 194             [ <ports> [ |dispose ] bi@ dup ] dip
 195             establish-connection
 196         ]
 197         [ get-local-address ]
 198         2bi
 199     ] with-destructors ;
 200
 201 : <client> ( remote encoding -- stream local )
 202     [ (client) ] dip swap [ <encoder-duplex> ] dip ;
 203
 204 SYMBOL: local-address
 205
 206 SYMBOL: remote-address
 207
 208 : with-client ( remote encoding quot -- )
 209     [
 210         [
 211             over remote-address set
 212             <client> local-address set
 213         ] dip with-stream
 214     ] with-scope ; inline
 215
 216 TUPLE: server-port < port addr encoding ;
 217
 218 : check-server-port ( port -- port )
 219     dup check-disposed
 220     dup server-port? [ "Not a server port" throw ] unless ; inline
 221
 222 GENERIC: (server) ( addrspec -- handle )
 223
 224 : <server> ( addrspec encoding -- server )
 225     [
 226         [ (server) ] keep
 227         [ drop server-port <port> ] [ get-local-address ] 2bi
 228         >>addr
 229     ] dip >>encoding ;
 230
 231 GENERIC: (accept) ( server addrspec -- handle sockaddr )
 232
 233 : accept ( server -- client remote )
 234     [
 235         dup addr>>
 236         [ (accept) ] keep
 237         parse-sockaddr swap
 238         <ports>
 239     ] keep encoding>> <encoder-duplex> swap ;
 240
 241 TUPLE: datagram-port < port addr ;
 242
 243 HOOK: (datagram) io-backend ( addr -- datagram )
 244
 245 : <datagram> ( addrspec -- datagram )
 246     [
 247         [ (datagram) |dispose ] keep
 248         [ drop datagram-port <port> ] [ get-local-address ] 2bi
 249         >>addr
 250     ] with-destructors ;
 251
 252 : check-datagram-port ( port -- port )
 253     dup check-disposed
 254     dup datagram-port? [ "Not a datagram port" throw ] unless ; inline
 255
 256 HOOK: (receive) io-backend ( datagram -- packet addrspec )
 257
 258 : receive ( datagram -- packet addrspec )
 259     check-datagram-port
 260     [ (receive) ] [ addr>> ] bi parse-sockaddr ;
 261
 262 : check-datagram-send ( packet addrspec port -- packet addrspec port )
 263     check-datagram-port
 264     2dup addr>> [ class ] bi@ assert=
 265     pick class byte-array assert= ;
 266
 267 HOOK: (send) io-backend ( packet addrspec datagram -- )
 268
 269 : send ( packet addrspec datagram -- )
 270     check-datagram-send (send) ;
 271
 272 : addrinfo>addrspec ( addrinfo -- addrspec )
 273     [ [ addr>> ] [ family>> sockaddr-of-family ] bi memory>struct ]
 274     [ family>> addrspec-of-family ] bi
 275     parse-sockaddr ;
 276
 277 : parse-addrinfo-list ( addrinfo -- seq )
 278     [ next>> dup [ addrinfo memory>struct ] when ] follow
 279     [ addrinfo>addrspec ] map
 280     sift ;
 281
 282 HOOK: addrinfo-error io-backend ( n -- )
 283
 284 GENERIC: resolve-host ( addrspec -- seq )
 285
 286 TUPLE: inet < abstract-inet ;
 287
 288 C: <inet> inet
 289
 290 : resolve-passive-host ( -- addrspecs )
 291     { T{ inet6 f "::" f } T{ inet4 f "0.0.0.0" f } } [ clone ] map ;
 292
 293 : prepare-addrinfo ( -- addrinfo )
 294     addrinfo <struct>
 295         PF_UNSPEC >>family
 296         IPPROTO_TCP >>protocol ;
 297
 298 : fill-in-ports ( addrspecs port -- addrspecs )
 299     '[ _ >>port ] map ;
 300
 301 M: inet resolve-host
 302     [ port>> ] [ host>> ] bi [
 303         f prepare-addrinfo f <void*>
 304         [ getaddrinfo addrinfo-error ] keep *void* addrinfo memory>struct
 305         [ parse-addrinfo-list ] keep freeaddrinfo
 306     ] [ resolve-passive-host ] if*
 307     swap fill-in-ports ;
 308
 309 M: f resolve-host drop { } ;
 310
 311 M: object resolve-host 1array ;
 312
 313 : host-name ( -- string )
 314     256 <byte-array> dup dup length gethostname
 315     zero? [ "gethostname failed" throw ] unless
 316     ascii alien>string ;
 317
 318 M: inet (client) resolve-host (client) ;
 319
 320 ERROR: invalid-inet-server addrspec ;
 321
 322 M: invalid-inet-server summary
 323     drop "Cannot use <server> with <inet>; use <inet4> or <inet6> instead" ;
 324
 325 M: inet (server)
 326     invalid-inet-server ;
 327
 328 {
 329     { [ os unix? ] [ "io.sockets.unix" require ] }
 330     { [ os winnt? ] [ "io.sockets.windows.nt" require ] }
 331 } cond