basis/io/sockets/sockets.factor

   1 ! Copyright (C) 2007, 2010 Slava Pestov, Doug Coleman,
   2 ! Daniel Ehrenberg.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: accessors alien.c-types alien.data alien.strings arrays
   5 assocs byte-arrays classes classes.struct combinators
   6 combinators.short-circuit continuations destructors fry generic
   7 grouping io.backend io.binary io.encodings io.encodings.ascii
   8 io.encodings.binary io.ports io.streams.duplex kernel math
   9 math.parser namespaces parser present sequences splitting
  10 strings summary system vocabs.loader vocabs.parser ;
  11 IN: io.sockets
  12
  13 << {
  14     { [ os windows? ] [ "windows.winsock" ] }
  15     { [ os unix? ] [ "unix.ffi" ] }
  16 } cond use-vocab >>
  17
  18 ! Addressing
  19 <PRIVATE
  20
  21 UNION: ?string string POSTPONE: f ;
  22
  23 GENERIC: protocol ( addrspec -- n )
  24
  25 GENERIC: protocol-family ( addrspec -- af )
  26
  27 GENERIC: sockaddr-size ( addrspec -- n )
  28
  29 GENERIC: make-sockaddr ( addrspec -- sockaddr )
  30
  31 GENERIC: empty-sockaddr ( addrspec -- sockaddr )
  32
  33 GENERIC: address-size ( addrspec -- n )
  34
  35 GENERIC: inet-ntop ( data addrspec -- str )
  36
  37 GENERIC: inet-pton ( str addrspec -- data )
  38
  39 GENERIC# with-port 1 ( addrspec port -- addrspec )
  40
  41 : make-sockaddr/size ( addrspec -- sockaddr size )
  42     [ make-sockaddr ] [ sockaddr-size ] bi ;
  43
  44 : empty-sockaddr/size ( addrspec -- sockaddr size )
  45     [ empty-sockaddr ] [ sockaddr-size ] bi ;
  46
  47 GENERIC: parse-sockaddr ( sockaddr addrspec -- newaddrspec )
  48
  49 M: f parse-sockaddr nip ;
  50
  51 HOOK: sockaddr-of-family os ( alien af -- sockaddr )
  52
  53 HOOK: addrspec-of-family os ( af -- addrspec )
  54
  55 PRIVATE>
  56
  57 TUPLE: local { path read-only } ;
  58
  59 : <local> ( path -- addrspec )
  60     normalize-path local boa ;
  61
  62 M: local present path>> "Unix domain socket: " prepend ;
  63
  64 M: local protocol drop 0 ;
  65
  66 SLOT: port
  67
  68 TUPLE: ipv4 { host ?string read-only } ;
  69
  70 C: <ipv4> ipv4
  71
  72 M: ipv4 inet-ntop ( data addrspec -- str )
  73     drop 4 memory>byte-array [ number>string ] { } map-as "." join ;
  74
  75 <PRIVATE
  76
  77 ERROR: malformed-ipv4 sequence ;
  78
  79 ERROR: bad-ipv4-component string ;
  80
  81 : parse-ipv4 ( string -- seq )
  82     "." split dup length 4 = [ malformed-ipv4 ] unless
  83     [ dup string>number [ ] [ bad-ipv4-component ] ?if ] B{ } map-as ;
  84
  85 ERROR: invalid-ipv4 string reason ;
  86
  87 M: invalid-ipv4 summary drop "Invalid IPv4 address" ;
  88
  89 PRIVATE>
  90
  91 M: ipv4 inet-pton ( str addrspec -- data )
  92     drop [ parse-ipv4 ] [ invalid-ipv4 ] recover ;
  93
  94 M: ipv4 address-size drop 4 ;
  95
  96 M: ipv4 protocol-family drop PF_INET ;
  97
  98 M: ipv4 sockaddr-size drop sockaddr-in heap-size ;
  99
 100 M: ipv4 empty-sockaddr drop sockaddr-in <struct> ;
 101
 102 M: ipv4 make-sockaddr ( inet -- sockaddr )
 103     sockaddr-in <struct>
 104         AF_INET >>family
 105         swap
 106         [ port>> htons >>port ]
 107         [ host>> "0.0.0.0" or ]
 108         [ inet-pton *uint >>addr ] tri ;
 109
 110 M: ipv4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
 111     [ addr>> <uint> ] dip inet-ntop <ipv4> ;
 112
 113 TUPLE: inet4 < ipv4 { port integer read-only } ;
 114
 115 C: <inet4> inet4
 116
 117 M: ipv4 with-port [ host>> ] dip <inet4> ;
 118
 119 M: inet4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
 120     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 121
 122 M: inet4 present
 123     [ host>> ] [ port>> number>string ] bi ":" glue ;
 124
 125 M: inet4 protocol drop 0 ;
 126
 127 TUPLE: ipv6 { host ?string read-only } ;
 128
 129 C: <ipv6> ipv6
 130
 131 M: ipv6 inet-ntop ( data addrspec -- str )
 132     drop 16 memory>byte-array 2 <groups> [ be> >hex ] map ":" join ;
 133
 134 ERROR: invalid-ipv6 string reason ;
 135
 136 <PRIVATE
 137
 138 ERROR: bad-ipv6-component obj ;
 139
 140 ERROR: bad-ipv4-embedded-prefix obj ;
 141
 142 ERROR: more-than-8-components ;
 143
 144 : parse-ipv6-component ( seq -- seq' )
 145     [ dup hex> [ nip ] [ bad-ipv6-component ] if* ] { } map-as ;
 146
 147 : parse-ipv6 ( string -- seq )
 148     [ f ] [
 149         ":" split CHAR: . over last member? [
 150             unclip-last
 151             [ parse-ipv6-component ] [ parse-ipv4 ] bi* append
 152         ] [
 153             parse-ipv6-component
 154         ] if
 155     ] if-empty ;
 156
 157 : pad-ipv6 ( string1 string2 -- seq )
 158     2dup [ length ] bi@ + 8 swap -
 159     dup 0 < [ more-than-8-components ] when
 160     <byte-array> glue ;
 161
 162 : ipv6-bytes ( seq -- bytes )
 163     [ 2 >be ] { } map-as B{ } concat-as ;
 164
 165 PRIVATE>
 166
 167 M: ipv6 inet-pton ( str addrspec -- data )
 168     drop
 169     [ "::" split1 [ parse-ipv6 ] bi@ pad-ipv6 ipv6-bytes ]
 170     [ invalid-ipv6 ]
 171     recover ;
 172
 173 M: ipv6 address-size drop 16 ;
 174
 175 M: ipv6 protocol-family drop PF_INET6 ;
 176
 177 M: ipv6 sockaddr-size drop sockaddr-in6 heap-size ;
 178
 179 M: ipv6 empty-sockaddr drop sockaddr-in6 <struct> ;
 180
 181 M: ipv6 make-sockaddr ( inet -- sockaddr )
 182     sockaddr-in6 <struct>
 183         AF_INET6 >>family
 184         swap
 185         [ port>> htons >>port ]
 186         [ host>> "::" or ]
 187         [ inet-pton >>addr ] tri ;
 188
 189 M: ipv6 parse-sockaddr
 190     [ addr>> ] dip inet-ntop <ipv6> ;
 191
 192 TUPLE: inet6 < ipv6 { port integer read-only } ;
 193
 194 C: <inet6> inet6
 195
 196 M: ipv6 with-port [ host>> ] dip <inet6> ;
 197
 198 M: inet6 parse-sockaddr
 199     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 200
 201 M: inet6 present
 202     [ host>> ] [ port>> number>string ] bi ":" glue ;
 203
 204 M: inet6 protocol drop 0 ;
 205
 206 <PRIVATE
 207
 208 GENERIC: (get-local-address) ( handle remote -- sockaddr )
 209
 210 : get-local-address ( handle remote -- local )
 211     [ (get-local-address) ] keep parse-sockaddr ;
 212
 213 GENERIC: (get-remote-address) ( handle remote -- sockaddr )
 214
 215 : get-remote-address ( handle local -- remote )
 216     [ (get-remote-address) ] keep parse-sockaddr ;
 217
 218 : <ports> ( handle -- input-port output-port )
 219     [
 220         [ <input-port> |dispose ] [ <output-port> |dispose ] bi
 221     ] with-destructors ;
 222
 223 SYMBOL: bind-local-address
 224
 225 GENERIC: establish-connection ( client-out remote -- )
 226
 227 GENERIC: ((client)) ( remote -- handle )
 228
 229 GENERIC: (client) ( remote -- client-in client-out local )
 230
 231 M: array (client) [ (client) 3array ] attempt-all first3 ;
 232
 233 M: object (client) ( remote -- client-in client-out local )
 234     [
 235         [ ((client)) ] keep
 236         [
 237             [ <ports> [ |dispose ] bi@ dup ] dip
 238             establish-connection
 239         ]
 240         [ get-local-address ]
 241         2bi
 242     ] with-destructors ;
 243
 244 TUPLE: server-port < port addr encoding ;
 245
 246 : check-server-port ( port -- port )
 247     dup check-disposed
 248     dup server-port? [ "Not a server port" throw ] unless ; inline
 249
 250 GENERIC: (server) ( addrspec -- handle )
 251
 252 GENERIC: (accept) ( server addrspec -- handle sockaddr )
 253
 254 TUPLE: datagram-port < port addr ;
 255
 256 HOOK: (datagram) io-backend ( addr -- datagram )
 257
 258
 259 TUPLE: raw-port < port addr ;
 260
 261 HOOK: (raw) io-backend ( addr -- raw )
 262
 263 HOOK: (receive) io-backend ( datagram -- packet addrspec )
 264
 265 ERROR: invalid-port object ;
 266
 267 : check-port ( packet addrspec port -- packet addrspec port )
 268     2dup addr>> [ class ] bi@ assert=
 269     pick class byte-array assert= ;
 270
 271 : check-connectionless-port ( port -- port )
 272     dup { [ datagram-port? ] [ raw-port? ] } 1|| [ invalid-port ] unless ;
 273
 274 : check-send ( packet addrspec port -- packet addrspec port )
 275     check-connectionless-port dup check-disposed check-port ;
 276
 277 : check-receive ( port -- port )
 278     check-connectionless-port dup check-disposed ;
 279
 280 HOOK: (send) io-backend ( packet addrspec datagram -- )
 281
 282 : addrinfo>addrspec ( addrinfo -- addrspec )
 283     [ [ addr>> ] [ family>> ] bi sockaddr-of-family ]
 284     [ family>> addrspec-of-family ] bi
 285     parse-sockaddr ;
 286
 287 : parse-addrinfo-list ( addrinfo -- seq )
 288     [ next>> ] follow
 289     [ addrinfo>addrspec ] map
 290     sift ;
 291
 292 HOOK: addrinfo-error io-backend ( n -- )
 293
 294 : prepare-addrinfo ( -- addrinfo )
 295     addrinfo <struct>
 296         PF_UNSPEC >>family
 297         IPPROTO_TCP >>protocol ;
 298
 299 PRIVATE>
 300
 301 : <client> ( remote encoding -- stream local )
 302     [ (client) ] dip swap [ <encoder-duplex> ] dip ;
 303
 304 SYMBOL: local-address
 305
 306 SYMBOL: remote-address
 307
 308 : with-client ( remote encoding quot -- )
 309     [
 310         [
 311             over remote-address set
 312             <client> local-address set
 313         ] dip with-stream
 314     ] with-scope ; inline
 315
 316 : <server> ( addrspec encoding -- server )
 317     [
 318         [ (server) ] keep
 319         [ drop server-port <port> ] [ get-local-address ] 2bi
 320         >>addr
 321     ] dip >>encoding ;
 322
 323 : accept ( server -- client remote )
 324     [
 325         dup addr>>
 326         [ (accept) ] keep
 327         parse-sockaddr swap
 328         <ports>
 329     ] keep encoding>> <encoder-duplex> swap ;
 330
 331 : <datagram> ( addrspec -- datagram )
 332     [
 333         [ (datagram) |dispose ] keep
 334         [ drop datagram-port <port> ] [ get-local-address ] 2bi
 335         >>addr
 336     ] with-destructors ;
 337
 338 : <raw> ( addrspec -- datagram )
 339     [
 340         [ (raw) |dispose ] keep
 341         [ drop raw-port <port> ] [ get-local-address ] 2bi
 342         >>addr
 343     ] with-destructors ;
 344
 345 : receive ( datagram -- packet addrspec )
 346     check-receive
 347     [ (receive) ] [ addr>> ] bi parse-sockaddr ;
 348
 349 : send ( packet addrspec datagram -- )
 350     check-send (send) ;
 351
 352 GENERIC: resolve-host ( addrspec -- seq )
 353
 354 TUPLE: hostname { host ?string read-only } ;
 355
 356 TUPLE: inet < hostname port ;
 357
 358 M: inet present
 359     [ host>> ] [ port>> number>string ] bi ":" glue ;
 360
 361 C: <inet> inet
 362
 363 M: string resolve-host
 364     f prepare-addrinfo f <void*>
 365     [ getaddrinfo addrinfo-error ] keep *void* addrinfo memory>struct
 366     [ parse-addrinfo-list ] keep freeaddrinfo ;
 367
 368 M: hostname resolve-host
 369     host>> resolve-host ;
 370
 371 M: inet resolve-host
 372     [ call-next-method ] [ port>> ] bi '[ _ with-port ] map ;
 373
 374 M: inet4 resolve-host 1array ;
 375
 376 M: inet6 resolve-host 1array ;
 377
 378 M: local resolve-host 1array ;
 379
 380 M: f resolve-host
 381     drop { T{ ipv6 f "::" } T{ ipv4 f "0.0.0.0" } } ;
 382
 383 : host-name ( -- string )
 384     256 <byte-array> dup dup length gethostname
 385     zero? [ "gethostname failed" throw ] unless
 386     ascii alien>string ;
 387
 388 M: inet (client) resolve-host (client) ;
 389
 390 ERROR: invalid-inet-server addrspec ;
 391
 392 M: invalid-inet-server summary
 393     drop "Cannot use <server> with <inet>; use <inet4> or <inet6> instead" ;
 394
 395 M: inet (server)
 396     invalid-inet-server ;
 397
 398 ERROR: invalid-local-address addrspec ;
 399
 400 M: invalid-local-address summary
 401     drop "Cannot use with-local-address with <inet>; use <inet4> or <inet6> instead" ;
 402
 403 : with-local-address ( addr quot -- )
 404     [
 405         [ ] [ inet4? ] [ inet6? ] tri or
 406         [ bind-local-address ]
 407         [ invalid-local-address ] if
 408     ] dip with-variable ; inline
 409
 410 : ipv6-supported? ( -- ? )
 411     [ "::1" 0 <inet6> binary <server> dispose t ] [ drop f ] recover ;
 412
 413 {
 414     { [ os unix? ] [ "io.sockets.unix" require ] }
 415     { [ os windows? ] [ "io.sockets.windows" require ] }
 416 } cond