basis/io/sockets/sockets.factor

   1 ! Copyright (C) 2007, 2011 Slava Pestov, Doug Coleman,
   2 ! Daniel Ehrenberg.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: accessors alien.c-types alien.data alien.strings arrays
   5 assocs byte-arrays classes classes.struct combinators
   6 combinators.short-circuit continuations destructors fry generic
   7 grouping init io.backend io.binary io.encodings
   8 io.encodings.ascii io.encodings.binary io.pathnames io.ports
   9 io.streams.duplex kernel libc locals math math.parser memoize
  10 namespaces parser present sequences splitting strings summary
  11 system vocabs.loader vocabs.parser vocabs
  12 sequences.private ;
  13 IN: io.sockets
  14
  15 << {
  16     { [ os windows? ] [ "windows.winsock" ] }
  17     { [ os unix? ] [ "unix.ffi" ] }
  18 } cond use-vocab >>
  19
  20 GENERIC# with-port 1 ( addrspec port -- addrspec )
  21
  22 ! Addressing
  23 <PRIVATE
  24
  25 GENERIC: protocol ( addrspec -- n )
  26
  27 GENERIC: protocol-family ( addrspec -- af )
  28
  29 GENERIC: sockaddr-size ( addrspec -- n )
  30
  31 GENERIC: make-sockaddr ( addrspec -- sockaddr )
  32
  33 GENERIC: empty-sockaddr ( addrspec -- sockaddr )
  34
  35 GENERIC: address-size ( addrspec -- n )
  36
  37 GENERIC: inet-ntop ( data addrspec -- str )
  38
  39 GENERIC: inet-pton ( str addrspec -- data )
  40
  41 : make-sockaddr/size ( addrspec -- sockaddr size )
  42     [ make-sockaddr ] [ sockaddr-size ] bi ;
  43
  44 : empty-sockaddr/size ( addrspec -- sockaddr size )
  45     [ empty-sockaddr ] [ sockaddr-size ] bi ;
  46
  47 GENERIC: parse-sockaddr ( sockaddr addrspec -- newaddrspec )
  48
  49 M: f parse-sockaddr nip ;
  50
  51 HOOK: sockaddr-of-family os ( alien af -- sockaddr )
  52
  53 HOOK: addrspec-of-family os ( af -- addrspec )
  54
  55 PRIVATE>
  56
  57 TUPLE: local { path string read-only } ;
  58
  59 : <local> ( path -- addrspec )
  60     absolute-path local boa ;
  61
  62 M: local present path>> "Unix domain socket: " prepend ;
  63
  64 M: local protocol drop 0 ;
  65
  66 SLOT: port
  67
  68 TUPLE: ipv4 { host maybe{ string } read-only } ;
  69
  70 <PRIVATE
  71
  72 ERROR: invalid-ipv4 string reason ;
  73
  74 M: invalid-ipv4 summary drop "Invalid IPv4 address" ;
  75
  76 ERROR: malformed-ipv4 sequence ;
  77
  78 ERROR: bad-ipv4-component string ;
  79
  80 : parse-ipv4 ( string -- seq )
  81     [ f ] [
  82         "." split dup length 4 = [ malformed-ipv4 ] unless
  83         [ dup string>number [ ] [ bad-ipv4-component ] ?if ] B{ } map-as
  84     ] if-empty ;
  85
  86 : check-ipv4 ( string -- )
  87     [ parse-ipv4 drop ] [ invalid-ipv4 ] recover ;
  88
  89 PRIVATE>
  90
  91 : <ipv4> ( host -- ipv4 ) dup check-ipv4 ipv4 boa ;
  92
  93 M: ipv4 inet-ntop ( data addrspec -- str )
  94     drop 4 memory>byte-array [ number>string ] { } map-as "." join ;
  95
  96 M: ipv4 inet-pton ( str addrspec -- data )
  97     drop [ parse-ipv4 ] [ invalid-ipv4 ] recover ;
  98
  99 M: ipv4 address-size drop 4 ;
 100
 101 M: ipv4 protocol-family drop PF_INET ;
 102
 103 M: ipv4 sockaddr-size drop sockaddr-in heap-size ;
 104
 105 M: ipv4 empty-sockaddr drop sockaddr-in <struct> ;
 106
 107 M: ipv4 make-sockaddr ( inet -- sockaddr )
 108     sockaddr-in <struct>
 109         AF_INET >>family
 110         swap
 111         [ port>> htons >>port ]
 112         [ host>> "0.0.0.0" or ]
 113         [ inet-pton uint deref >>addr ] tri ;
 114
 115 M: ipv4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
 116     [ addr>> uint <ref> ] dip inet-ntop <ipv4> ;
 117
 118 TUPLE: inet4 < ipv4 { port integer read-only } ;
 119
 120 : <inet4> ( host port -- inet4 )
 121     over check-ipv4 inet4 boa ;
 122
 123 M: ipv4 with-port [ host>> ] dip <inet4> ;
 124
 125 M: inet4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
 126     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 127
 128 M: inet4 present
 129     [ host>> ] [ port>> number>string ] bi ":" glue ;
 130
 131 M: inet4 protocol drop 0 ;
 132
 133 TUPLE: ipv6
 134 { host maybe{ string } read-only }
 135 { scope-id integer read-only } ;
 136
 137 <PRIVATE
 138
 139 ERROR: invalid-ipv6 host reason ;
 140
 141 M: invalid-ipv6 summary drop "Invalid IPv6 address" ;
 142
 143 ERROR: bad-ipv6-component obj ;
 144
 145 ERROR: bad-ipv4-embedded-prefix obj ;
 146
 147 ERROR: more-than-8-components ;
 148
 149 : parse-ipv6-component ( seq -- seq' )
 150     [ dup hex> [ nip ] [ bad-ipv6-component ] if* ] { } map-as ;
 151
 152 : parse-ipv6 ( string -- seq )
 153     [ f ] [
 154         ":" split CHAR: . over last member? [
 155             unclip-last
 156             [ parse-ipv6-component ] [ parse-ipv4 ] bi* append
 157         ] [
 158             parse-ipv6-component
 159         ] if
 160     ] if-empty ;
 161
 162 : check-ipv6 ( string -- )
 163     [ "::" split1 [ parse-ipv6 ] bi@ 2drop ] [ invalid-ipv6 ] recover ;
 164
 165 PRIVATE>
 166
 167 : <ipv6> ( host -- ipv6 ) dup check-ipv6 0 ipv6 boa ;
 168
 169 M: ipv6 inet-ntop ( data addrspec -- str )
 170     drop 16 memory>byte-array 2 <groups> [ be> >hex ] map ":" join ;
 171
 172 <PRIVATE
 173
 174 : pad-ipv6 ( string1 string2 -- seq )
 175     2dup [ length ] bi@ + 8 swap -
 176     dup 0 < [ more-than-8-components ] when
 177     <byte-array> glue ;
 178
 179 : ipv6-bytes ( seq -- bytes )
 180     [ 2 >be ] { } map-as B{ } concat-as ;
 181
 182 PRIVATE>
 183
 184 M: ipv6 inet-pton ( str addrspec -- data )
 185     drop
 186     [ "::" split1 [ parse-ipv6 ] bi@ pad-ipv6 ipv6-bytes ]
 187     [ invalid-ipv6 ]
 188     recover ;
 189
 190 M: ipv6 address-size drop 16 ;
 191
 192 M: ipv6 protocol-family drop PF_INET6 ;
 193
 194 M: ipv6 sockaddr-size drop sockaddr-in6 heap-size ;
 195
 196 M: ipv6 empty-sockaddr drop sockaddr-in6 <struct> ;
 197
 198 M: ipv6 make-sockaddr ( inet -- sockaddr )
 199     sockaddr-in6 <struct>
 200         AF_INET6 >>family
 201         swap
 202         [ port>> htons >>port ]
 203         [ [ host>> "::" or ] keep inet-pton >>addr ]
 204         [ scope-id>> >>scopeid ]
 205         tri ;
 206
 207 M: ipv6 parse-sockaddr
 208     [ [ addr>> ] dip inet-ntop ] [ drop scopeid>> ] 2bi
 209     ipv6 boa ;
 210
 211 M: ipv6 present
 212     [ host>> ] [ scope-id>> ] bi
 213     [ number>string "%" glue ] unless-zero ;
 214
 215 TUPLE: inet6 < ipv6 { port integer read-only } ;
 216
 217 : <inet6> ( host port -- inet6 )
 218     [ dup check-ipv6 0 ] dip inet6 boa ;
 219
 220 M: ipv6 with-port
 221     [ [ host>> ] [ scope-id>> ] bi ] dip
 222     inet6 boa ;
 223
 224 M: inet6 parse-sockaddr
 225     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 226
 227 M: inet6 present
 228     [ call-next-method ] [ port>> number>string ] bi ":" glue ;
 229
 230 M: inet6 protocol drop 0 ;
 231
 232 <PRIVATE
 233
 234 GENERIC: (get-local-address) ( handle remote -- sockaddr )
 235
 236 : get-local-address ( handle remote -- local )
 237     [ (get-local-address) ] keep parse-sockaddr ;
 238
 239 GENERIC: (get-remote-address) ( handle remote -- sockaddr )
 240
 241 : get-remote-address ( handle local -- remote )
 242     [ (get-remote-address) ] keep parse-sockaddr ;
 243
 244 : <ports> ( handle -- input-port output-port )
 245     [
 246         [ <input-port> |dispose ] [ <output-port> |dispose ] bi
 247     ] with-destructors ;
 248
 249 SYMBOL: bind-local-address
 250
 251 GENERIC: establish-connection ( client-out remote -- )
 252
 253 GENERIC: ((client)) ( remote -- handle )
 254
 255 GENERIC: (client) ( remote -- client-in client-out local )
 256
 257 M: array (client) [ (client) 3array ] attempt-all first3 ;
 258
 259 M: object (client) ( remote -- client-in client-out local )
 260     [
 261         [ ((client)) ] keep
 262         [
 263             [ <ports> [ |dispose ] bi@ dup ] dip
 264             establish-connection
 265         ]
 266         [ get-local-address ]
 267         2bi
 268     ] with-destructors ;
 269
 270 TUPLE: server-port < port addr encoding ;
 271
 272 GENERIC: (server) ( addrspec -- handle )
 273
 274 GENERIC: (accept) ( server addrspec -- handle sockaddr )
 275
 276 TUPLE: datagram-port < port addr ;
 277
 278 HOOK: (datagram) io-backend ( addr -- datagram )
 279
 280 TUPLE: raw-port < port addr ;
 281
 282 HOOK: (raw) io-backend ( addr -- raw )
 283
 284 HOOK: (receive-unsafe) io-backend ( n buf datagram -- size addrspec )
 285
 286 ERROR: invalid-port object ;
 287
 288 : check-port ( packet addrspec port -- packet addrspec port )
 289     2dup addr>> [ class-of ] bi@ assert=
 290     pick class-of byte-array assert= ;
 291
 292 : check-connectionless-port ( port -- port )
 293     dup { [ datagram-port? ] [ raw-port? ] } 1|| [ invalid-port ] unless ;
 294
 295 : check-send ( packet addrspec port -- packet addrspec port )
 296     check-connectionless-port dup check-disposed check-port ;
 297
 298 : check-receive ( port -- port )
 299     check-connectionless-port dup check-disposed ;
 300
 301 HOOK: (send) io-backend ( packet addrspec datagram -- )
 302
 303 : addrinfo>addrspec ( addrinfo -- addrspec )
 304     [ [ addr>> ] [ family>> ] bi sockaddr-of-family ]
 305     [ family>> addrspec-of-family ] bi
 306     parse-sockaddr ;
 307
 308 : parse-addrinfo-list ( addrinfo -- seq )
 309     [ next>> ] follow
 310     [ addrinfo>addrspec ] map
 311     sift ;
 312
 313 HOOK: addrinfo-error io-backend ( n -- )
 314
 315 : prepare-addrinfo ( -- addrinfo )
 316     addrinfo <struct>
 317         PF_UNSPEC >>family
 318         IPPROTO_TCP >>protocol ;
 319
 320 PRIVATE>
 321
 322 : <client> ( remote encoding -- stream local )
 323     [ (client) ] dip swap [ <encoder-duplex> ] dip ;
 324
 325 SYMBOL: local-address
 326
 327 SYMBOL: remote-address
 328
 329 : with-client ( remote encoding quot -- )
 330     [
 331         [
 332             over remote-address set
 333             <client> local-address set
 334         ] dip with-stream
 335     ] with-scope ; inline
 336
 337 : <server> ( addrspec encoding -- server )
 338     [
 339         [ (server) ] keep
 340         [ drop server-port <port> ] [ get-local-address ] 2bi
 341         >>addr
 342     ] dip >>encoding ;
 343
 344 : accept ( server -- client remote )
 345     [
 346         dup addr>>
 347         [ (accept) ] keep
 348         parse-sockaddr swap
 349         <ports>
 350     ] keep encoding>> <encoder-duplex> swap ;
 351
 352 : <datagram> ( addrspec -- datagram )
 353     [
 354         [ (datagram) |dispose ] keep
 355         [ drop datagram-port <port> ] [ get-local-address ] 2bi
 356         >>addr
 357     ] with-destructors ;
 358
 359 : <raw> ( addrspec -- datagram )
 360     [
 361         [ (raw) |dispose ] keep
 362         [ drop raw-port <port> ] [ get-local-address ] 2bi
 363         >>addr
 364     ] with-destructors ;
 365
 366 : receive-unsafe ( n buf datagram -- count addrspec )
 367     check-receive
 368     [ (receive-unsafe) ] [ addr>> ] bi parse-sockaddr ; inline
 369
 370 CONSTANT: datagram-size 65536
 371
 372 :: receive ( datagram -- packet addrspec )
 373     datagram-size (byte-array) :> buf
 374     datagram-size buf datagram
 375     receive-unsafe :> ( count addrspec )
 376     count buf resize addrspec ; inline
 377
 378 :: receive-into ( buf datagram -- buf-slice addrspec )
 379     buf length :> n
 380     n buf datagram receive-unsafe :> ( count addrspec )
 381     buf count head-slice addrspec ; inline
 382
 383 : send ( packet addrspec datagram -- )
 384     check-send (send) ; inline
 385
 386 MEMO: ipv6-supported? ( -- ? )
 387     [ "::1" 0 <inet6> binary <server> dispose t ] [ drop f ] recover ;
 388
 389 [ \ ipv6-supported? reset-memoized ]
 390 "io.sockets:ipv6-supported?" add-startup-hook
 391
 392 GENERIC: resolve-host ( addrspec -- seq )
 393
 394 HOOK: resolve-localhost os ( -- obj )
 395
 396 TUPLE: hostname { host maybe{ string } read-only } ;
 397
 398 TUPLE: inet < hostname port ;
 399
 400 M: inet present
 401     [ host>> ] [ port>> number>string ] bi ":" glue ;
 402
 403 C: <inet> inet
 404
 405 M: string resolve-host
 406     f prepare-addrinfo f void* <ref>
 407     [ getaddrinfo addrinfo-error ] keep void* deref addrinfo memory>struct
 408     [ parse-addrinfo-list ] keep freeaddrinfo ;
 409
 410 M: string with-port <inet> ;
 411
 412 M: hostname resolve-host
 413     host>> resolve-host ;
 414
 415 M: hostname with-port
 416     [ host>> ] dip <inet> ;
 417
 418 M: inet resolve-host
 419     [ call-next-method ] [ port>> ] bi '[ _ with-port ] map ;
 420
 421 M: inet4 resolve-host 1array ;
 422
 423 M: inet6 resolve-host 1array ;
 424
 425 M: local resolve-host 1array ;
 426
 427 M: f resolve-host
 428     drop resolve-localhost ;
 429
 430 M: object resolve-localhost
 431     ipv6-supported?
 432     { T{ ipv4 f "0.0.0.0" } T{ ipv6 f "::" } }
 433     { T{ ipv4 f "0.0.0.0" } }
 434     ? ;
 435
 436 : host-name ( -- string )
 437     256 <byte-array> dup dup length gethostname
 438     zero? [ "gethostname failed" throw ] unless
 439     ascii alien>string ;
 440
 441 M: inet (client) resolve-host (client) ;
 442
 443 ERROR: invalid-inet-server addrspec ;
 444
 445 M: invalid-inet-server summary
 446     drop "Cannot use <server> with <inet>; use <inet4> or <inet6> instead" ;
 447
 448 M: inet (server)
 449     invalid-inet-server ;
 450
 451 ERROR: invalid-local-address addrspec ;
 452
 453 M: invalid-local-address summary
 454     drop "Cannot use with-local-address with <inet>; use <inet4> or <inet6> instead" ;
 455
 456 : with-local-address ( addr quot -- )
 457     [
 458         [ ] [ inet4? ] [ inet6? ] tri or
 459         [ bind-local-address ]
 460         [ invalid-local-address ] if
 461     ] dip with-variable ; inline
 462
 463 {
 464     { [ os unix? ] [ "io.sockets.unix" require ] }
 465     { [ os windows? ] [ "io.sockets.windows" require ] }
 466 } cond