basis/io/sockets/sockets.factor

   1 ! Copyright (C) 2007, 2010 Slava Pestov, Doug Coleman,
   2 ! Daniel Ehrenberg.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: accessors alien.c-types alien.data alien.strings arrays
   5 assocs byte-arrays classes classes.struct combinators
   6 combinators.short-circuit continuations destructors fry generic
   7 grouping init io.backend io.binary io.encodings
   8 io.encodings.ascii io.encodings.binary io.ports
   9 io.streams.duplex kernel math math.parser memoize namespaces
  10 parser present sequences splitting strings summary system
  11 vocabs.loader vocabs.parser ;
  12 IN: io.sockets
  13
  14 << {
  15     { [ os windows? ] [ "windows.winsock" ] }
  16     { [ os unix? ] [ "unix.ffi" ] }
  17 } cond use-vocab >>
  18
  19 GENERIC# with-port 1 ( addrspec port -- addrspec )
  20
  21 ! Addressing
  22 <PRIVATE
  23
  24 UNION: ?string string POSTPONE: f ;
  25
  26 GENERIC: protocol ( addrspec -- n )
  27
  28 GENERIC: protocol-family ( addrspec -- af )
  29
  30 GENERIC: sockaddr-size ( addrspec -- n )
  31
  32 GENERIC: make-sockaddr ( addrspec -- sockaddr )
  33
  34 GENERIC: empty-sockaddr ( addrspec -- sockaddr )
  35
  36 GENERIC: address-size ( addrspec -- n )
  37
  38 GENERIC: inet-ntop ( data addrspec -- str )
  39
  40 GENERIC: inet-pton ( str addrspec -- data )
  41
  42 : make-sockaddr/size ( addrspec -- sockaddr size )
  43     [ make-sockaddr ] [ sockaddr-size ] bi ;
  44
  45 : empty-sockaddr/size ( addrspec -- sockaddr size )
  46     [ empty-sockaddr ] [ sockaddr-size ] bi ;
  47
  48 GENERIC: parse-sockaddr ( sockaddr addrspec -- newaddrspec )
  49
  50 M: f parse-sockaddr nip ;
  51
  52 HOOK: sockaddr-of-family os ( alien af -- sockaddr )
  53
  54 HOOK: addrspec-of-family os ( af -- addrspec )
  55
  56 PRIVATE>
  57
  58 TUPLE: local { path read-only } ;
  59
  60 : <local> ( path -- addrspec )
  61     normalize-path local boa ;
  62
  63 M: local present path>> "Unix domain socket: " prepend ;
  64
  65 M: local protocol drop 0 ;
  66
  67 SLOT: port
  68
  69 TUPLE: ipv4 { host ?string read-only } ;
  70
  71 C: <ipv4> ipv4
  72
  73 M: ipv4 inet-ntop ( data addrspec -- str )
  74     drop 4 memory>byte-array [ number>string ] { } map-as "." join ;
  75
  76 <PRIVATE
  77
  78 ERROR: malformed-ipv4 sequence ;
  79
  80 ERROR: bad-ipv4-component string ;
  81
  82 : parse-ipv4 ( string -- seq )
  83     "." split dup length 4 = [ malformed-ipv4 ] unless
  84     [ dup string>number [ ] [ bad-ipv4-component ] ?if ] B{ } map-as ;
  85
  86 ERROR: invalid-ipv4 string reason ;
  87
  88 M: invalid-ipv4 summary drop "Invalid IPv4 address" ;
  89
  90 PRIVATE>
  91
  92 M: ipv4 inet-pton ( str addrspec -- data )
  93     drop [ parse-ipv4 ] [ invalid-ipv4 ] recover ;
  94
  95 M: ipv4 address-size drop 4 ;
  96
  97 M: ipv4 protocol-family drop PF_INET ;
  98
  99 M: ipv4 sockaddr-size drop sockaddr-in heap-size ;
 100
 101 M: ipv4 empty-sockaddr drop sockaddr-in <struct> ;
 102
 103 M: ipv4 make-sockaddr ( inet -- sockaddr )
 104     sockaddr-in <struct>
 105         AF_INET >>family
 106         swap
 107         [ port>> htons >>port ]
 108         [ host>> "0.0.0.0" or ]
 109         [ inet-pton uint deref >>addr ] tri ;
 110
 111 M: ipv4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
 112     [ addr>> uint <ref> ] dip inet-ntop <ipv4> ;
 113
 114 TUPLE: inet4 < ipv4 { port integer read-only } ;
 115
 116 C: <inet4> inet4
 117
 118 M: ipv4 with-port [ host>> ] dip <inet4> ;
 119
 120 M: inet4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
 121     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 122
 123 M: inet4 present
 124     [ host>> ] [ port>> number>string ] bi ":" glue ;
 125
 126 M: inet4 protocol drop 0 ;
 127
 128 TUPLE: ipv6 { host ?string read-only } ;
 129
 130 C: <ipv6> ipv6
 131
 132 M: ipv6 inet-ntop ( data addrspec -- str )
 133     drop 16 memory>byte-array 2 <groups> [ be> >hex ] map ":" join ;
 134
 135 ERROR: invalid-ipv6 string reason ;
 136
 137 <PRIVATE
 138
 139 ERROR: bad-ipv6-component obj ;
 140
 141 ERROR: bad-ipv4-embedded-prefix obj ;
 142
 143 ERROR: more-than-8-components ;
 144
 145 : parse-ipv6-component ( seq -- seq' )
 146     [ dup hex> [ nip ] [ bad-ipv6-component ] if* ] { } map-as ;
 147
 148 : parse-ipv6 ( string -- seq )
 149     [ f ] [
 150         ":" split CHAR: . over last member? [
 151             unclip-last
 152             [ parse-ipv6-component ] [ parse-ipv4 ] bi* append
 153         ] [
 154             parse-ipv6-component
 155         ] if
 156     ] if-empty ;
 157
 158 : pad-ipv6 ( string1 string2 -- seq )
 159     2dup [ length ] bi@ + 8 swap -
 160     dup 0 < [ more-than-8-components ] when
 161     <byte-array> glue ;
 162
 163 : ipv6-bytes ( seq -- bytes )
 164     [ 2 >be ] { } map-as B{ } concat-as ;
 165
 166 PRIVATE>
 167
 168 M: ipv6 inet-pton ( str addrspec -- data )
 169     drop
 170     [ "::" split1 [ parse-ipv6 ] bi@ pad-ipv6 ipv6-bytes ]
 171     [ invalid-ipv6 ]
 172     recover ;
 173
 174 M: ipv6 address-size drop 16 ;
 175
 176 M: ipv6 protocol-family drop PF_INET6 ;
 177
 178 M: ipv6 sockaddr-size drop sockaddr-in6 heap-size ;
 179
 180 M: ipv6 empty-sockaddr drop sockaddr-in6 <struct> ;
 181
 182 M: ipv6 make-sockaddr ( inet -- sockaddr )
 183     sockaddr-in6 <struct>
 184         AF_INET6 >>family
 185         swap
 186         [ port>> htons >>port ]
 187         [ host>> "::" or ]
 188         [ inet-pton >>addr ] tri ;
 189
 190 M: ipv6 parse-sockaddr
 191     [ addr>> ] dip inet-ntop <ipv6> ;
 192
 193 TUPLE: inet6 < ipv6 { port integer read-only } ;
 194
 195 C: <inet6> inet6
 196
 197 M: ipv6 with-port [ host>> ] dip <inet6> ;
 198
 199 M: inet6 parse-sockaddr
 200     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 201
 202 M: inet6 present
 203     [ host>> ] [ port>> number>string ] bi ":" glue ;
 204
 205 M: inet6 protocol drop 0 ;
 206
 207 <PRIVATE
 208
 209 GENERIC: (get-local-address) ( handle remote -- sockaddr )
 210
 211 : get-local-address ( handle remote -- local )
 212     [ (get-local-address) ] keep parse-sockaddr ;
 213
 214 GENERIC: (get-remote-address) ( handle remote -- sockaddr )
 215
 216 : get-remote-address ( handle local -- remote )
 217     [ (get-remote-address) ] keep parse-sockaddr ;
 218
 219 : <ports> ( handle -- input-port output-port )
 220     [
 221         [ <input-port> |dispose ] [ <output-port> |dispose ] bi
 222     ] with-destructors ;
 223
 224 SYMBOL: bind-local-address
 225
 226 GENERIC: establish-connection ( client-out remote -- )
 227
 228 GENERIC: ((client)) ( remote -- handle )
 229
 230 GENERIC: (client) ( remote -- client-in client-out local )
 231
 232 M: array (client) [ (client) 3array ] attempt-all first3 ;
 233
 234 M: object (client) ( remote -- client-in client-out local )
 235     [
 236         [ ((client)) ] keep
 237         [
 238             [ <ports> [ |dispose ] bi@ dup ] dip
 239             establish-connection
 240         ]
 241         [ get-local-address ]
 242         2bi
 243     ] with-destructors ;
 244
 245 TUPLE: server-port < port addr encoding ;
 246
 247 : check-server-port ( port -- port )
 248     dup check-disposed
 249     dup server-port? [ "Not a server port" throw ] unless ; inline
 250
 251 GENERIC: (server) ( addrspec -- handle )
 252
 253 GENERIC: (accept) ( server addrspec -- handle sockaddr )
 254
 255 TUPLE: datagram-port < port addr ;
 256
 257 HOOK: (datagram) io-backend ( addr -- datagram )
 258
 259 TUPLE: raw-port < port addr ;
 260
 261 HOOK: (raw) io-backend ( addr -- raw )
 262
 263 HOOK: (receive) io-backend ( datagram -- packet addrspec )
 264
 265 ERROR: invalid-port object ;
 266
 267 : check-port ( packet addrspec port -- packet addrspec port )
 268     2dup addr>> [ class ] bi@ assert=
 269     pick class byte-array assert= ;
 270
 271 : check-connectionless-port ( port -- port )
 272     dup { [ datagram-port? ] [ raw-port? ] } 1|| [ invalid-port ] unless ;
 273
 274 : check-send ( packet addrspec port -- packet addrspec port )
 275     check-connectionless-port dup check-disposed check-port ;
 276
 277 : check-receive ( port -- port )
 278     check-connectionless-port dup check-disposed ;
 279
 280 HOOK: (send) io-backend ( packet addrspec datagram -- )
 281
 282 : addrinfo>addrspec ( addrinfo -- addrspec )
 283     [ [ addr>> ] [ family>> ] bi sockaddr-of-family ]
 284     [ family>> addrspec-of-family ] bi
 285     parse-sockaddr ;
 286
 287 : parse-addrinfo-list ( addrinfo -- seq )
 288     [ next>> ] follow
 289     [ addrinfo>addrspec ] map
 290     sift ;
 291
 292 HOOK: addrinfo-error io-backend ( n -- )
 293
 294 : prepare-addrinfo ( -- addrinfo )
 295     addrinfo <struct>
 296         PF_UNSPEC >>family
 297         IPPROTO_TCP >>protocol ;
 298
 299 PRIVATE>
 300
 301 : <client> ( remote encoding -- stream local )
 302     [ (client) ] dip swap [ <encoder-duplex> ] dip ;
 303
 304 SYMBOL: local-address
 305
 306 SYMBOL: remote-address
 307
 308 : with-client ( remote encoding quot -- )
 309     [
 310         [
 311             over remote-address set
 312             <client> local-address set
 313         ] dip with-stream
 314     ] with-scope ; inline
 315
 316 : <server> ( addrspec encoding -- server )
 317     [
 318         [ (server) ] keep
 319         [ drop server-port <port> ] [ get-local-address ] 2bi
 320         >>addr
 321     ] dip >>encoding ;
 322
 323 : accept ( server -- client remote )
 324     [
 325         dup addr>>
 326         [ (accept) ] keep
 327         parse-sockaddr swap
 328         <ports>
 329     ] keep encoding>> <encoder-duplex> swap ;
 330
 331 : <datagram> ( addrspec -- datagram )
 332     [
 333         [ (datagram) |dispose ] keep
 334         [ drop datagram-port <port> ] [ get-local-address ] 2bi
 335         >>addr
 336     ] with-destructors ;
 337
 338 : <raw> ( addrspec -- datagram )
 339     [
 340         [ (raw) |dispose ] keep
 341         [ drop raw-port <port> ] [ get-local-address ] 2bi
 342         >>addr
 343     ] with-destructors ;
 344
 345 : receive ( datagram -- packet addrspec )
 346     check-receive
 347     [ (receive) ] [ addr>> ] bi parse-sockaddr ;
 348
 349 : send ( packet addrspec datagram -- )
 350     check-send (send) ;
 351
 352 MEMO: ipv6-supported? ( -- ? )
 353     [ "::1" 0 <inet6> binary <server> dispose t ] [ drop f ] recover ;
 354
 355 [ \ ipv6-supported? reset-memoized ] "io.sockets" add-startup-hook
 356
 357 GENERIC: resolve-host ( addrspec -- seq )
 358
 359 HOOK: resolve-localhost os ( -- obj )
 360
 361 TUPLE: hostname { host ?string read-only } ;
 362
 363 TUPLE: inet < hostname port ;
 364
 365 M: inet present
 366     [ host>> ] [ port>> number>string ] bi ":" glue ;
 367
 368 C: <inet> inet
 369
 370 M: string resolve-host
 371     f prepare-addrinfo f void* <ref>
 372     [ getaddrinfo addrinfo-error ] keep void* deref addrinfo memory>struct
 373     [ parse-addrinfo-list ] keep freeaddrinfo ;
 374
 375 M: string with-port <inet> ;
 376
 377 M: hostname resolve-host
 378     host>> resolve-host ;
 379
 380 M: hostname with-port
 381     [ host>> ] dip <inet> ;
 382
 383 M: inet resolve-host
 384     [ call-next-method ] [ port>> ] bi '[ _ with-port ] map ;
 385
 386 M: inet4 resolve-host 1array ;
 387
 388 M: inet6 resolve-host 1array ;
 389
 390 M: local resolve-host 1array ;
 391
 392 M: f resolve-host
 393     drop resolve-localhost ;
 394
 395 M: object resolve-localhost
 396     ipv6-supported?
 397     { T{ ipv4 f "0.0.0.0" } T{ ipv6 f "::" } }
 398     { T{ ipv4 f "0.0.0.0" } }
 399     ? ;
 400
 401 : host-name ( -- string )
 402     256 <byte-array> dup dup length gethostname
 403     zero? [ "gethostname failed" throw ] unless
 404     ascii alien>string ;
 405
 406 M: inet (client) resolve-host (client) ;
 407
 408 ERROR: invalid-inet-server addrspec ;
 409
 410 M: invalid-inet-server summary
 411     drop "Cannot use <server> with <inet>; use <inet4> or <inet6> instead" ;
 412
 413 M: inet (server)
 414     invalid-inet-server ;
 415
 416 ERROR: invalid-local-address addrspec ;
 417
 418 M: invalid-local-address summary
 419     drop "Cannot use with-local-address with <inet>; use <inet4> or <inet6> instead" ;
 420
 421 : with-local-address ( addr quot -- )
 422     [
 423         [ ] [ inet4? ] [ inet6? ] tri or
 424         [ bind-local-address ]
 425         [ invalid-local-address ] if
 426     ] dip with-variable ; inline
 427
 428 {
 429     { [ os unix? ] [ "io.sockets.unix" require ] }
 430     { [ os windows? ] [ "io.sockets.windows" require ] }
 431 } cond