basis/io/sockets/sockets.factor

   1 ! Copyright (C) 2007, 2008 Slava Pestov, Doug Coleman,
   2 ! Daniel Ehrenberg.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: generic kernel io.backend namespaces continuations sequences
   5 arrays io.encodings io.ports io.streams.duplex io.encodings.ascii
   6 alien.strings io.binary accessors destructors classes byte-arrays
   7 parser alien.c-types math.parser splitting grouping math assocs
   8 summary system vocabs.loader combinators present fry vocabs.parser
   9 classes.struct alien.data ;
  10 IN: io.sockets
  11
  12 << {
  13     { [ os windows? ] [ "windows.winsock" ] }
  14     { [ os unix? ] [ "unix.ffi" ] }
  15 } cond use-vocab >>
  16
  17 ! Addressing
  18 <PRIVATE
  19
  20 GENERIC: protocol-family ( addrspec -- af )
  21
  22 GENERIC: sockaddr-size ( addrspec -- n )
  23
  24 GENERIC: make-sockaddr ( addrspec -- sockaddr )
  25
  26 GENERIC: empty-sockaddr ( addrspec -- sockaddr )
  27
  28 GENERIC: address-size ( addrspec -- n )
  29
  30 GENERIC: inet-ntop ( data addrspec -- str )
  31
  32 GENERIC: inet-pton ( str addrspec -- data )
  33
  34 : make-sockaddr/size ( addrspec -- sockaddr size )
  35     [ make-sockaddr ] [ sockaddr-size ] bi ;
  36
  37 : empty-sockaddr/size ( addrspec -- sockaddr size )
  38     [ empty-sockaddr ] [ sockaddr-size ] bi ;
  39
  40 GENERIC: parse-sockaddr ( sockaddr addrspec -- newaddrspec )
  41
  42 HOOK: sockaddr-of-family os ( alien af -- sockaddr )
  43
  44 HOOK: addrspec-of-family os ( af -- addrspec )
  45
  46 PRIVATE>
  47
  48 TUPLE: abstract-inet host port ;
  49
  50 M: abstract-inet present
  51     [ host>> ":" ] [ port>> number>string ] bi 3append ;
  52
  53 TUPLE: local path ;
  54
  55 : <local> ( path -- addrspec )
  56     normalize-path local boa ;
  57
  58 M: local present path>> "Unix domain socket: " prepend ;
  59
  60 TUPLE: inet4 < abstract-inet ;
  61
  62 C: <inet4> inet4
  63
  64 M: inet4 inet-ntop ( data addrspec -- str )
  65     drop 4 memory>byte-array [ number>string ] { } map-as "." join ;
  66
  67 ERROR: malformed-inet4 sequence ;
  68 ERROR: bad-inet4-component string ;
  69
  70 : parse-inet4 ( string -- seq )
  71     "." split dup length 4 = [
  72         malformed-inet4
  73     ] unless
  74     [
  75         string>number
  76         [ "Dotted component not a number" throw ] unless*
  77     ] B{ } map-as ;
  78
  79 ERROR: invalid-inet4 string reason ;
  80
  81 M: invalid-inet4 summary drop "Invalid IPv4 address" ;
  82
  83 M: inet4 inet-pton ( str addrspec -- data )
  84     drop
  85     [ parse-inet4 ] [ invalid-inet4 ] recover ;
  86
  87 M: inet4 address-size drop 4 ;
  88
  89 M: inet4 protocol-family drop PF_INET ;
  90
  91 M: inet4 sockaddr-size drop sockaddr-in heap-size ;
  92
  93 M: inet4 empty-sockaddr drop sockaddr-in <struct> ;
  94
  95 M: inet4 make-sockaddr ( inet -- sockaddr )
  96     sockaddr-in <struct>
  97         AF_INET >>family
  98         swap [ port>> htons >>port ]
  99             [ host>> "0.0.0.0" or ]
 100             [ inet-pton *uint >>addr ] tri ;
 101
 102 M: inet4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
 103     [ [ addr>> <uint> ] dip inet-ntop ]
 104     [ drop port>> ntohs ] 2bi <inet4> ;
 105
 106 TUPLE: inet6 < abstract-inet ;
 107
 108 C: <inet6> inet6
 109
 110 M: inet6 inet-ntop ( data addrspec -- str )
 111     drop 16 memory>byte-array 2 <groups> [ be> >hex ] map ":" join ;
 112
 113 ERROR: invalid-inet6 string reason ;
 114
 115 M: invalid-inet6 summary drop "Invalid IPv6 address" ;
 116
 117 <PRIVATE
 118
 119 ERROR: bad-ipv6-component obj ;
 120
 121 ERROR: bad-ipv4-embedded-prefix obj ;
 122
 123 : parse-ipv6-component ( seq -- seq' )
 124     [ dup hex> [ nip ] [ bad-ipv6-component ] if* ] { } map-as ;
 125
 126 : parse-inet6 ( string -- seq )
 127     [ f ] [
 128         ":" split CHAR: . over last member? [
 129             unclip-last
 130             [ parse-ipv6-component ] [ parse-inet4 ] bi* append
 131         ] [
 132             parse-ipv6-component
 133         ] if
 134     ] if-empty ;
 135
 136 : pad-inet6 ( string1 string2 -- seq )
 137     2dup [ length ] bi@ + 8 swap -
 138     dup 0 < [ "More than 8 components" throw ] when
 139     <byte-array> glue ;
 140
 141 : inet6-bytes ( seq -- bytes )
 142     [ 2 >be ] { } map-as B{ } concat-as ;
 143
 144 PRIVATE>
 145
 146 M: inet6 inet-pton ( str addrspec -- data )
 147     drop
 148     [
 149         "::" split1 [ parse-inet6 ] bi@ pad-inet6 inet6-bytes
 150     ] [ invalid-inet6 ] recover ;
 151
 152 M: inet6 address-size drop 16 ;
 153
 154 M: inet6 protocol-family drop PF_INET6 ;
 155
 156 M: inet6 sockaddr-size drop sockaddr-in6 heap-size ;
 157
 158 M: inet6 empty-sockaddr drop sockaddr-in6 <struct> ;
 159
 160 M: inet6 make-sockaddr ( inet -- sockaddr )
 161     sockaddr-in6 <struct>
 162         AF_INET6 >>family
 163         swap [ port>> htons >>port ]
 164             [ host>> "::" or ]
 165             [ inet-pton >>addr ] tri ;
 166
 167 M: inet6 parse-sockaddr
 168     [ [ addr>> ] dip inet-ntop ]
 169     [ drop port>> ntohs ] 2bi <inet6> ;
 170
 171 M: f parse-sockaddr nip ;
 172
 173 <PRIVATE
 174
 175 GENERIC: (get-local-address) ( handle remote -- sockaddr )
 176
 177 : get-local-address ( handle remote -- local )
 178     [ (get-local-address) ] keep parse-sockaddr ;
 179
 180 GENERIC: (get-remote-address) ( handle remote -- sockaddr )
 181
 182 : get-remote-address ( handle local -- remote )
 183     [ (get-remote-address) ] keep parse-sockaddr ;
 184
 185 : <ports> ( handle -- input-port output-port )
 186     [
 187         [ <input-port> |dispose ] [ <output-port> |dispose ] bi
 188     ] with-destructors ;
 189
 190 SYMBOL: bind-local-address
 191
 192 GENERIC: establish-connection ( client-out remote -- )
 193
 194 GENERIC: ((client)) ( remote -- handle )
 195
 196 GENERIC: (client) ( remote -- client-in client-out local )
 197
 198 M: array (client) [ (client) 3array ] attempt-all first3 ;
 199
 200 M: object (client) ( remote -- client-in client-out local )
 201     [
 202         [ ((client)) ] keep
 203         [
 204             [ <ports> [ |dispose ] bi@ dup ] dip
 205             establish-connection
 206         ]
 207         [ get-local-address ]
 208         2bi
 209     ] with-destructors ;
 210
 211 TUPLE: server-port < port addr encoding ;
 212
 213 : check-server-port ( port -- port )
 214     dup check-disposed
 215     dup server-port? [ "Not a server port" throw ] unless ; inline
 216
 217 GENERIC: (server) ( addrspec -- handle )
 218
 219 GENERIC: (accept) ( server addrspec -- handle sockaddr )
 220
 221 TUPLE: datagram-port < port addr ;
 222
 223 HOOK: (datagram) io-backend ( addr -- datagram )
 224
 225 : check-datagram-port ( port -- port )
 226     dup check-disposed
 227     dup datagram-port? [ "Not a datagram port" throw ] unless ; inline
 228
 229 HOOK: (receive) io-backend ( datagram -- packet addrspec )
 230
 231 : check-datagram-send ( packet addrspec port -- packet addrspec port )
 232     check-datagram-port
 233     2dup addr>> [ class ] bi@ assert=
 234     pick class byte-array assert= ;
 235
 236 HOOK: (send) io-backend ( packet addrspec datagram -- )
 237
 238 : addrinfo>addrspec ( addrinfo -- addrspec )
 239     [ [ addr>> ] [ family>> ] bi sockaddr-of-family ]
 240     [ family>> addrspec-of-family ] bi
 241     parse-sockaddr ;
 242
 243 : parse-addrinfo-list ( addrinfo -- seq )
 244     [ next>> ] follow
 245     [ addrinfo>addrspec ] map
 246     sift ;
 247
 248 HOOK: addrinfo-error io-backend ( n -- )
 249
 250 : resolve-passive-host ( -- addrspecs )
 251     { T{ inet6 f "::" f } T{ inet4 f "0.0.0.0" f } } [ clone ] map ;
 252
 253 : prepare-addrinfo ( -- addrinfo )
 254     addrinfo <struct>
 255         PF_UNSPEC >>family
 256         IPPROTO_TCP >>protocol ;
 257
 258 : fill-in-ports ( addrspecs port -- addrspecs )
 259     '[ _ >>port ] map ;
 260
 261 PRIVATE>
 262
 263 : <client> ( remote encoding -- stream local )
 264     [ (client) ] dip swap [ <encoder-duplex> ] dip ;
 265
 266 SYMBOL: local-address
 267
 268 SYMBOL: remote-address
 269
 270 : with-client ( remote encoding quot -- )
 271     [
 272         [
 273             over remote-address set
 274             <client> local-address set
 275         ] dip with-stream
 276     ] with-scope ; inline
 277
 278 : <server> ( addrspec encoding -- server )
 279     [
 280         [ (server) ] keep
 281         [ drop server-port <port> ] [ get-local-address ] 2bi
 282         >>addr
 283     ] dip >>encoding ;
 284
 285 : accept ( server -- client remote )
 286     [
 287         dup addr>>
 288         [ (accept) ] keep
 289         parse-sockaddr swap
 290         <ports>
 291     ] keep encoding>> <encoder-duplex> swap ;
 292
 293 : <datagram> ( addrspec -- datagram )
 294     [
 295         [ (datagram) |dispose ] keep
 296         [ drop datagram-port <port> ] [ get-local-address ] 2bi
 297         >>addr
 298     ] with-destructors ;
 299
 300 : receive ( datagram -- packet addrspec )
 301     check-datagram-port
 302     [ (receive) ] [ addr>> ] bi parse-sockaddr ;
 303
 304 : send ( packet addrspec datagram -- )
 305     check-datagram-send (send) ;
 306
 307 GENERIC: resolve-host ( addrspec -- seq )
 308
 309 TUPLE: inet < abstract-inet ;
 310
 311 C: <inet> inet
 312
 313 M: inet resolve-host
 314     [ port>> ] [ host>> ] bi [
 315         f prepare-addrinfo f <void*>
 316         [ getaddrinfo addrinfo-error ] keep *void* addrinfo memory>struct
 317         [ parse-addrinfo-list ] keep freeaddrinfo
 318     ] [ resolve-passive-host ] if*
 319     swap fill-in-ports ;
 320
 321 M: f resolve-host drop { } ;
 322
 323 M: object resolve-host 1array ;
 324
 325 : host-name ( -- string )
 326     256 <byte-array> dup dup length gethostname
 327     zero? [ "gethostname failed" throw ] unless
 328     ascii alien>string ;
 329
 330 M: inet (client) resolve-host (client) ;
 331
 332 ERROR: invalid-inet-server addrspec ;
 333
 334 M: invalid-inet-server summary
 335     drop "Cannot use <server> with <inet>; use <inet4> or <inet6> instead" ;
 336
 337 M: inet (server)
 338     invalid-inet-server ;
 339
 340 ERROR: invalid-local-address addrspec ;
 341
 342 M: invalid-local-address summary
 343     drop "Cannot use with-local-address with <inet>; use <inet4> or <inet6> instead" ;
 344
 345 : with-local-address ( addr quot -- )
 346     [
 347         [ ] [ inet4? ] [ inet6? ] tri or
 348         [ bind-local-address ]
 349         [ invalid-local-address ] if
 350     ] dip with-variable ; inline
 351
 352 {
 353     { [ os unix? ] [ "io.sockets.unix" require ] }
 354     { [ os winnt? ] [ "io.sockets.windows.nt" require ] }
 355 } cond