basis/io/sockets/sockets.factor

   1 ! Copyright (C) 2007, 2011 Slava Pestov, Doug Coleman,
   2 ! Daniel Ehrenberg.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: accessors alien.c-types alien.data alien.strings arrays
   5 byte-arrays classes classes.struct combinators
   6 combinators.short-circuit continuations destructors fry
   7 grouping init io.backend io.binary io.encodings.ascii
   8 io.encodings.binary io.pathnames io.ports io.streams.duplex
   9 kernel locals math math.parser memoize namespaces present
  10 sequences sequences.private splitting strings summary system
  11 vocabs vocabs.parser ip-parser ip-parser.private random ;
  12 IN: io.sockets
  13
  14 << {
  15     { [ os windows? ] [ "windows.winsock" ] }
  16     { [ os unix? ] [ "unix.ffi" ] }
  17 } cond use-vocab >>
  18
  19 GENERIC# with-port 1 ( addrspec port -- addrspec )
  20
  21 ! Addressing
  22 <PRIVATE
  23
  24 GENERIC: protocol ( addrspec -- n )
  25
  26 GENERIC: protocol-family ( addrspec -- af )
  27
  28 GENERIC: sockaddr-size ( addrspec -- n )
  29
  30 GENERIC: make-sockaddr ( addrspec -- sockaddr )
  31
  32 GENERIC: empty-sockaddr ( addrspec -- sockaddr )
  33
  34 GENERIC: address-size ( addrspec -- n )
  35
  36 GENERIC: inet-ntop ( data addrspec -- str )
  37
  38 GENERIC: inet-pton ( str addrspec -- data )
  39
  40 : make-sockaddr/size ( addrspec -- sockaddr size )
  41     [ make-sockaddr ] [ sockaddr-size ] bi ;
  42
  43 : empty-sockaddr/size ( addrspec -- sockaddr size )
  44     [ empty-sockaddr ] [ sockaddr-size ] bi ;
  45
  46 GENERIC: parse-sockaddr ( sockaddr addrspec -- newaddrspec )
  47
  48 M: f parse-sockaddr nip ;
  49
  50 HOOK: sockaddr-of-family os ( alien af -- sockaddr )
  51
  52 HOOK: addrspec-of-family os ( af -- addrspec )
  53
  54 PRIVATE>
  55
  56 TUPLE: local { path string read-only } ;
  57
  58 : <local> ( path -- addrspec )
  59     absolute-path local boa ;
  60
  61 M: local present path>> "Unix domain socket: " prepend ;
  62
  63 M: local protocol drop 0 ;
  64
  65 SLOT: port
  66
  67 TUPLE: ipv4 { host maybe{ string } read-only } ;
  68
  69 <PRIVATE
  70
  71 ERROR: invalid-ipv4 host reason ;
  72
  73 M: invalid-ipv4 summary drop "Invalid IPv4 address" ;
  74
  75 : ?parse-ipv4 ( string -- seq/f )
  76     [ f ] [ parse-ipv4 ] if-empty ;
  77
  78 : check-ipv4 ( host -- )
  79     [ ?parse-ipv4 drop ] [ invalid-ipv4 ] recover ;
  80
  81 PRIVATE>
  82
  83 : <ipv4> ( host -- ipv4 ) dup check-ipv4 ipv4 boa ;
  84
  85 M: ipv4 inet-ntop ( data addrspec -- str )
  86     drop 4 memory>byte-array join-ipv4 ;
  87
  88 M: ipv4 inet-pton ( str addrspec -- data )
  89     drop [ ?parse-ipv4 ] [ invalid-ipv4 ] recover ;
  90
  91 M: ipv4 address-size drop 4 ;
  92
  93 M: ipv4 protocol-family drop PF_INET ;
  94
  95 M: ipv4 sockaddr-size drop sockaddr-in heap-size ;
  96
  97 M: ipv4 empty-sockaddr drop sockaddr-in <struct> ;
  98
  99 M: ipv4 make-sockaddr ( inet -- sockaddr )
 100     sockaddr-in <struct>
 101         AF_INET >>family
 102         swap
 103         [ port>> htons >>port ]
 104         [ host>> "0.0.0.0" or ]
 105         [ inet-pton uint deref >>addr ] tri ;
 106
 107 M: ipv4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
 108     [ addr>> uint <ref> ] dip inet-ntop <ipv4> ;
 109
 110 TUPLE: inet4 < ipv4 { port integer read-only } ;
 111
 112 : <inet4> ( host port -- inet4 )
 113     over check-ipv4 inet4 boa ;
 114
 115 M: ipv4 with-port [ host>> ] dip <inet4> ;
 116
 117 M: inet4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
 118     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 119
 120 M: inet4 present
 121     [ host>> ] [ port>> number>string ] bi ":" glue ;
 122
 123 M: inet4 protocol drop 0 ;
 124
 125 TUPLE: ipv6
 126 { host maybe{ string } read-only }
 127 { scope-id integer read-only } ;
 128
 129 <PRIVATE
 130
 131 ERROR: invalid-ipv6 host reason ;
 132
 133 M: invalid-ipv6 summary drop "Invalid IPv6 address" ;
 134
 135 : check-ipv6 ( host -- )
 136     [ parse-ipv6 drop ] [ invalid-ipv6 ] recover ;
 137
 138 PRIVATE>
 139
 140 : <ipv6> ( host -- ipv6 ) dup check-ipv6 0 ipv6 boa ;
 141
 142 M: ipv6 inet-ntop ( data addrspec -- str )
 143     drop 16 memory>byte-array 2 <groups> [ be> >hex ] map ":" join ;
 144
 145 <PRIVATE
 146
 147 : ipv6-bytes ( seq -- bytes )
 148     [ 2 >be ] { } map-as B{ } concat-as ;
 149
 150 PRIVATE>
 151
 152 M: ipv6 inet-pton ( str addrspec -- data )
 153     drop [ parse-ipv6 ipv6-bytes ] [ invalid-ipv6 ] recover ;
 154
 155 M: ipv6 address-size drop 16 ;
 156
 157 M: ipv6 protocol-family drop PF_INET6 ;
 158
 159 M: ipv6 sockaddr-size drop sockaddr-in6 heap-size ;
 160
 161 M: ipv6 empty-sockaddr drop sockaddr-in6 <struct> ;
 162
 163 M: ipv6 make-sockaddr ( inet -- sockaddr )
 164     sockaddr-in6 <struct>
 165         AF_INET6 >>family
 166         swap
 167         [ port>> htons >>port ]
 168         [ [ host>> "::" or ] keep inet-pton >>addr ]
 169         [ scope-id>> >>scopeid ]
 170         tri ;
 171
 172 M: ipv6 parse-sockaddr
 173     [ [ addr>> ] dip inet-ntop ] [ drop scopeid>> ] 2bi
 174     ipv6 boa ;
 175
 176 M: ipv6 present
 177     [ host>> ] [ scope-id>> ] bi
 178     [ number>string "%" glue ] unless-zero ;
 179
 180 TUPLE: inet6 < ipv6 { port integer read-only } ;
 181
 182 : <inet6> ( host port -- inet6 )
 183     [ dup check-ipv6 0 ] dip inet6 boa ;
 184
 185 M: ipv6 with-port
 186     [ [ host>> ] [ scope-id>> ] bi ] dip
 187     inet6 boa ;
 188
 189 M: inet6 parse-sockaddr
 190     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 191
 192 M: inet6 present
 193     [ call-next-method ] [ port>> number>string ] bi ":" glue ;
 194
 195 M: inet6 protocol drop 0 ;
 196
 197 ERROR: addrinfo-error n string ;
 198
 199 <PRIVATE
 200
 201 GENERIC: (get-local-address) ( handle remote -- sockaddr )
 202
 203 : get-local-address ( handle remote -- local )
 204     [ (get-local-address) ] keep parse-sockaddr ;
 205
 206 GENERIC: (get-remote-address) ( handle remote -- sockaddr )
 207
 208 : get-remote-address ( handle local -- remote )
 209     [ (get-remote-address) ] keep parse-sockaddr ;
 210
 211 : <ports> ( handle -- input-port output-port )
 212     [
 213         [ <input-port> |dispose ] [ <output-port> |dispose ] bi
 214     ] with-destructors ;
 215
 216 SYMBOL: bind-local-address
 217
 218 GENERIC: establish-connection ( client-out remote -- )
 219
 220 GENERIC: ((client)) ( remote -- handle )
 221
 222 GENERIC: (client) ( remote -- client-in client-out local )
 223
 224 M: array (client) [ (client) 3array ] attempt-all first3 ;
 225
 226 M: object (client) ( remote -- client-in client-out local )
 227     [
 228         [ ((client)) ] keep
 229         [
 230             [ <ports> [ |dispose ] bi@ dup ] dip
 231             establish-connection
 232         ]
 233         [ get-local-address ]
 234         2bi
 235     ] with-destructors ;
 236
 237 TUPLE: server-port < port addr encoding ;
 238
 239 GENERIC: (server) ( addrspec -- handle )
 240
 241 GENERIC: (accept) ( server addrspec -- handle sockaddr )
 242
 243 TUPLE: datagram-port < port addr ;
 244
 245 HOOK: (datagram) io-backend ( addr -- datagram )
 246
 247 TUPLE: raw-port < port addr ;
 248
 249 HOOK: (raw) io-backend ( addr -- raw )
 250
 251 HOOK: (broadcast) io-backend ( datagram -- datagram )
 252
 253 HOOK: (receive-unsafe) io-backend ( n buf datagram -- count addrspec )
 254
 255 ERROR: invalid-port object ;
 256
 257 : check-port ( bytes addrspec port -- bytes addrspec port )
 258     2dup addr>> [ class-of ] bi@ assert=
 259     pick class-of byte-array assert= ;
 260
 261 : check-connectionless-port ( port -- port )
 262     dup { [ datagram-port? ] [ raw-port? ] } 1|| [ invalid-port ] unless ;
 263
 264 : check-send ( bytes addrspec port -- bytes addrspec port )
 265     check-connectionless-port check-disposed check-port ;
 266
 267 : check-receive ( port -- port )
 268     check-connectionless-port check-disposed ;
 269
 270 HOOK: (send) io-backend ( bytes addrspec datagram -- )
 271
 272 : addrinfo>addrspec ( addrinfo -- addrspec )
 273     [ [ addr>> ] [ family>> ] bi sockaddr-of-family ]
 274     [ family>> addrspec-of-family ] bi
 275     parse-sockaddr ;
 276
 277 : parse-addrinfo-list ( addrinfo -- seq )
 278     [ next>> ] follow
 279     [ addrinfo>addrspec ] map
 280     sift ;
 281
 282 HOOK: addrinfo-error-string io-backend ( n -- string )
 283
 284 : prepare-addrinfo ( -- addrinfo )
 285     addrinfo <struct>
 286         PF_UNSPEC >>family
 287         IPPROTO_TCP >>protocol ;
 288
 289 PRIVATE>
 290
 291 : <client> ( remote encoding -- stream local )
 292     [ (client) ] dip swap [ <encoder-duplex> ] dip ;
 293
 294 SYMBOL: local-address
 295
 296 SYMBOL: remote-address
 297
 298 : with-client ( remote encoding quot -- )
 299     [
 300         [
 301             over remote-address set
 302             <client> local-address set
 303         ] dip with-stream
 304     ] with-scope ; inline
 305
 306 : <server> ( addrspec encoding -- server )
 307     [
 308         [ (server) ] keep
 309         [ drop server-port <port> ] [ get-local-address ] 2bi
 310         >>addr
 311     ] dip >>encoding ;
 312
 313 : accept ( server -- client remote )
 314     [
 315         dup addr>>
 316         [ (accept) ] keep
 317         parse-sockaddr swap
 318         <ports>
 319     ] [ encoding>> ] bi <encoder-duplex> swap ;
 320
 321 : <datagram> ( addrspec -- datagram )
 322     [
 323         [ (datagram) |dispose ] keep
 324         [ drop datagram-port <port> ] [ get-local-address ] 2bi
 325         >>addr
 326     ] with-destructors ;
 327
 328 : <raw> ( addrspec -- datagram )
 329     [
 330         [ (raw) |dispose ] keep
 331         [ drop raw-port <port> ] [ get-local-address ] 2bi
 332         >>addr
 333     ] with-destructors ;
 334
 335 : <broadcast> ( addrspec -- datagram )
 336     <datagram> (broadcast) ;
 337
 338 : receive-unsafe ( n buf datagram -- count addrspec )
 339     check-receive
 340     [ (receive-unsafe) ] [ addr>> ] bi parse-sockaddr ; inline
 341
 342 CONSTANT: datagram-size 65536
 343
 344 :: receive ( datagram -- bytes addrspec )
 345     datagram-size (byte-array) :> buf
 346     datagram-size buf datagram
 347     receive-unsafe :> ( count addrspec )
 348     count buf resize addrspec ; inline
 349
 350 :: receive-into ( buf datagram -- buf-slice addrspec )
 351     buf length :> n
 352     n buf datagram receive-unsafe :> ( count addrspec )
 353     buf count head-slice addrspec ; inline
 354
 355 : send ( bytes addrspec datagram -- )
 356     check-send (send) ; inline
 357
 358 MEMO: ipv6-supported? ( -- ? )
 359     [ "::1" 0 <inet6> binary <server> dispose t ] [ drop f ] recover ;
 360
 361 [ \ ipv6-supported? reset-memoized ]
 362 "io.sockets:ipv6-supported?" add-startup-hook
 363
 364 GENERIC: resolve-host ( addrspec -- seq )
 365
 366 HOOK: resolve-localhost os ( -- obj )
 367
 368 TUPLE: hostname { host maybe{ string } read-only } ;
 369
 370 TUPLE: inet < hostname port ;
 371
 372 M: inet present
 373     [ host>> ] [ port>> number>string ] bi ":" glue ;
 374
 375 C: <inet> inet
 376
 377 M: string resolve-host
 378     f prepare-addrinfo f void* <ref> [
 379         getaddrinfo [
 380             dup addrinfo-error-string addrinfo-error
 381         ] unless-zero
 382     ] keep void* deref addrinfo memory>struct
 383     [ parse-addrinfo-list ] keep freeaddrinfo ;
 384
 385 M: string with-port <inet> ;
 386
 387 M: hostname resolve-host
 388     host>> resolve-host ;
 389
 390 M: hostname with-port
 391     [ host>> ] dip <inet> ;
 392
 393 M: inet resolve-host
 394     [ call-next-method ] [ port>> ] bi '[ _ with-port ] map ;
 395
 396 M: inet4 resolve-host 1array ;
 397
 398 M: inet6 resolve-host 1array ;
 399
 400 M: local resolve-host 1array ;
 401
 402 M: f resolve-host
 403     drop resolve-localhost ;
 404
 405 M: object resolve-localhost
 406     ipv6-supported?
 407     { T{ ipv4 f "0.0.0.0" } T{ ipv6 f "::" } }
 408     { T{ ipv4 f "0.0.0.0" } }
 409     ? ;
 410
 411 HOOK: host-name os ( -- string )
 412
 413 M: inet (client) resolve-host (client) ;
 414
 415 ERROR: invalid-inet-server addrspec ;
 416
 417 M: invalid-inet-server summary
 418     drop "Cannot use <server> with <inet>; use <inet4> or <inet6> instead" ;
 419
 420 M: inet (server)
 421     invalid-inet-server ;
 422
 423 ERROR: invalid-local-address addrspec ;
 424
 425 M: invalid-local-address summary
 426     drop "Cannot use with-local-address with <inet>; use <inet4> or <inet6> instead" ;
 427
 428 : with-local-address ( addr quot -- )
 429     [
 430         [ ] [ inet4? ] [ inet6? ] tri or
 431         [ bind-local-address ]
 432         [ invalid-local-address ] if
 433     ] dip with-variable ; inline
 434
 435 : protocol-port ( protocol -- port )
 436     [ f getservbyname [ port>> htons ] [ f ] if* ] [ f ] if* ;
 437
 438
 439 GENERIC: <random-local-inet> ( inet -- inet4 )
 440 M: inet4 <random-local-inet> drop f 0 <inet4> ;
 441 M: inet <random-local-inet> drop resolve-localhost random ;
 442 M: inet6 <random-local-inet> drop f 0 <inet6> ;
 443
 444 : <random-local-datagram> ( inet -- datagram )
 445     <random-local-inet> <datagram> ;
 446
 447 : <random-local-broadcast> ( inet -- datagram )
 448     <random-local-inet> <broadcast> ;
 449
 450 : with-random-local-datagram ( quot -- )
 451     [ dup <random-local-datagram> ] dip with-disposal ; inline
 452
 453 : with-random-local-broadcast ( quot -- )
 454     [ dup <random-local-broadcast> ] dip with-disposal ; inline
 455
 456 : send-once ( bytes addrspec -- )
 457     [ send ] with-random-local-datagram ;
 458
 459 : broadcast-once ( bytes addrspec -- )
 460     [ send ] with-random-local-broadcast ;
 461
 462 {
 463     { [ os unix? ] [ "io.sockets.unix" require ] }
 464     { [ os windows? ] [ "io.sockets.windows" require ] }
 465 } cond