basis/io/sockets/sockets.factor

   1 ! Copyright (C) 2007, 2010 Slava Pestov, Doug Coleman,
   2 ! Daniel Ehrenberg.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: generic kernel io.backend namespaces continuations sequences
   5 arrays io.encodings io.ports io.streams.duplex io.encodings.ascii
   6 alien.strings io.binary accessors destructors classes byte-arrays
   7 parser alien.c-types math.parser splitting grouping math assocs
   8 summary system vocabs.loader combinators present fry vocabs.parser
   9 classes.struct alien.data ;
  10 IN: io.sockets
  11
  12 << {
  13     { [ os windows? ] [ "windows.winsock" ] }
  14     { [ os unix? ] [ "unix.ffi" ] }
  15 } cond use-vocab >>
  16
  17 ! Addressing
  18 <PRIVATE
  19
  20 GENERIC: protocol-family ( addrspec -- af )
  21
  22 GENERIC: sockaddr-size ( addrspec -- n )
  23
  24 GENERIC: make-sockaddr ( addrspec -- sockaddr )
  25
  26 GENERIC: empty-sockaddr ( addrspec -- sockaddr )
  27
  28 GENERIC: address-size ( addrspec -- n )
  29
  30 GENERIC: inet-ntop ( data addrspec -- str )
  31
  32 GENERIC: inet-pton ( str addrspec -- data )
  33
  34 : make-sockaddr/size ( addrspec -- sockaddr size )
  35     [ make-sockaddr ] [ sockaddr-size ] bi ;
  36
  37 : empty-sockaddr/size ( addrspec -- sockaddr size )
  38     [ empty-sockaddr ] [ sockaddr-size ] bi ;
  39
  40 GENERIC: parse-sockaddr ( sockaddr addrspec -- newaddrspec )
  41
  42 M: f parse-sockaddr nip ;
  43
  44 HOOK: sockaddr-of-family os ( alien af -- sockaddr )
  45
  46 HOOK: addrspec-of-family os ( af -- addrspec )
  47
  48 PRIVATE>
  49
  50 TUPLE: local path ;
  51
  52 : <local> ( path -- addrspec )
  53     normalize-path local boa ;
  54
  55 M: local present path>> "Unix domain socket: " prepend ;
  56
  57 SLOT: port
  58
  59 TUPLE: ipv4 host ;
  60
  61 M: ipv4 inet-ntop ( data addrspec -- str )
  62     drop 4 memory>byte-array [ number>string ] { } map-as "." join ;
  63
  64 <PRIVATE
  65
  66 ERROR: malformed-ipv4 sequence ;
  67
  68 ERROR: bad-ipv4-component string ;
  69
  70 : parse-ipv4 ( string -- seq )
  71     "." split dup length 4 = [ malformed-ipv4 ] unless
  72     [ dup string>number [ ] [ bad-ipv4-component ] ?if ] B{ } map-as ;
  73
  74 ERROR: invalid-ipv4 string reason ;
  75
  76 M: invalid-ipv4 summary drop "Invalid IPv4 address" ;
  77
  78 PRIVATE>
  79
  80 M: ipv4 inet-pton ( str addrspec -- data )
  81     drop [ parse-ipv4 ] [ invalid-ipv4 ] recover ;
  82
  83 M: ipv4 address-size drop 4 ;
  84
  85 M: ipv4 protocol-family drop PF_INET ;
  86
  87 M: ipv4 sockaddr-size drop sockaddr-in heap-size ;
  88
  89 M: ipv4 empty-sockaddr drop sockaddr-in <struct> ;
  90
  91 M: ipv4 make-sockaddr ( inet -- sockaddr )
  92     sockaddr-in <struct>
  93         AF_INET >>family
  94         swap
  95         [ port>> htons >>port ]
  96         [ host>> "0.0.0.0" or ]
  97         [ inet-pton *uint >>addr ] tri ;
  98
  99 TUPLE: inet4 < ipv4 port ;
 100
 101 C: <inet4> inet4
 102
 103 M: inet4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
 104     [ [ addr>> <uint> ] dip inet-ntop ]
 105     [ drop port>> ntohs ] 2bi <inet4> ;
 106
 107 M: inet4 present
 108     [ host>> ] [ port>> number>string ] bi ":" glue ;
 109
 110 TUPLE: ipv6 host ;
 111
 112 M: ipv6 inet-ntop ( data addrspec -- str )
 113     drop 16 memory>byte-array 2 <groups> [ be> >hex ] map ":" join ;
 114
 115 ERROR: invalid-ipv6 string reason ;
 116
 117 <PRIVATE
 118
 119 ERROR: bad-ipv6-component obj ;
 120
 121 ERROR: bad-ipv4-embedded-prefix obj ;
 122
 123 ERROR: more-than-8-components ;
 124
 125 : parse-ipv6-component ( seq -- seq' )
 126     [ dup hex> [ nip ] [ bad-ipv6-component ] if* ] { } map-as ;
 127
 128 : parse-ipv6 ( string -- seq )
 129     [ f ] [
 130         ":" split CHAR: . over last member? [
 131             unclip-last
 132             [ parse-ipv6-component ] [ parse-ipv4 ] bi* append
 133         ] [
 134             parse-ipv6-component
 135         ] if
 136     ] if-empty ;
 137
 138 : pad-ipv6 ( string1 string2 -- seq )
 139     2dup [ length ] bi@ + 8 swap -
 140     dup 0 < [ more-than-8-components ] when
 141     <byte-array> glue ;
 142
 143 : ipv6-bytes ( seq -- bytes )
 144     [ 2 >be ] { } map-as B{ } concat-as ;
 145
 146 PRIVATE>
 147
 148 M: ipv6 inet-pton ( str addrspec -- data )
 149     drop
 150     [ "::" split1 [ parse-ipv6 ] bi@ pad-ipv6 ipv6-bytes ]
 151     [ invalid-ipv6 ]
 152     recover ;
 153
 154 M: ipv6 address-size drop 16 ;
 155
 156 M: ipv6 protocol-family drop PF_INET6 ;
 157
 158 M: ipv6 sockaddr-size drop sockaddr-in6 heap-size ;
 159
 160 M: ipv6 empty-sockaddr drop sockaddr-in6 <struct> ;
 161
 162 M: ipv6 make-sockaddr ( inet -- sockaddr )
 163     sockaddr-in6 <struct>
 164         AF_INET6 >>family
 165         swap [ port>> htons >>port ]
 166             [ host>> "::" or ]
 167             [ inet-pton >>addr ] tri ;
 168
 169 TUPLE: inet6 < ipv6 port ;
 170
 171 C: <inet6> inet6
 172
 173 M: inet6 parse-sockaddr
 174     [ [ addr>> ] dip inet-ntop ]
 175     [ drop port>> ntohs ] 2bi <inet6> ;
 176
 177 M: inet6 present
 178     [ host>> ] [ port>> number>string ] bi ":" glue ;
 179
 180 <PRIVATE
 181
 182 GENERIC: (get-local-address) ( handle remote -- sockaddr )
 183
 184 : get-local-address ( handle remote -- local )
 185     [ (get-local-address) ] keep parse-sockaddr ;
 186
 187 GENERIC: (get-remote-address) ( handle remote -- sockaddr )
 188
 189 : get-remote-address ( handle local -- remote )
 190     [ (get-remote-address) ] keep parse-sockaddr ;
 191
 192 : <ports> ( handle -- input-port output-port )
 193     [
 194         [ <input-port> |dispose ] [ <output-port> |dispose ] bi
 195     ] with-destructors ;
 196
 197 SYMBOL: bind-local-address
 198
 199 GENERIC: establish-connection ( client-out remote -- )
 200
 201 GENERIC: ((client)) ( remote -- handle )
 202
 203 GENERIC: (client) ( remote -- client-in client-out local )
 204
 205 M: array (client) [ (client) 3array ] attempt-all first3 ;
 206
 207 M: object (client) ( remote -- client-in client-out local )
 208     [
 209         [ ((client)) ] keep
 210         [
 211             [ <ports> [ |dispose ] bi@ dup ] dip
 212             establish-connection
 213         ]
 214         [ get-local-address ]
 215         2bi
 216     ] with-destructors ;
 217
 218 TUPLE: server-port < port addr encoding ;
 219
 220 : check-server-port ( port -- port )
 221     dup check-disposed
 222     dup server-port? [ "Not a server port" throw ] unless ; inline
 223
 224 GENERIC: (server) ( addrspec -- handle )
 225
 226 GENERIC: (accept) ( server addrspec -- handle sockaddr )
 227
 228 TUPLE: datagram-port < port addr ;
 229
 230 HOOK: (datagram) io-backend ( addr -- datagram )
 231
 232 : check-datagram-port ( port -- port )
 233     dup check-disposed
 234     dup datagram-port? [ "Not a datagram port" throw ] unless ; inline
 235
 236 HOOK: (receive) io-backend ( datagram -- packet addrspec )
 237
 238 : check-datagram-send ( packet addrspec port -- packet addrspec port )
 239     check-datagram-port
 240     2dup addr>> [ class ] bi@ assert=
 241     pick class byte-array assert= ;
 242
 243 HOOK: (send) io-backend ( packet addrspec datagram -- )
 244
 245 : addrinfo>addrspec ( addrinfo -- addrspec )
 246     [ [ addr>> ] [ family>> ] bi sockaddr-of-family ]
 247     [ family>> addrspec-of-family ] bi
 248     parse-sockaddr ;
 249
 250 : parse-addrinfo-list ( addrinfo -- seq )
 251     [ next>> ] follow
 252     [ addrinfo>addrspec ] map
 253     sift ;
 254
 255 HOOK: addrinfo-error io-backend ( n -- )
 256
 257 : resolve-passive-host ( -- addrspecs )
 258     { T{ inet6 f "::" f } T{ inet4 f "0.0.0.0" f } } [ clone ] map ;
 259
 260 : prepare-addrinfo ( -- addrinfo )
 261     addrinfo <struct>
 262         PF_UNSPEC >>family
 263         IPPROTO_TCP >>protocol ;
 264
 265 : fill-in-ports ( addrspecs port -- addrspecs )
 266     '[ _ >>port ] map ;
 267
 268 PRIVATE>
 269
 270 : <client> ( remote encoding -- stream local )
 271     [ (client) ] dip swap [ <encoder-duplex> ] dip ;
 272
 273 SYMBOL: local-address
 274
 275 SYMBOL: remote-address
 276
 277 : with-client ( remote encoding quot -- )
 278     [
 279         [
 280             over remote-address set
 281             <client> local-address set
 282         ] dip with-stream
 283     ] with-scope ; inline
 284
 285 : <server> ( addrspec encoding -- server )
 286     [
 287         [ (server) ] keep
 288         [ drop server-port <port> ] [ get-local-address ] 2bi
 289         >>addr
 290     ] dip >>encoding ;
 291
 292 : accept ( server -- client remote )
 293     [
 294         dup addr>>
 295         [ (accept) ] keep
 296         parse-sockaddr swap
 297         <ports>
 298     ] keep encoding>> <encoder-duplex> swap ;
 299
 300 : <datagram> ( addrspec -- datagram )
 301     [
 302         [ (datagram) |dispose ] keep
 303         [ drop datagram-port <port> ] [ get-local-address ] 2bi
 304         >>addr
 305     ] with-destructors ;
 306
 307 : receive ( datagram -- packet addrspec )
 308     check-datagram-port
 309     [ (receive) ] [ addr>> ] bi parse-sockaddr ;
 310
 311 : send ( packet addrspec datagram -- )
 312     check-datagram-send (send) ;
 313
 314 GENERIC: resolve-host ( addrspec -- seq )
 315
 316 TUPLE: hostname host ;
 317
 318 TUPLE: inet < hostname port ;
 319
 320 M: inet present
 321     [ host>> ] [ port>> number>string ] bi ":" glue ;
 322
 323 C: <inet> inet
 324
 325 M: hostname resolve-host
 326     host>> [
 327         f prepare-addrinfo f <void*>
 328         [ getaddrinfo addrinfo-error ] keep *void* addrinfo memory>struct
 329         [ parse-addrinfo-list ] keep freeaddrinfo
 330     ] [ resolve-passive-host ] if* ;
 331
 332 M: inet resolve-host
 333     [ call-next-method ] [ port>> ] bi fill-in-ports ;
 334
 335 M: f resolve-host drop { } ;
 336
 337 M: object resolve-host 1array ;
 338
 339 : host-name ( -- string )
 340     256 <byte-array> dup dup length gethostname
 341     zero? [ "gethostname failed" throw ] unless
 342     ascii alien>string ;
 343
 344 M: inet (client) resolve-host (client) ;
 345
 346 ERROR: invalid-inet-server addrspec ;
 347
 348 M: invalid-inet-server summary
 349     drop "Cannot use <server> with <inet>; use <inet4> or <inet6> instead" ;
 350
 351 M: inet (server)
 352     invalid-inet-server ;
 353
 354 ERROR: invalid-local-address addrspec ;
 355
 356 M: invalid-local-address summary
 357     drop "Cannot use with-local-address with <inet>; use <inet4> or <inet6> instead" ;
 358
 359 : with-local-address ( addr quot -- )
 360     [
 361         [ ] [ inet4? ] [ inet6? ] tri or
 362         [ bind-local-address ]
 363         [ invalid-local-address ] if
 364     ] dip with-variable ; inline
 365
 366 {
 367     { [ os unix? ] [ "io.sockets.unix" require ] }
 368     { [ os winnt? ] [ "io.sockets.windows.nt" require ] }
 369 } cond