basis/io/sockets/sockets.factor

   1 ! Copyright (C) 2007, 2010 Slava Pestov, Doug Coleman,
   2 ! Daniel Ehrenberg.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: generic kernel io.backend namespaces continuations sequences
   5 arrays io.encodings io.ports io.streams.duplex io.encodings.ascii
   6 alien.strings io.binary accessors destructors classes byte-arrays
   7 parser alien.c-types math.parser splitting grouping math assocs
   8 summary system vocabs.loader combinators present fry vocabs.parser
   9 classes.struct alien.data strings io.encodings.binary ;
  10 IN: io.sockets
  11
  12 << {
  13     { [ os windows? ] [ "windows.winsock" ] }
  14     { [ os unix? ] [ "unix.ffi" ] }
  15 } cond use-vocab >>
  16
  17 ! Addressing
  18 <PRIVATE
  19
  20 UNION: ?string string POSTPONE: f ;
  21
  22 GENERIC: protocol ( addrspec -- n )
  23
  24 GENERIC: protocol-family ( addrspec -- af )
  25
  26 GENERIC: sockaddr-size ( addrspec -- n )
  27
  28 GENERIC: make-sockaddr ( addrspec -- sockaddr )
  29
  30 GENERIC: empty-sockaddr ( addrspec -- sockaddr )
  31
  32 GENERIC: address-size ( addrspec -- n )
  33
  34 GENERIC: inet-ntop ( data addrspec -- str )
  35
  36 GENERIC: inet-pton ( str addrspec -- data )
  37
  38 GENERIC# with-port 1 ( addrspec port -- addrspec )
  39
  40 : make-sockaddr/size ( addrspec -- sockaddr size )
  41     [ make-sockaddr ] [ sockaddr-size ] bi ;
  42
  43 : empty-sockaddr/size ( addrspec -- sockaddr size )
  44     [ empty-sockaddr ] [ sockaddr-size ] bi ;
  45
  46 GENERIC: parse-sockaddr ( sockaddr addrspec -- newaddrspec )
  47
  48 M: f parse-sockaddr nip ;
  49
  50 HOOK: sockaddr-of-family os ( alien af -- sockaddr )
  51
  52 HOOK: addrspec-of-family os ( af -- addrspec )
  53
  54 PRIVATE>
  55
  56 TUPLE: local { path read-only } ;
  57
  58 : <local> ( path -- addrspec )
  59     normalize-path local boa ;
  60
  61 M: local present path>> "Unix domain socket: " prepend ;
  62
  63 M: local protocol drop 0 ;
  64
  65 SLOT: port
  66
  67 TUPLE: ipv4 { host ?string read-only } ;
  68
  69 C: <ipv4> ipv4
  70
  71 M: ipv4 inet-ntop ( data addrspec -- str )
  72     drop 4 memory>byte-array [ number>string ] { } map-as "." join ;
  73
  74 <PRIVATE
  75
  76 ERROR: malformed-ipv4 sequence ;
  77
  78 ERROR: bad-ipv4-component string ;
  79
  80 : parse-ipv4 ( string -- seq )
  81     "." split dup length 4 = [ malformed-ipv4 ] unless
  82     [ dup string>number [ ] [ bad-ipv4-component ] ?if ] B{ } map-as ;
  83
  84 ERROR: invalid-ipv4 string reason ;
  85
  86 M: invalid-ipv4 summary drop "Invalid IPv4 address" ;
  87
  88 PRIVATE>
  89
  90 M: ipv4 inet-pton ( str addrspec -- data )
  91     drop [ parse-ipv4 ] [ invalid-ipv4 ] recover ;
  92
  93 M: ipv4 address-size drop 4 ;
  94
  95 M: ipv4 protocol-family drop PF_INET ;
  96
  97 M: ipv4 sockaddr-size drop sockaddr-in heap-size ;
  98
  99 M: ipv4 empty-sockaddr drop sockaddr-in <struct> ;
 100
 101 M: ipv4 make-sockaddr ( inet -- sockaddr )
 102     sockaddr-in <struct>
 103         AF_INET >>family
 104         swap
 105         [ port>> htons >>port ]
 106         [ host>> "0.0.0.0" or ]
 107         [ inet-pton *uint >>addr ] tri ;
 108
 109 M: ipv4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
 110     [ addr>> <uint> ] dip inet-ntop <ipv4> ;
 111
 112 TUPLE: inet4 < ipv4 { port integer read-only } ;
 113
 114 C: <inet4> inet4
 115
 116 M: ipv4 with-port [ host>> ] dip <inet4> ;
 117
 118 M: inet4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
 119     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 120
 121 M: inet4 present
 122     [ host>> ] [ port>> number>string ] bi ":" glue ;
 123
 124 M: inet4 protocol drop 0 ;
 125
 126 TUPLE: ipv6 { host ?string read-only } ;
 127
 128 C: <ipv6> ipv6
 129
 130 M: ipv6 inet-ntop ( data addrspec -- str )
 131     drop 16 memory>byte-array 2 <groups> [ be> >hex ] map ":" join ;
 132
 133 ERROR: invalid-ipv6 string reason ;
 134
 135 <PRIVATE
 136
 137 ERROR: bad-ipv6-component obj ;
 138
 139 ERROR: bad-ipv4-embedded-prefix obj ;
 140
 141 ERROR: more-than-8-components ;
 142
 143 : parse-ipv6-component ( seq -- seq' )
 144     [ dup hex> [ nip ] [ bad-ipv6-component ] if* ] { } map-as ;
 145
 146 : parse-ipv6 ( string -- seq )
 147     [ f ] [
 148         ":" split CHAR: . over last member? [
 149             unclip-last
 150             [ parse-ipv6-component ] [ parse-ipv4 ] bi* append
 151         ] [
 152             parse-ipv6-component
 153         ] if
 154     ] if-empty ;
 155
 156 : pad-ipv6 ( string1 string2 -- seq )
 157     2dup [ length ] bi@ + 8 swap -
 158     dup 0 < [ more-than-8-components ] when
 159     <byte-array> glue ;
 160
 161 : ipv6-bytes ( seq -- bytes )
 162     [ 2 >be ] { } map-as B{ } concat-as ;
 163
 164 PRIVATE>
 165
 166 M: ipv6 inet-pton ( str addrspec -- data )
 167     drop
 168     [ "::" split1 [ parse-ipv6 ] bi@ pad-ipv6 ipv6-bytes ]
 169     [ invalid-ipv6 ]
 170     recover ;
 171
 172 M: ipv6 address-size drop 16 ;
 173
 174 M: ipv6 protocol-family drop PF_INET6 ;
 175
 176 M: ipv6 sockaddr-size drop sockaddr-in6 heap-size ;
 177
 178 M: ipv6 empty-sockaddr drop sockaddr-in6 <struct> ;
 179
 180 M: ipv6 make-sockaddr ( inet -- sockaddr )
 181     sockaddr-in6 <struct>
 182         AF_INET6 >>family
 183         swap
 184         [ port>> htons >>port ]
 185         [ host>> "::" or ]
 186         [ inet-pton >>addr ] tri ;
 187
 188 M: ipv6 parse-sockaddr
 189     [ addr>> ] dip inet-ntop <ipv6> ;
 190
 191 TUPLE: inet6 < ipv6 { port integer read-only } ;
 192
 193 C: <inet6> inet6
 194
 195 M: ipv6 with-port [ host>> ] dip <inet6> ;
 196
 197 M: inet6 parse-sockaddr
 198     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 199
 200 M: inet6 present
 201     [ host>> ] [ port>> number>string ] bi ":" glue ;
 202
 203 M: inet6 protocol drop 0 ;
 204
 205 <PRIVATE
 206
 207 GENERIC: (get-local-address) ( handle remote -- sockaddr )
 208
 209 : get-local-address ( handle remote -- local )
 210     [ (get-local-address) ] keep parse-sockaddr ;
 211
 212 GENERIC: (get-remote-address) ( handle remote -- sockaddr )
 213
 214 : get-remote-address ( handle local -- remote )
 215     [ (get-remote-address) ] keep parse-sockaddr ;
 216
 217 : <ports> ( handle -- input-port output-port )
 218     [
 219         [ <input-port> |dispose ] [ <output-port> |dispose ] bi
 220     ] with-destructors ;
 221
 222 SYMBOL: bind-local-address
 223
 224 GENERIC: establish-connection ( client-out remote -- )
 225
 226 GENERIC: ((client)) ( remote -- handle )
 227
 228 GENERIC: (client) ( remote -- client-in client-out local )
 229
 230 M: array (client) [ (client) 3array ] attempt-all first3 ;
 231
 232 M: object (client) ( remote -- client-in client-out local )
 233     [
 234         [ ((client)) ] keep
 235         [
 236             [ <ports> [ |dispose ] bi@ dup ] dip
 237             establish-connection
 238         ]
 239         [ get-local-address ]
 240         2bi
 241     ] with-destructors ;
 242
 243 TUPLE: server-port < port addr encoding ;
 244
 245 : check-server-port ( port -- port )
 246     dup check-disposed
 247     dup server-port? [ "Not a server port" throw ] unless ; inline
 248
 249 GENERIC: (server) ( addrspec -- handle )
 250
 251 GENERIC: (accept) ( server addrspec -- handle sockaddr )
 252
 253 TUPLE: datagram-port < port addr ;
 254
 255 HOOK: (datagram) io-backend ( addr -- datagram )
 256
 257 : check-datagram-port ( port -- port )
 258     dup check-disposed
 259     dup datagram-port? [ "Not a datagram port" throw ] unless ; inline
 260
 261 HOOK: (receive) io-backend ( datagram -- packet addrspec )
 262
 263 : check-datagram-send ( packet addrspec port -- packet addrspec port )
 264     check-datagram-port
 265     2dup addr>> [ class ] bi@ assert=
 266     pick class byte-array assert= ;
 267
 268 HOOK: (send) io-backend ( packet addrspec datagram -- )
 269
 270 : addrinfo>addrspec ( addrinfo -- addrspec )
 271     [ [ addr>> ] [ family>> ] bi sockaddr-of-family ]
 272     [ family>> addrspec-of-family ] bi
 273     parse-sockaddr ;
 274
 275 : parse-addrinfo-list ( addrinfo -- seq )
 276     [ next>> ] follow
 277     [ addrinfo>addrspec ] map
 278     sift ;
 279
 280 HOOK: addrinfo-error io-backend ( n -- )
 281
 282 : prepare-addrinfo ( -- addrinfo )
 283     addrinfo <struct>
 284         PF_UNSPEC >>family
 285         IPPROTO_TCP >>protocol ;
 286
 287 PRIVATE>
 288
 289 : <client> ( remote encoding -- stream local )
 290     [ (client) ] dip swap [ <encoder-duplex> ] dip ;
 291
 292 SYMBOL: local-address
 293
 294 SYMBOL: remote-address
 295
 296 : with-client ( remote encoding quot -- )
 297     [
 298         [
 299             over remote-address set
 300             <client> local-address set
 301         ] dip with-stream
 302     ] with-scope ; inline
 303
 304 : <server> ( addrspec encoding -- server )
 305     [
 306         [ (server) ] keep
 307         [ drop server-port <port> ] [ get-local-address ] 2bi
 308         >>addr
 309     ] dip >>encoding ;
 310
 311 : accept ( server -- client remote )
 312     [
 313         dup addr>>
 314         [ (accept) ] keep
 315         parse-sockaddr swap
 316         <ports>
 317     ] keep encoding>> <encoder-duplex> swap ;
 318
 319 : <datagram> ( addrspec -- datagram )
 320     [
 321         [ (datagram) |dispose ] keep
 322         [ drop datagram-port <port> ] [ get-local-address ] 2bi
 323         >>addr
 324     ] with-destructors ;
 325
 326 : receive ( datagram -- packet addrspec )
 327     check-datagram-port
 328     [ (receive) ] [ addr>> ] bi parse-sockaddr ;
 329
 330 : send ( packet addrspec datagram -- )
 331     check-datagram-send (send) ;
 332
 333 GENERIC: resolve-host ( addrspec -- seq )
 334
 335 TUPLE: hostname { host ?string read-only } ;
 336
 337 TUPLE: inet < hostname port ;
 338
 339 M: inet present
 340     [ host>> ] [ port>> number>string ] bi ":" glue ;
 341
 342 C: <inet> inet
 343
 344 M: string resolve-host
 345     f prepare-addrinfo f <void*>
 346     [ getaddrinfo addrinfo-error ] keep *void* addrinfo memory>struct
 347     [ parse-addrinfo-list ] keep freeaddrinfo ;
 348
 349 M: hostname resolve-host
 350     host>> resolve-host ;
 351
 352 M: inet resolve-host
 353     [ call-next-method ] [ port>> ] bi '[ _ with-port ] map ;
 354
 355 M: inet4 resolve-host 1array ;
 356
 357 M: inet6 resolve-host 1array ;
 358
 359 M: local resolve-host 1array ;
 360
 361 M: f resolve-host
 362     drop { T{ ipv6 f "::" } T{ ipv4 f "0.0.0.0" } } ;
 363
 364 : host-name ( -- string )
 365     256 <byte-array> dup dup length gethostname
 366     zero? [ "gethostname failed" throw ] unless
 367     ascii alien>string ;
 368
 369 M: inet (client) resolve-host (client) ;
 370
 371 ERROR: invalid-inet-server addrspec ;
 372
 373 M: invalid-inet-server summary
 374     drop "Cannot use <server> with <inet>; use <inet4> or <inet6> instead" ;
 375
 376 M: inet (server)
 377     invalid-inet-server ;
 378
 379 ERROR: invalid-local-address addrspec ;
 380
 381 M: invalid-local-address summary
 382     drop "Cannot use with-local-address with <inet>; use <inet4> or <inet6> instead" ;
 383
 384 : with-local-address ( addr quot -- )
 385     [
 386         [ ] [ inet4? ] [ inet6? ] tri or
 387         [ bind-local-address ]
 388         [ invalid-local-address ] if
 389     ] dip with-variable ; inline
 390
 391 : ipv6-supported? ( -- ? )
 392     [ "::1" 0 <inet6> binary <server> dispose t ] [ drop f ] recover ;
 393
 394 {
 395     { [ os unix? ] [ "io.sockets.unix" require ] }
 396     { [ os windows? ] [ "io.sockets.windows" require ] }
 397 } cond