basis/io/sockets/sockets.factor

   1 ! Copyright (C) 2007, 2010 Slava Pestov, Doug Coleman,
   2 ! Daniel Ehrenberg.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: generic kernel io.backend namespaces continuations sequences
   5 arrays io.encodings io.ports io.streams.duplex io.encodings.ascii
   6 alien.strings io.binary accessors destructors classes byte-arrays
   7 parser alien.c-types math.parser splitting grouping math assocs
   8 summary system vocabs.loader combinators present fry vocabs.parser
   9 classes.struct alien.data strings ;
  10 IN: io.sockets
  11
  12 << {
  13     { [ os windows? ] [ "windows.winsock" ] }
  14     { [ os unix? ] [ "unix.ffi" ] }
  15 } cond use-vocab >>
  16
  17 ! Addressing
  18 <PRIVATE
  19
  20 GENERIC: protocol-family ( addrspec -- af )
  21
  22 GENERIC: sockaddr-size ( addrspec -- n )
  23
  24 GENERIC: make-sockaddr ( addrspec -- sockaddr )
  25
  26 GENERIC: empty-sockaddr ( addrspec -- sockaddr )
  27
  28 GENERIC: address-size ( addrspec -- n )
  29
  30 GENERIC: inet-ntop ( data addrspec -- str )
  31
  32 GENERIC: inet-pton ( str addrspec -- data )
  33
  34 GENERIC# with-port 1 ( addrspec port -- addrspec )
  35
  36 : make-sockaddr/size ( addrspec -- sockaddr size )
  37     [ make-sockaddr ] [ sockaddr-size ] bi ;
  38
  39 : empty-sockaddr/size ( addrspec -- sockaddr size )
  40     [ empty-sockaddr ] [ sockaddr-size ] bi ;
  41
  42 GENERIC: parse-sockaddr ( sockaddr addrspec -- newaddrspec )
  43
  44 M: f parse-sockaddr nip ;
  45
  46 HOOK: sockaddr-of-family os ( alien af -- sockaddr )
  47
  48 HOOK: addrspec-of-family os ( af -- addrspec )
  49
  50 PRIVATE>
  51
  52 TUPLE: local path ;
  53
  54 : <local> ( path -- addrspec )
  55     normalize-path local boa ;
  56
  57 M: local present path>> "Unix domain socket: " prepend ;
  58
  59 SLOT: port
  60
  61 TUPLE: ipv4 { host string read-only } ;
  62
  63 C: <ipv4> ipv4
  64
  65 M: ipv4 inet-ntop ( data addrspec -- str )
  66     drop 4 memory>byte-array [ number>string ] { } map-as "." join ;
  67
  68 <PRIVATE
  69
  70 ERROR: malformed-ipv4 sequence ;
  71
  72 ERROR: bad-ipv4-component string ;
  73
  74 : parse-ipv4 ( string -- seq )
  75     "." split dup length 4 = [ malformed-ipv4 ] unless
  76     [ dup string>number [ ] [ bad-ipv4-component ] ?if ] B{ } map-as ;
  77
  78 ERROR: invalid-ipv4 string reason ;
  79
  80 M: invalid-ipv4 summary drop "Invalid IPv4 address" ;
  81
  82 PRIVATE>
  83
  84 M: ipv4 inet-pton ( str addrspec -- data )
  85     drop [ parse-ipv4 ] [ invalid-ipv4 ] recover ;
  86
  87 M: ipv4 address-size drop 4 ;
  88
  89 M: ipv4 protocol-family drop PF_INET ;
  90
  91 M: ipv4 sockaddr-size drop sockaddr-in heap-size ;
  92
  93 M: ipv4 empty-sockaddr drop sockaddr-in <struct> ;
  94
  95 M: ipv4 make-sockaddr ( inet -- sockaddr )
  96     sockaddr-in <struct>
  97         AF_INET >>family
  98         swap
  99         [ port>> htons >>port ]
 100         [ host>> "0.0.0.0" or ]
 101         [ inet-pton *uint >>addr ] tri ;
 102
 103 M: ipv4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
 104     [ addr>> <uint> ] dip inet-ntop <ipv4> ;
 105
 106 TUPLE: inet4 < ipv4 { port integer read-only } ;
 107
 108 C: <inet4> inet4
 109
 110 M: ipv4 with-port [ host>> ] dip <inet4> ;
 111
 112 M: inet4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
 113     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 114
 115 M: inet4 present
 116     [ host>> ] [ port>> number>string ] bi ":" glue ;
 117
 118 TUPLE: ipv6 { host string read-only } ;
 119
 120 C: <ipv6> ipv6
 121
 122 M: ipv6 inet-ntop ( data addrspec -- str )
 123     drop 16 memory>byte-array 2 <groups> [ be> >hex ] map ":" join ;
 124
 125 ERROR: invalid-ipv6 string reason ;
 126
 127 <PRIVATE
 128
 129 ERROR: bad-ipv6-component obj ;
 130
 131 ERROR: bad-ipv4-embedded-prefix obj ;
 132
 133 ERROR: more-than-8-components ;
 134
 135 : parse-ipv6-component ( seq -- seq' )
 136     [ dup hex> [ nip ] [ bad-ipv6-component ] if* ] { } map-as ;
 137
 138 : parse-ipv6 ( string -- seq )
 139     [ f ] [
 140         ":" split CHAR: . over last member? [
 141             unclip-last
 142             [ parse-ipv6-component ] [ parse-ipv4 ] bi* append
 143         ] [
 144             parse-ipv6-component
 145         ] if
 146     ] if-empty ;
 147
 148 : pad-ipv6 ( string1 string2 -- seq )
 149     2dup [ length ] bi@ + 8 swap -
 150     dup 0 < [ more-than-8-components ] when
 151     <byte-array> glue ;
 152
 153 : ipv6-bytes ( seq -- bytes )
 154     [ 2 >be ] { } map-as B{ } concat-as ;
 155
 156 PRIVATE>
 157
 158 M: ipv6 inet-pton ( str addrspec -- data )
 159     drop
 160     [ "::" split1 [ parse-ipv6 ] bi@ pad-ipv6 ipv6-bytes ]
 161     [ invalid-ipv6 ]
 162     recover ;
 163
 164 M: ipv6 address-size drop 16 ;
 165
 166 M: ipv6 protocol-family drop PF_INET6 ;
 167
 168 M: ipv6 sockaddr-size drop sockaddr-in6 heap-size ;
 169
 170 M: ipv6 empty-sockaddr drop sockaddr-in6 <struct> ;
 171
 172 M: ipv6 make-sockaddr ( inet -- sockaddr )
 173     sockaddr-in6 <struct>
 174         AF_INET6 >>family
 175         swap
 176         [ port>> htons >>port ]
 177         [ host>> "::" or ]
 178         [ inet-pton >>addr ] tri ;
 179
 180 M: ipv6 parse-sockaddr
 181     [ addr>> ] dip inet-ntop <ipv6> ;
 182
 183 TUPLE: inet6 < ipv6 { port integer read-only } ;
 184
 185 C: <inet6> inet6
 186
 187 M: ipv6 with-port [ host>> ] dip <inet6> ;
 188
 189 M: inet6 parse-sockaddr
 190     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 191
 192 M: inet6 present
 193     [ host>> ] [ port>> number>string ] bi ":" glue ;
 194
 195 <PRIVATE
 196
 197 GENERIC: (get-local-address) ( handle remote -- sockaddr )
 198
 199 : get-local-address ( handle remote -- local )
 200     [ (get-local-address) ] keep parse-sockaddr ;
 201
 202 GENERIC: (get-remote-address) ( handle remote -- sockaddr )
 203
 204 : get-remote-address ( handle local -- remote )
 205     [ (get-remote-address) ] keep parse-sockaddr ;
 206
 207 : <ports> ( handle -- input-port output-port )
 208     [
 209         [ <input-port> |dispose ] [ <output-port> |dispose ] bi
 210     ] with-destructors ;
 211
 212 SYMBOL: bind-local-address
 213
 214 GENERIC: establish-connection ( client-out remote -- )
 215
 216 GENERIC: ((client)) ( remote -- handle )
 217
 218 GENERIC: (client) ( remote -- client-in client-out local )
 219
 220 M: array (client) [ (client) 3array ] attempt-all first3 ;
 221
 222 M: object (client) ( remote -- client-in client-out local )
 223     [
 224         [ ((client)) ] keep
 225         [
 226             [ <ports> [ |dispose ] bi@ dup ] dip
 227             establish-connection
 228         ]
 229         [ get-local-address ]
 230         2bi
 231     ] with-destructors ;
 232
 233 TUPLE: server-port < port addr encoding ;
 234
 235 : check-server-port ( port -- port )
 236     dup check-disposed
 237     dup server-port? [ "Not a server port" throw ] unless ; inline
 238
 239 GENERIC: (server) ( addrspec -- handle )
 240
 241 GENERIC: (accept) ( server addrspec -- handle sockaddr )
 242
 243 TUPLE: datagram-port < port addr ;
 244
 245 HOOK: (datagram) io-backend ( addr -- datagram )
 246
 247 : check-datagram-port ( port -- port )
 248     dup check-disposed
 249     dup datagram-port? [ "Not a datagram port" throw ] unless ; inline
 250
 251 HOOK: (receive) io-backend ( datagram -- packet addrspec )
 252
 253 : check-datagram-send ( packet addrspec port -- packet addrspec port )
 254     check-datagram-port
 255     2dup addr>> [ class ] bi@ assert=
 256     pick class byte-array assert= ;
 257
 258 HOOK: (send) io-backend ( packet addrspec datagram -- )
 259
 260 : addrinfo>addrspec ( addrinfo -- addrspec )
 261     [ [ addr>> ] [ family>> ] bi sockaddr-of-family ]
 262     [ family>> addrspec-of-family ] bi
 263     parse-sockaddr ;
 264
 265 : parse-addrinfo-list ( addrinfo -- seq )
 266     [ next>> ] follow
 267     [ addrinfo>addrspec ] map
 268     sift ;
 269
 270 HOOK: addrinfo-error io-backend ( n -- )
 271
 272 : prepare-addrinfo ( -- addrinfo )
 273     addrinfo <struct>
 274         PF_UNSPEC >>family
 275         IPPROTO_TCP >>protocol ;
 276
 277 PRIVATE>
 278
 279 : <client> ( remote encoding -- stream local )
 280     [ (client) ] dip swap [ <encoder-duplex> ] dip ;
 281
 282 SYMBOL: local-address
 283
 284 SYMBOL: remote-address
 285
 286 : with-client ( remote encoding quot -- )
 287     [
 288         [
 289             over remote-address set
 290             <client> local-address set
 291         ] dip with-stream
 292     ] with-scope ; inline
 293
 294 : <server> ( addrspec encoding -- server )
 295     [
 296         [ (server) ] keep
 297         [ drop server-port <port> ] [ get-local-address ] 2bi
 298         >>addr
 299     ] dip >>encoding ;
 300
 301 : accept ( server -- client remote )
 302     [
 303         dup addr>>
 304         [ (accept) ] keep
 305         parse-sockaddr swap
 306         <ports>
 307     ] keep encoding>> <encoder-duplex> swap ;
 308
 309 : <datagram> ( addrspec -- datagram )
 310     [
 311         [ (datagram) |dispose ] keep
 312         [ drop datagram-port <port> ] [ get-local-address ] 2bi
 313         >>addr
 314     ] with-destructors ;
 315
 316 : receive ( datagram -- packet addrspec )
 317     check-datagram-port
 318     [ (receive) ] [ addr>> ] bi parse-sockaddr ;
 319
 320 : send ( packet addrspec datagram -- )
 321     check-datagram-send (send) ;
 322
 323 GENERIC: resolve-host ( addrspec -- seq )
 324
 325 TUPLE: hostname host ;
 326
 327 TUPLE: inet < hostname port ;
 328
 329 M: inet present
 330     [ host>> ] [ port>> number>string ] bi ":" glue ;
 331
 332 C: <inet> inet
 333
 334 M: string resolve-host
 335     f prepare-addrinfo f <void*>
 336     [ getaddrinfo addrinfo-error ] keep *void* addrinfo memory>struct
 337     [ parse-addrinfo-list ] keep freeaddrinfo ;
 338
 339 M: hostname resolve-host
 340     host>> resolve-host ;
 341
 342 M: inet resolve-host
 343     [ call-next-method ] [ port>> ] bi '[ _ with-port ] map ;
 344
 345 M: inet4 resolve-host 1array ;
 346
 347 M: inet6 resolve-host 1array ;
 348
 349 M: local resolve-host 1array ;
 350
 351 M: f resolve-host
 352     drop { T{ ipv6 f "::" } T{ ipv4 f "0.0.0.0" } } ;
 353
 354 : host-name ( -- string )
 355     256 <byte-array> dup dup length gethostname
 356     zero? [ "gethostname failed" throw ] unless
 357     ascii alien>string ;
 358
 359 M: inet (client) resolve-host (client) ;
 360
 361 ERROR: invalid-inet-server addrspec ;
 362
 363 M: invalid-inet-server summary
 364     drop "Cannot use <server> with <inet>; use <inet4> or <inet6> instead" ;
 365
 366 M: inet (server)
 367     invalid-inet-server ;
 368
 369 ERROR: invalid-local-address addrspec ;
 370
 371 M: invalid-local-address summary
 372     drop "Cannot use with-local-address with <inet>; use <inet4> or <inet6> instead" ;
 373
 374 : with-local-address ( addr quot -- )
 375     [
 376         [ ] [ inet4? ] [ inet6? ] tri or
 377         [ bind-local-address ]
 378         [ invalid-local-address ] if
 379     ] dip with-variable ; inline
 380
 381 {
 382     { [ os unix? ] [ "io.sockets.unix" require ] }
 383     { [ os winnt? ] [ "io.sockets.windows.nt" require ] }
 384 } cond