basis/io/sockets/sockets.factor

   1 ! Copyright (C) 2007, 2010 Slava Pestov, Doug Coleman,
   2 ! Daniel Ehrenberg.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: accessors alien.c-types alien.data alien.strings arrays
   5 assocs byte-arrays classes classes.struct combinators
   6 combinators.short-circuit continuations destructors fry generic
   7 grouping init io.backend io.binary io.encodings
   8 io.encodings.ascii io.encodings.binary io.ports
   9 io.streams.duplex kernel math math.parser memoize namespaces
  10 parser present sequences splitting strings summary system
  11 vocabs.loader vocabs.parser ;
  12 IN: io.sockets
  13
  14 << {
  15     { [ os windows? ] [ "windows.winsock" ] }
  16     { [ os unix? ] [ "unix.ffi" ] }
  17 } cond use-vocab >>
  18
  19 ! Addressing
  20 <PRIVATE
  21
  22 UNION: ?string string POSTPONE: f ;
  23
  24 GENERIC: protocol ( addrspec -- n )
  25
  26 GENERIC: protocol-family ( addrspec -- af )
  27
  28 GENERIC: sockaddr-size ( addrspec -- n )
  29
  30 GENERIC: make-sockaddr ( addrspec -- sockaddr )
  31
  32 GENERIC: empty-sockaddr ( addrspec -- sockaddr )
  33
  34 GENERIC: address-size ( addrspec -- n )
  35
  36 GENERIC: inet-ntop ( data addrspec -- str )
  37
  38 GENERIC: inet-pton ( str addrspec -- data )
  39
  40 : make-sockaddr/size ( addrspec -- sockaddr size )
  41     [ make-sockaddr ] [ sockaddr-size ] bi ;
  42
  43 : empty-sockaddr/size ( addrspec -- sockaddr size )
  44     [ empty-sockaddr ] [ sockaddr-size ] bi ;
  45
  46 GENERIC: parse-sockaddr ( sockaddr addrspec -- newaddrspec )
  47
  48 M: f parse-sockaddr nip ;
  49
  50 HOOK: sockaddr-of-family os ( alien af -- sockaddr )
  51
  52 HOOK: addrspec-of-family os ( af -- addrspec )
  53
  54 PRIVATE>
  55
  56 GENERIC# with-port 1 ( addrspec port -- addrspec )
  57
  58 TUPLE: local { path read-only } ;
  59
  60 : <local> ( path -- addrspec )
  61     normalize-path local boa ;
  62
  63 M: local present path>> "Unix domain socket: " prepend ;
  64
  65 M: local protocol drop 0 ;
  66
  67 SLOT: port
  68
  69 TUPLE: ipv4 { host ?string read-only } ;
  70
  71 C: <ipv4> ipv4
  72
  73 M: ipv4 inet-ntop ( data addrspec -- str )
  74     drop 4 memory>byte-array [ number>string ] { } map-as "." join ;
  75
  76 <PRIVATE
  77
  78 ERROR: malformed-ipv4 sequence ;
  79
  80 ERROR: bad-ipv4-component string ;
  81
  82 : parse-ipv4 ( string -- seq )
  83     "." split dup length 4 = [ malformed-ipv4 ] unless
  84     [ dup string>number [ ] [ bad-ipv4-component ] ?if ] B{ } map-as ;
  85
  86 ERROR: invalid-ipv4 string reason ;
  87
  88 M: invalid-ipv4 summary drop "Invalid IPv4 address" ;
  89
  90 PRIVATE>
  91
  92 M: ipv4 inet-pton ( str addrspec -- data )
  93     drop [ parse-ipv4 ] [ invalid-ipv4 ] recover ;
  94
  95 M: ipv4 address-size drop 4 ;
  96
  97 M: ipv4 protocol-family drop PF_INET ;
  98
  99 M: ipv4 sockaddr-size drop sockaddr-in heap-size ;
 100
 101 M: ipv4 empty-sockaddr drop sockaddr-in <struct> ;
 102
 103 M: ipv4 make-sockaddr ( inet -- sockaddr )
 104     sockaddr-in <struct>
 105         AF_INET >>family
 106         swap
 107         [ port>> htons >>port ]
 108         [ host>> "0.0.0.0" or ]
 109         [ inet-pton *uint >>addr ] tri ;
 110
 111 M: ipv4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
 112     [ addr>> <uint> ] dip inet-ntop <ipv4> ;
 113
 114 TUPLE: inet4 < ipv4 { port integer read-only } ;
 115
 116 : inet-string? ( string exemplar -- ? )
 117     '[ _ _ inet-pton drop t ] [ drop f ] recover ;
 118
 119 : inet4-string? ( string -- ? ) T{ inet4 } inet-string? ;
 120
 121 ERROR: invalid-inet4 string ;
 122
 123 : ensure-inet4-string ( string -- string )
 124     dup [ dup inet4-string? [ invalid-inet4 ] unless ] when ;
 125
 126 : <inet4> ( host port -- inet4 )
 127     [ ensure-inet4-string ] dip inet4 boa ;
 128
 129 M: ipv4 with-port [ host>> ] dip <inet4> ;
 130
 131 M: inet4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
 132     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 133
 134 M: inet4 present
 135     [ host>> ] [ port>> number>string ] bi ":" glue ;
 136
 137 M: inet4 protocol drop 0 ;
 138
 139 TUPLE: ipv6 { host ?string read-only } ;
 140
 141 C: <ipv6> ipv6
 142
 143 M: ipv6 inet-ntop ( data addrspec -- str )
 144     drop 16 memory>byte-array 2 <groups> [ be> >hex ] map ":" join ;
 145
 146 ERROR: invalid-ipv6 string reason ;
 147
 148 <PRIVATE
 149
 150 ERROR: bad-ipv6-component obj ;
 151
 152 ERROR: bad-ipv4-embedded-prefix obj ;
 153
 154 ERROR: more-than-8-components ;
 155
 156 : parse-ipv6-component ( seq -- seq' )
 157     [ dup hex> [ nip ] [ bad-ipv6-component ] if* ] { } map-as ;
 158
 159 : parse-ipv6 ( string -- seq )
 160     [ f ] [
 161         ":" split CHAR: . over last member? [
 162             unclip-last
 163             [ parse-ipv6-component ] [ parse-ipv4 ] bi* append
 164         ] [
 165             parse-ipv6-component
 166         ] if
 167     ] if-empty ;
 168
 169 : pad-ipv6 ( string1 string2 -- seq )
 170     2dup [ length ] bi@ + 8 swap -
 171     dup 0 < [ more-than-8-components ] when
 172     <byte-array> glue ;
 173
 174 : ipv6-bytes ( seq -- bytes )
 175     [ 2 >be ] { } map-as B{ } concat-as ;
 176
 177 PRIVATE>
 178
 179 ERROR: empty-ipv6 ;
 180
 181 M: ipv6 inet-pton ( str addrspec -- data )
 182     drop [
 183         [ empty-ipv6 ]
 184         [ "::" split1 [ parse-ipv6 ] bi@ pad-ipv6 ipv6-bytes ] if-empty
 185     ] [ invalid-ipv6 ] recover ;
 186
 187 M: ipv6 address-size drop 16 ;
 188
 189 M: ipv6 protocol-family drop PF_INET6 ;
 190
 191 M: ipv6 sockaddr-size drop sockaddr-in6 heap-size ;
 192
 193 M: ipv6 empty-sockaddr drop sockaddr-in6 <struct> ;
 194
 195 M: ipv6 make-sockaddr ( inet -- sockaddr )
 196     sockaddr-in6 <struct>
 197         AF_INET6 >>family
 198         swap
 199         [ port>> htons >>port ]
 200         [ host>> "::" or ]
 201         [ inet-pton >>addr ] tri ;
 202
 203 M: ipv6 parse-sockaddr
 204     [ addr>> ] dip inet-ntop <ipv6> ;
 205
 206 TUPLE: inet6 < ipv6 { port integer read-only } ;
 207
 208 : inet6-string? ( string -- ? ) T{ inet6 } inet-string? ;
 209
 210 ERROR: invalid-inet6 string ;
 211
 212 : ensure-inet6-string ( string -- string )
 213     dup [ dup inet6-string? [ invalid-inet6 ] unless ] when ;
 214
 215 : <inet6> ( host port -- inet6 )
 216     [ ensure-inet6-string ] dip inet6 boa ;
 217
 218 M: ipv6 with-port [ host>> ] dip <inet6> ;
 219
 220 M: inet6 parse-sockaddr
 221     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 222
 223 M: inet6 present
 224     [ host>> ] [ port>> number>string ] bi ":" glue ;
 225
 226 M: inet6 protocol drop 0 ;
 227
 228 <PRIVATE
 229
 230 GENERIC: (get-local-address) ( handle remote -- sockaddr )
 231
 232 : get-local-address ( handle remote -- local )
 233     [ (get-local-address) ] keep parse-sockaddr ;
 234
 235 GENERIC: (get-remote-address) ( handle remote -- sockaddr )
 236
 237 : get-remote-address ( handle local -- remote )
 238     [ (get-remote-address) ] keep parse-sockaddr ;
 239
 240 : <ports> ( handle -- input-port output-port )
 241     [
 242         [ <input-port> |dispose ] [ <output-port> |dispose ] bi
 243     ] with-destructors ;
 244
 245 SYMBOL: bind-local-address
 246
 247 GENERIC: establish-connection ( client-out remote -- )
 248
 249 GENERIC: ((client)) ( remote -- handle )
 250
 251 GENERIC: (client) ( remote -- client-in client-out local )
 252
 253 M: array (client) [ (client) 3array ] attempt-all first3 ;
 254
 255 M: object (client) ( remote -- client-in client-out local )
 256     [
 257         [ ((client)) ] keep
 258         [
 259             [ <ports> [ |dispose ] bi@ dup ] dip
 260             establish-connection
 261         ]
 262         [ get-local-address ]
 263         2bi
 264     ] with-destructors ;
 265
 266 TUPLE: server-port < port addr encoding ;
 267
 268 : check-server-port ( port -- port )
 269     dup check-disposed
 270     dup server-port? [ "Not a server port" throw ] unless ; inline
 271
 272 GENERIC: (server) ( addrspec -- handle )
 273
 274 GENERIC: (accept) ( server addrspec -- handle sockaddr )
 275
 276 TUPLE: datagram-port < port addr ;
 277
 278 HOOK: (datagram) io-backend ( addr -- datagram )
 279
 280 TUPLE: raw-port < port addr ;
 281
 282 HOOK: (raw) io-backend ( addr -- raw )
 283
 284 HOOK: (receive) io-backend ( datagram -- packet addrspec )
 285
 286 ERROR: invalid-port object ;
 287
 288 : check-port ( packet addrspec port -- packet addrspec port )
 289     2dup addr>> [ class ] bi@ assert=
 290     pick class byte-array assert= ;
 291
 292 : check-connectionless-port ( port -- port )
 293     dup { [ datagram-port? ] [ raw-port? ] } 1|| [ invalid-port ] unless ;
 294
 295 : check-send ( packet addrspec port -- packet addrspec port )
 296     check-connectionless-port dup check-disposed check-port ;
 297
 298 : check-receive ( port -- port )
 299     check-connectionless-port dup check-disposed ;
 300
 301 HOOK: (send) io-backend ( packet addrspec datagram -- )
 302
 303 : addrinfo>addrspec ( addrinfo -- addrspec )
 304     [ [ addr>> ] [ family>> ] bi sockaddr-of-family ]
 305     [ family>> addrspec-of-family ] bi
 306     parse-sockaddr ;
 307
 308 : parse-addrinfo-list ( addrinfo -- seq )
 309     [ next>> ] follow
 310     [ addrinfo>addrspec ] map
 311     sift ;
 312
 313 HOOK: addrinfo-error io-backend ( n -- )
 314
 315 : prepare-addrinfo ( -- addrinfo )
 316     addrinfo <struct>
 317         PF_UNSPEC >>family
 318         IPPROTO_TCP >>protocol ;
 319
 320 PRIVATE>
 321
 322 : <client> ( remote encoding -- stream local )
 323     [ (client) ] dip swap [ <encoder-duplex> ] dip ;
 324
 325 SYMBOL: local-address
 326
 327 SYMBOL: remote-address
 328
 329 : with-client ( remote encoding quot -- )
 330     [
 331         [
 332             over remote-address set
 333             <client> local-address set
 334         ] dip with-stream
 335     ] with-scope ; inline
 336
 337 : <server> ( addrspec encoding -- server )
 338     [
 339         [ (server) ] keep
 340         [ drop server-port <port> ] [ get-local-address ] 2bi
 341         >>addr
 342     ] dip >>encoding ;
 343
 344 : accept ( server -- client remote )
 345     [
 346         dup addr>>
 347         [ (accept) ] keep
 348         parse-sockaddr swap
 349         <ports>
 350     ] keep encoding>> <encoder-duplex> swap ;
 351
 352 : <datagram> ( addrspec -- datagram )
 353     [
 354         [ (datagram) |dispose ] keep
 355         [ drop datagram-port <port> ] [ get-local-address ] 2bi
 356         >>addr
 357     ] with-destructors ;
 358
 359 : <raw> ( addrspec -- datagram )
 360     [
 361         [ (raw) |dispose ] keep
 362         [ drop raw-port <port> ] [ get-local-address ] 2bi
 363         >>addr
 364     ] with-destructors ;
 365
 366 : receive ( datagram -- packet addrspec )
 367     check-receive
 368     [ (receive) ] [ addr>> ] bi parse-sockaddr ;
 369
 370 : send ( packet addrspec datagram -- )
 371     check-send (send) ;
 372
 373 MEMO: ipv6-supported? ( -- ? )
 374     [ "::1" 0 <inet6> binary <server> dispose t ] [ drop f ] recover ;
 375
 376 [ \ ipv6-supported? reset-memoized ] "io.sockets" add-startup-hook
 377
 378 GENERIC: resolve-host ( addrspec -- seq )
 379
 380 HOOK: resolve-localhost os ( -- obj )
 381
 382 TUPLE: hostname { host ?string read-only } ;
 383
 384 TUPLE: inet < hostname port ;
 385
 386 M: inet present
 387     [ host>> ] [ port>> number>string ] bi ":" glue ;
 388
 389 : <inet> ( host port -- inet )
 390     {
 391         { [ over inet4-string? ] [ inet4 boa ] }
 392         { [ over inet6-string? ] [ inet6 boa ] }
 393         [ inet boa ]
 394     } cond ;
 395
 396 M: inet with-port [ host>> ] dip <inet> ;
 397
 398 M: string resolve-host
 399     f prepare-addrinfo f <void*>
 400     [ getaddrinfo addrinfo-error ] keep *void* addrinfo memory>struct
 401     [ parse-addrinfo-list ] keep freeaddrinfo ;
 402
 403 M: hostname resolve-host
 404     host>> resolve-host ;
 405
 406 M: inet resolve-host
 407     [ call-next-method ] [ port>> ] bi '[ _ with-port ] map ;
 408
 409 M: inet4 resolve-host 1array ;
 410
 411 M: inet6 resolve-host 1array ;
 412
 413 M: local resolve-host 1array ;
 414
 415 M: f resolve-host
 416     drop resolve-localhost ;
 417
 418 M: object resolve-localhost
 419     ipv6-supported?
 420     { T{ ipv4 f "0.0.0.0" } T{ ipv6 f "::" } }
 421     { T{ ipv4 f "0.0.0.0" } }
 422     ? ;
 423
 424 : host-name ( -- string )
 425     256 <byte-array> dup dup length gethostname
 426     zero? [ "gethostname failed" throw ] unless
 427     ascii alien>string ;
 428
 429 M: inet (client) resolve-host (client) ;
 430
 431 ERROR: invalid-inet-server addrspec ;
 432
 433 M: invalid-inet-server summary
 434     drop "Cannot use <server> with <inet>; use <inet4> or <inet6> instead" ;
 435
 436 M: inet (server)
 437     invalid-inet-server ;
 438
 439 ERROR: invalid-local-address addrspec ;
 440
 441 M: invalid-local-address summary
 442     drop "Cannot use with-local-address with <inet>; use <inet4> or <inet6> instead" ;
 443
 444 : with-local-address ( addr quot -- )
 445     [
 446         [ ] [ inet4? ] [ inet6? ] tri or
 447         [ bind-local-address ]
 448         [ invalid-local-address ] if
 449     ] dip with-variable ; inline
 450
 451 {
 452     { [ os unix? ] [ "io.sockets.unix" require ] }
 453     { [ os windows? ] [ "io.sockets.windows" require ] }
 454 } cond