basis/io/sockets/sockets.factor

   1 ! Copyright (C) 2007, 2011 Slava Pestov, Doug Coleman,
   2 ! Daniel Ehrenberg.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: accessors alien.c-types alien.data alien.strings arrays
   5 byte-arrays classes classes.struct combinators
   6 combinators.short-circuit continuations destructors endian fry
   7 grouping init io.backend io.encodings.ascii io.encodings.binary
   8 io.pathnames io.ports io.streams.duplex ip-parser
   9 ip-parser.private kernel locals math math.parser
  10 memoize namespaces present random sequences sequences.private
  11 splitting strings summary system vocabs vocabs.parser
  12 vocabs.platforms ;
  13 IN: io.sockets
  14
  15 USE-UNIX: unix.ffi
  16
  17 GENERIC#: with-port 1 ( addrspec port -- addrspec )
  18
  19 ! Addressing
  20 <PRIVATE
  21
  22 GENERIC: protocol ( addrspec -- n )
  23
  24 GENERIC: protocol-family ( addrspec -- af )
  25
  26 GENERIC: sockaddr-size ( addrspec -- n )
  27
  28 GENERIC: make-sockaddr ( addrspec -- sockaddr )
  29
  30 GENERIC: make-sockaddr-outgoing ( addrspec -- sockaddr )
  31
  32 GENERIC: empty-sockaddr ( addrspec -- sockaddr )
  33
  34 GENERIC: address-size ( addrspec -- n )
  35
  36 GENERIC: inet-ntop ( data addrspec -- str )
  37
  38 GENERIC: inet-pton ( str addrspec -- data )
  39
  40 : make-sockaddr/size-outgoing ( addrspec -- sockaddr size )
  41     [ make-sockaddr-outgoing ] [ sockaddr-size ] bi ;
  42
  43 : make-sockaddr/size ( addrspec -- sockaddr size )
  44     [ make-sockaddr ] [ sockaddr-size ] bi ;
  45
  46 : empty-sockaddr/size ( addrspec -- sockaddr size )
  47     [ empty-sockaddr ] [ sockaddr-size ] bi ;
  48
  49 M: object make-sockaddr-outgoing make-sockaddr ;
  50
  51 GENERIC: parse-sockaddr ( sockaddr addrspec -- newaddrspec )
  52
  53 M: f parse-sockaddr nip ;
  54
  55 HOOK: sockaddr-of-family os ( alien af -- sockaddr )
  56
  57 HOOK: addrspec-of-family os ( af -- addrspec )
  58
  59 PRIVATE>
  60
  61 TUPLE: local { path string read-only } ;
  62
  63 : <local> ( path -- addrspec )
  64     absolute-path local boa ;
  65
  66 M: local present path>> "Unix domain socket: " prepend ;
  67
  68 M: local protocol drop 0 ;
  69
  70 SLOT: port
  71
  72 TUPLE: ipv4 { host maybe{ string } read-only } ;
  73
  74 <PRIVATE
  75
  76 ERROR: invalid-ipv4 host reason ;
  77
  78 M: invalid-ipv4 summary drop "Invalid IPv4 address" ;
  79
  80 : ?parse-ipv4 ( string -- seq/f )
  81     [ f ] [ parse-ipv4 ] if-empty ;
  82
  83 : check-ipv4 ( host -- )
  84     [ ?parse-ipv4 drop ] [ invalid-ipv4 ] recover ;
  85
  86 PRIVATE>
  87
  88 : <ipv4> ( host -- ipv4 ) dup check-ipv4 ipv4 boa ;
  89
  90 M: ipv4 inet-ntop
  91     drop 4 memory>byte-array join-ipv4 ;
  92
  93 M: ipv4 inet-pton
  94     drop [ ?parse-ipv4 ] [ invalid-ipv4 ] recover ;
  95
  96 M: ipv4 address-size drop 4 ;
  97
  98 M: ipv4 protocol-family drop PF_INET ;
  99
 100 M: ipv4 sockaddr-size drop sockaddr-in heap-size ;
 101
 102 M: ipv4 empty-sockaddr drop sockaddr-in new ;
 103
 104 : make-sockaddr-part ( inet -- sockaddr )
 105     sockaddr-in new
 106         AF_INET >>family
 107         swap
 108         port>> 0 or htons >>port ; inline
 109
 110 M: ipv4 make-sockaddr
 111     [ make-sockaddr-part ]
 112     [ host>> "0.0.0.0" or ]
 113     [ inet-pton uint deref >>addr ] tri ;
 114
 115 M: ipv4 make-sockaddr-outgoing
 116     [ make-sockaddr-part ]
 117     [ host>> dup { f "0.0.0.0" } member? [ drop "127.0.0.1" ] when ]
 118     [ inet-pton uint deref >>addr ] tri ;
 119
 120 M: ipv4 parse-sockaddr
 121     [ addr>> uint <ref> ] dip inet-ntop <ipv4> ;
 122
 123 TUPLE: inet4 < ipv4 { port maybe{ integer } read-only } ;
 124
 125 : <inet4> ( host port -- inet4 )
 126     over check-ipv4 inet4 boa ;
 127
 128 M: ipv4 with-port [ host>> ] dip <inet4> ;
 129
 130 M: inet4 parse-sockaddr
 131     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 132
 133 M: inet4 present
 134     [ host>> ] [ port>> number>string ] bi ":" glue ;
 135
 136 M: inet4 protocol drop 0 ;
 137
 138 TUPLE: ipv6
 139 { host maybe{ string } read-only }
 140 { scope-id integer read-only } ;
 141
 142 <PRIVATE
 143
 144 ERROR: invalid-ipv6 host reason ;
 145
 146 M: invalid-ipv6 summary drop "Invalid IPv6 address" ;
 147
 148 : check-ipv6 ( host -- )
 149     [ parse-ipv6 drop ] [ invalid-ipv6 ] recover ;
 150
 151 PRIVATE>
 152
 153 : <ipv6> ( host -- ipv6 ) dup check-ipv6 0 ipv6 boa ;
 154
 155 M: ipv6 inet-ntop
 156     drop 16 memory>byte-array 2 <groups> [ be> >hex ] map ":" join ;
 157
 158 <PRIVATE
 159
 160 : ipv6-bytes ( seq -- bytes )
 161     [ 2 >be ] { } map-as B{ } concat-as ;
 162
 163 PRIVATE>
 164
 165 M: ipv6 inet-pton
 166     drop [ parse-ipv6 ipv6-bytes ] [ invalid-ipv6 ] recover ;
 167
 168 M: ipv6 address-size drop 16 ;
 169
 170 M: ipv6 protocol-family drop PF_INET6 ;
 171
 172 M: ipv6 sockaddr-size drop sockaddr-in6 heap-size ;
 173
 174 M: ipv6 empty-sockaddr drop sockaddr-in6 new ;
 175
 176 : make-sockaddr-in6-part ( inet -- sockaddr )
 177     sockaddr-in6 new
 178         AF_INET6 >>family
 179         swap
 180         port>> 0 or htons >>port ; inline
 181
 182 M: ipv6 make-sockaddr
 183     [ make-sockaddr-in6-part ]
 184     [ [ host>> "::" or ] keep inet-pton >>addr ]
 185     [ scope-id>> >>scopeid ]
 186     tri ;
 187
 188 M: ipv6 make-sockaddr-outgoing
 189     [ make-sockaddr-in6-part ]
 190     [ [ host>> dup { f "::" } member? [ drop "::1" ] when ] keep inet-pton >>addr ]
 191     [ scope-id>> >>scopeid ]
 192     tri ;
 193
 194 M: ipv6 parse-sockaddr
 195     [ [ addr>> ] dip inet-ntop ] [ drop scopeid>> ] 2bi
 196     ipv6 boa ;
 197
 198 M: ipv6 present
 199     [ host>> ] [ scope-id>> ] bi
 200     [ number>string "%" glue ] unless-zero ;
 201
 202 TUPLE: inet6 < ipv6 { port maybe{ integer } read-only } ;
 203
 204 : <inet6> ( host port -- inet6 )
 205     [ dup check-ipv6 0 ] dip inet6 boa ;
 206
 207 M: ipv6 with-port
 208     [ [ host>> ] [ scope-id>> ] bi ] dip
 209     inet6 boa ;
 210
 211 M: inet6 parse-sockaddr
 212     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 213
 214 M: inet6 present
 215     [ call-next-method ] [ port>> number>string ] bi ":" glue ;
 216
 217 M: inet6 protocol drop 0 ;
 218
 219 ERROR: addrinfo-error n string host ;
 220
 221 <PRIVATE
 222
 223 GENERIC: (get-local-address) ( handle remote -- sockaddr )
 224
 225 : get-local-address ( handle remote -- local )
 226     [ (get-local-address) ] keep parse-sockaddr ;
 227
 228 GENERIC: (get-remote-address) ( handle remote -- sockaddr )
 229
 230 : get-remote-address ( handle local -- remote )
 231     [ (get-remote-address) ] keep parse-sockaddr ;
 232
 233 : <ports> ( handle -- input-port output-port )
 234     [
 235         [ <input-port> |dispose ] [ <output-port> |dispose ] bi
 236     ] with-destructors ;
 237
 238 SYMBOL: bind-local-address
 239
 240 GENERIC: establish-connection ( client-out remote -- )
 241
 242 GENERIC: remote>handle ( remote -- handle )
 243
 244 GENERIC: (client) ( remote -- client-in client-out local )
 245
 246 M: array (client) [ (client) 3array ] attempt-all first3 ;
 247
 248 M: object (client)
 249     [
 250         [ remote>handle ] keep
 251         [
 252             [ <ports> [ |dispose ] bi@ dup ] dip
 253             establish-connection
 254         ]
 255         [ get-local-address ]
 256         2bi
 257     ] with-destructors ;
 258
 259 TUPLE: server-port < port addr encoding ;
 260
 261 GENERIC: (server) ( addrspec -- handle )
 262
 263 GENERIC: (accept) ( server addrspec -- handle sockaddr )
 264
 265 TUPLE: datagram-port < port addr ;
 266
 267 HOOK: (datagram) io-backend ( addr -- datagram )
 268
 269 TUPLE: raw-port < port addr ;
 270
 271 HOOK: (raw) io-backend ( addr -- raw )
 272
 273 HOOK: (broadcast) io-backend ( datagram -- datagram )
 274
 275 HOOK: (receive-unsafe) io-backend ( n buf datagram -- count addrspec )
 276
 277 ERROR: invalid-port object ;
 278
 279 : check-port ( bytes addrspec port -- bytes addrspec port )
 280     2dup addr>> [ class-of ] bi@ assert=
 281     pick class-of byte-array assert= ;
 282
 283 : check-connectionless-port ( port -- port )
 284     dup { [ datagram-port? ] [ raw-port? ] } 1|| [ invalid-port ] unless ;
 285
 286 : check-send ( bytes addrspec port -- bytes addrspec port )
 287     check-connectionless-port check-disposed check-port ;
 288
 289 : check-receive ( port -- port )
 290     check-connectionless-port check-disposed ;
 291
 292 HOOK: (send) io-backend ( bytes addrspec datagram -- )
 293
 294 : addrinfo>addrspec ( addrinfo -- addrspec )
 295     [ [ addr>> ] [ family>> ] bi sockaddr-of-family ]
 296     [ family>> addrspec-of-family ] bi
 297     parse-sockaddr ;
 298
 299 : parse-addrinfo-list ( addrinfo -- seq )
 300     [ next>> ] follow
 301     [ addrinfo>addrspec ] map
 302     sift ;
 303
 304 HOOK: addrinfo-error-string io-backend ( n -- string )
 305
 306 : prepare-addrinfo ( -- addrinfo )
 307     addrinfo new
 308         PF_UNSPEC >>family
 309         IPPROTO_TCP >>protocol ;
 310
 311 PRIVATE>
 312
 313 : <client> ( remote encoding -- stream local )
 314     [ (client) ] dip swap [ <encoder-duplex> ] dip ;
 315
 316 SYMBOL: local-address
 317
 318 SYMBOL: remote-address
 319
 320 : with-client ( remote encoding quot -- )
 321     [
 322         [
 323             over remote-address set
 324             <client> local-address set
 325         ] dip with-stream
 326     ] with-scope ; inline
 327
 328 : <server> ( addrspec encoding -- server )
 329     [
 330         [ (server) ] keep
 331         [ drop server-port <port> ] [ get-local-address ] 2bi
 332         >>addr
 333     ] dip >>encoding ;
 334
 335 : accept ( server -- client remote )
 336     [
 337         dup addr>>
 338         [ (accept) ] keep
 339         parse-sockaddr swap
 340         <ports>
 341     ] [ encoding>> ] bi <encoder-duplex> swap ;
 342
 343 : <datagram> ( addrspec -- datagram )
 344     [
 345         [ (datagram) |dispose ] keep
 346         [ drop datagram-port <port> ] [ get-local-address ] 2bi
 347         >>addr
 348     ] with-destructors ;
 349
 350 : <raw> ( addrspec -- datagram )
 351     [
 352         [ (raw) |dispose ] keep
 353         [ drop raw-port <port> ] [ get-local-address ] 2bi
 354         >>addr
 355     ] with-destructors ;
 356
 357 : <broadcast> ( addrspec -- datagram )
 358     <datagram> (broadcast) ;
 359
 360 : receive-unsafe ( n buf datagram -- count addrspec )
 361     check-receive
 362     [ (receive-unsafe) ] [ addr>> ] bi parse-sockaddr ; inline
 363
 364 CONSTANT: datagram-size 65536
 365
 366 :: receive ( datagram -- bytes addrspec )
 367     datagram-size (byte-array) :> buf
 368     datagram-size buf datagram
 369     receive-unsafe :> ( count addrspec )
 370     count buf resize addrspec ; inline
 371
 372 :: receive-into ( buf datagram -- buf-slice addrspec )
 373     buf length :> n
 374     n buf datagram receive-unsafe :> ( count addrspec )
 375     buf count head-slice addrspec ; inline
 376
 377 : send ( bytes addrspec datagram -- )
 378     check-send (send) ; inline
 379
 380 MEMO: ipv6-supported? ( -- ? )
 381     [ "::1" 0 <inet6> binary <server> dispose t ] [ drop f ] recover ;
 382
 383 STARTUP-HOOK: [ \ ipv6-supported? reset-memoized ]
 384
 385 GENERIC: resolve-host ( addrspec -- seq )
 386
 387 HOOK: resolve-localhost os ( -- obj )
 388
 389 TUPLE: hostname { host maybe{ string } read-only } ;
 390
 391 TUPLE: inet < hostname port ;
 392
 393 M: inet present
 394     [ host>> ] [ port>> number>string ] bi ":" glue ;
 395
 396 C: <inet> inet
 397
 398 M:: string resolve-host ( host -- seq )
 399     host f prepare-addrinfo f void* <ref> [
 400         getaddrinfo [
 401             dup addrinfo-error-string host addrinfo-error
 402         ] unless-zero
 403     ] keep void* deref addrinfo memory>struct
 404     [ parse-addrinfo-list ] keep freeaddrinfo ;
 405
 406 M: string with-port <inet> ;
 407
 408 M: hostname resolve-host
 409     host>> resolve-host ;
 410
 411 M: hostname with-port
 412     [ host>> ] dip <inet> ;
 413
 414 M: inet resolve-host
 415     [ call-next-method ] [ port>> ] bi '[ _ with-port ] map ;
 416
 417 M: inet4 resolve-host 1array ;
 418
 419 M: inet6 resolve-host 1array ;
 420
 421 M: local resolve-host 1array ;
 422
 423 M: f resolve-host
 424     drop resolve-localhost ;
 425
 426 M: object resolve-localhost
 427     ipv6-supported?
 428     { T{ ipv4 f "0.0.0.0" } T{ ipv6 f "::" } }
 429     { T{ ipv4 f "0.0.0.0" } }
 430     ? ;
 431
 432 HOOK: host-name os ( -- string )
 433
 434 M: inet (client) resolve-host (client) ;
 435
 436 ERROR: invalid-inet-server addrspec ;
 437
 438 M: invalid-inet-server summary
 439     drop "Cannot use <server> with <inet>; use <inet4> or <inet6> instead" ;
 440
 441 M: inet (server)
 442     invalid-inet-server ;
 443
 444 ERROR: invalid-local-address addrspec ;
 445
 446 M: invalid-local-address summary
 447     drop "Cannot use with-local-address with <inet>; use <inet4> or <inet6> instead" ;
 448
 449 : with-local-address ( addr quot -- )
 450     [
 451         [ ] [ inet4? ] [ inet6? ] tri or
 452         [ bind-local-address ]
 453         [ invalid-local-address ] if
 454     ] dip with-variable ; inline
 455
 456 : protocol-port ( protocol -- port )
 457     [ f getservbyname [ port>> htons ] [ f ] if* ] [ f ] if* ;
 458
 459 : port-protocol ( port -- protocol )
 460     [ htons f getservbyport [ name>> ] [ f ] if* ] [ f ] if* ;
 461
 462 : <any-port-local-inet4> ( -- inet4 ) f 0 <inet4> ;
 463 : <any-port-local-inet6> ( -- inet6 ) f 0 <inet6> ;
 464
 465 GENERIC: <any-port-local-inet> ( inet -- inet4 )
 466 M: inet4 <any-port-local-inet> drop <any-port-local-inet4> ;
 467 M: inet6 <any-port-local-inet> drop f 0 <inet6> ;
 468
 469 : <any-port-local-datagram> ( inet -- datagram )
 470     <any-port-local-inet> <datagram> ;
 471
 472 : <any-port-local-broadcast> ( inet -- datagram )
 473     <any-port-local-inet> <broadcast> ;
 474
 475 : with-any-port-local-datagram ( quot -- )
 476     [ dup <any-port-local-datagram> ] dip with-disposal ; inline
 477
 478 : with-any-port-local-broadcast ( quot -- )
 479     [ dup <any-port-local-broadcast> ] dip with-disposal ; inline
 480
 481 : send-once ( bytes addrspec -- )
 482     [ send ] with-any-port-local-datagram ;
 483
 484 : broadcast-once ( bytes addrspec -- )
 485     [ send ] with-any-port-local-broadcast ;
 486
 487 USE-UNIX: io.sockets.unix
 488 USE-WINDOWS: io.sockets.windows
 489 USE-WINDOWS: windows.winsock