basis/io/sockets/sockets.factor

   1 ! Copyright (C) 2007, 2011 Slava Pestov, Doug Coleman,
   2 ! Daniel Ehrenberg.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: accessors alien.c-types alien.data alien.strings arrays
   5 assocs byte-arrays classes classes.struct combinators
   6 combinators.short-circuit continuations destructors fry generic
   7 grouping init io.backend io.binary io.encodings
   8 io.encodings.ascii io.encodings.binary io.pathnames io.ports
   9 io.streams.duplex kernel libc locals math math.parser memoize
  10 namespaces parser present sequences splitting strings summary
  11 system values vocabs.loader vocabs.parser
  12 sequences.private ;
  13 IN: io.sockets
  14
  15 << {
  16     { [ os windows? ] [ "windows.winsock" ] }
  17     { [ os unix? ] [ "unix.ffi" ] }
  18 } cond use-vocab >>
  19
  20 GENERIC# with-port 1 ( addrspec port -- addrspec )
  21
  22 ! Addressing
  23 <PRIVATE
  24
  25 UNION: ?string string POSTPONE: f ;
  26
  27 GENERIC: protocol ( addrspec -- n )
  28
  29 GENERIC: protocol-family ( addrspec -- af )
  30
  31 GENERIC: sockaddr-size ( addrspec -- n )
  32
  33 GENERIC: make-sockaddr ( addrspec -- sockaddr )
  34
  35 GENERIC: empty-sockaddr ( addrspec -- sockaddr )
  36
  37 GENERIC: address-size ( addrspec -- n )
  38
  39 GENERIC: inet-ntop ( data addrspec -- str )
  40
  41 GENERIC: inet-pton ( str addrspec -- data )
  42
  43 : make-sockaddr/size ( addrspec -- sockaddr size )
  44     [ make-sockaddr ] [ sockaddr-size ] bi ;
  45
  46 : empty-sockaddr/size ( addrspec -- sockaddr size )
  47     [ empty-sockaddr ] [ sockaddr-size ] bi ;
  48
  49 GENERIC: parse-sockaddr ( sockaddr addrspec -- newaddrspec )
  50
  51 M: f parse-sockaddr nip ;
  52
  53 HOOK: sockaddr-of-family os ( alien af -- sockaddr )
  54
  55 HOOK: addrspec-of-family os ( af -- addrspec )
  56
  57 PRIVATE>
  58
  59 TUPLE: local { path string read-only } ;
  60
  61 : <local> ( path -- addrspec )
  62     absolute-path local boa ;
  63
  64 M: local present path>> "Unix domain socket: " prepend ;
  65
  66 M: local protocol drop 0 ;
  67
  68 SLOT: port
  69
  70 TUPLE: ipv4 { host ?string read-only } ;
  71
  72 <PRIVATE
  73
  74 ERROR: invalid-ipv4 string reason ;
  75
  76 M: invalid-ipv4 summary drop "Invalid IPv4 address" ;
  77
  78 ERROR: malformed-ipv4 sequence ;
  79
  80 ERROR: bad-ipv4-component string ;
  81
  82 : parse-ipv4 ( string -- seq )
  83     [ f ] [
  84         "." split dup length 4 = [ malformed-ipv4 ] unless
  85         [ dup string>number [ ] [ bad-ipv4-component ] ?if ] B{ } map-as
  86     ] if-empty ;
  87
  88 : check-ipv4 ( string -- )
  89     [ parse-ipv4 drop ] [ invalid-ipv4 ] recover ;
  90
  91 PRIVATE>
  92
  93 : <ipv4> ( host -- ipv4 ) dup check-ipv4 ipv4 boa ;
  94
  95 M: ipv4 inet-ntop ( data addrspec -- str )
  96     drop 4 memory>byte-array [ number>string ] { } map-as "." join ;
  97
  98 M: ipv4 inet-pton ( str addrspec -- data )
  99     drop [ parse-ipv4 ] [ invalid-ipv4 ] recover ;
 100
 101 M: ipv4 address-size drop 4 ;
 102
 103 M: ipv4 protocol-family drop PF_INET ;
 104
 105 M: ipv4 sockaddr-size drop sockaddr-in heap-size ;
 106
 107 M: ipv4 empty-sockaddr drop sockaddr-in <struct> ;
 108
 109 M: ipv4 make-sockaddr ( inet -- sockaddr )
 110     sockaddr-in <struct>
 111         AF_INET >>family
 112         swap
 113         [ port>> htons >>port ]
 114         [ host>> "0.0.0.0" or ]
 115         [ inet-pton uint deref >>addr ] tri ;
 116
 117 M: ipv4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
 118     [ addr>> uint <ref> ] dip inet-ntop <ipv4> ;
 119
 120 TUPLE: inet4 < ipv4 { port integer read-only } ;
 121
 122 : <inet4> ( host port -- inet4 )
 123     over check-ipv4 inet4 boa ;
 124
 125 M: ipv4 with-port [ host>> ] dip <inet4> ;
 126
 127 M: inet4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
 128     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 129
 130 M: inet4 present
 131     [ host>> ] [ port>> number>string ] bi ":" glue ;
 132
 133 M: inet4 protocol drop 0 ;
 134
 135 TUPLE: ipv6
 136 { host ?string read-only }
 137 { scope-id integer read-only } ;
 138
 139 <PRIVATE
 140
 141 ERROR: invalid-ipv6 host reason ;
 142
 143 M: invalid-ipv6 summary drop "Invalid IPv6 address" ;
 144
 145 ERROR: bad-ipv6-component obj ;
 146
 147 ERROR: bad-ipv4-embedded-prefix obj ;
 148
 149 ERROR: more-than-8-components ;
 150
 151 : parse-ipv6-component ( seq -- seq' )
 152     [ dup hex> [ nip ] [ bad-ipv6-component ] if* ] { } map-as ;
 153
 154 : parse-ipv6 ( string -- seq )
 155     [ f ] [
 156         ":" split CHAR: . over last member? [
 157             unclip-last
 158             [ parse-ipv6-component ] [ parse-ipv4 ] bi* append
 159         ] [
 160             parse-ipv6-component
 161         ] if
 162     ] if-empty ;
 163
 164 : check-ipv6 ( string -- )
 165     [ "::" split1 [ parse-ipv6 ] bi@ 2drop ] [ invalid-ipv6 ] recover ;
 166
 167 PRIVATE>
 168
 169 : <ipv6> ( host -- ipv6 ) dup check-ipv6 0 ipv6 boa ;
 170
 171 M: ipv6 inet-ntop ( data addrspec -- str )
 172     drop 16 memory>byte-array 2 <groups> [ be> >hex ] map ":" join ;
 173
 174 <PRIVATE
 175
 176 : pad-ipv6 ( string1 string2 -- seq )
 177     2dup [ length ] bi@ + 8 swap -
 178     dup 0 < [ more-than-8-components ] when
 179     <byte-array> glue ;
 180
 181 : ipv6-bytes ( seq -- bytes )
 182     [ 2 >be ] { } map-as B{ } concat-as ;
 183
 184 PRIVATE>
 185
 186 M: ipv6 inet-pton ( str addrspec -- data )
 187     drop
 188     [ "::" split1 [ parse-ipv6 ] bi@ pad-ipv6 ipv6-bytes ]
 189     [ invalid-ipv6 ]
 190     recover ;
 191
 192 M: ipv6 address-size drop 16 ;
 193
 194 M: ipv6 protocol-family drop PF_INET6 ;
 195
 196 M: ipv6 sockaddr-size drop sockaddr-in6 heap-size ;
 197
 198 M: ipv6 empty-sockaddr drop sockaddr-in6 <struct> ;
 199
 200 M: ipv6 make-sockaddr ( inet -- sockaddr )
 201     sockaddr-in6 <struct>
 202         AF_INET6 >>family
 203         swap
 204         [ port>> htons >>port ]
 205         [ [ host>> "::" or ] keep inet-pton >>addr ]
 206         [ scope-id>> >>scopeid ]
 207         tri ;
 208
 209 M: ipv6 parse-sockaddr
 210     [ [ addr>> ] dip inet-ntop ] [ drop scopeid>> ] 2bi
 211     ipv6 boa ;
 212
 213 M: ipv6 present
 214     [ host>> ] [ scope-id>> ] bi
 215     [ number>string "%" glue ] unless-zero ;
 216
 217 TUPLE: inet6 < ipv6 { port integer read-only } ;
 218
 219 : <inet6> ( host port -- inet6 )
 220     [ dup check-ipv6 0 ] dip inet6 boa ;
 221
 222 M: ipv6 with-port
 223     [ [ host>> ] [ scope-id>> ] bi ] dip
 224     inet6 boa ;
 225
 226 M: inet6 parse-sockaddr
 227     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 228
 229 M: inet6 present
 230     [ call-next-method ] [ port>> number>string ] bi ":" glue ;
 231
 232 M: inet6 protocol drop 0 ;
 233
 234 <PRIVATE
 235
 236 GENERIC: (get-local-address) ( handle remote -- sockaddr )
 237
 238 : get-local-address ( handle remote -- local )
 239     [ (get-local-address) ] keep parse-sockaddr ;
 240
 241 GENERIC: (get-remote-address) ( handle remote -- sockaddr )
 242
 243 : get-remote-address ( handle local -- remote )
 244     [ (get-remote-address) ] keep parse-sockaddr ;
 245
 246 : <ports> ( handle -- input-port output-port )
 247     [
 248         [ <input-port> |dispose ] [ <output-port> |dispose ] bi
 249     ] with-destructors ;
 250
 251 SYMBOL: bind-local-address
 252
 253 GENERIC: establish-connection ( client-out remote -- )
 254
 255 GENERIC: ((client)) ( remote -- handle )
 256
 257 GENERIC: (client) ( remote -- client-in client-out local )
 258
 259 M: array (client) [ (client) 3array ] attempt-all first3 ;
 260
 261 M: object (client) ( remote -- client-in client-out local )
 262     [
 263         [ ((client)) ] keep
 264         [
 265             [ <ports> [ |dispose ] bi@ dup ] dip
 266             establish-connection
 267         ]
 268         [ get-local-address ]
 269         2bi
 270     ] with-destructors ;
 271
 272 TUPLE: server-port < port addr encoding ;
 273
 274 : check-server-port ( port -- port )
 275     dup check-disposed
 276     dup server-port? [ "Not a server port" throw ] unless ; inline
 277
 278 GENERIC: (server) ( addrspec -- handle )
 279
 280 GENERIC: (accept) ( server addrspec -- handle sockaddr )
 281
 282 TUPLE: datagram-port < port addr ;
 283
 284 HOOK: (datagram) io-backend ( addr -- datagram )
 285
 286 TUPLE: raw-port < port addr ;
 287
 288 HOOK: (raw) io-backend ( addr -- raw )
 289
 290 HOOK: (receive) io-backend ( n buf datagram -- size addrspec )
 291
 292 ERROR: invalid-port object ;
 293
 294 : check-port ( packet addrspec port -- packet addrspec port )
 295     2dup addr>> [ class ] bi@ assert=
 296     pick class byte-array assert= ;
 297
 298 : check-connectionless-port ( port -- port )
 299     dup { [ datagram-port? ] [ raw-port? ] } 1|| [ invalid-port ] unless ;
 300
 301 : check-send ( packet addrspec port -- packet addrspec port )
 302     check-connectionless-port dup check-disposed check-port ;
 303
 304 : check-receive ( port -- port )
 305     check-connectionless-port dup check-disposed ;
 306
 307 HOOK: (send) io-backend ( packet addrspec datagram -- )
 308
 309 : addrinfo>addrspec ( addrinfo -- addrspec )
 310     [ [ addr>> ] [ family>> ] bi sockaddr-of-family ]
 311     [ family>> addrspec-of-family ] bi
 312     parse-sockaddr ;
 313
 314 : parse-addrinfo-list ( addrinfo -- seq )
 315     [ next>> ] follow
 316     [ addrinfo>addrspec ] map
 317     sift ;
 318
 319 HOOK: addrinfo-error io-backend ( n -- )
 320
 321 : prepare-addrinfo ( -- addrinfo )
 322     addrinfo <struct>
 323         PF_UNSPEC >>family
 324         IPPROTO_TCP >>protocol ;
 325
 326 PRIVATE>
 327
 328 : <client> ( remote encoding -- stream local )
 329     [ (client) ] dip swap [ <encoder-duplex> ] dip ;
 330
 331 SYMBOL: local-address
 332
 333 SYMBOL: remote-address
 334
 335 : with-client ( remote encoding quot -- )
 336     [
 337         [
 338             over remote-address set
 339             <client> local-address set
 340         ] dip with-stream
 341     ] with-scope ; inline
 342
 343 : <server> ( addrspec encoding -- server )
 344     [
 345         [ (server) ] keep
 346         [ drop server-port <port> ] [ get-local-address ] 2bi
 347         >>addr
 348     ] dip >>encoding ;
 349
 350 : accept ( server -- client remote )
 351     [
 352         dup addr>>
 353         [ (accept) ] keep
 354         parse-sockaddr swap
 355         <ports>
 356     ] keep encoding>> <encoder-duplex> swap ;
 357
 358 : <datagram> ( addrspec -- datagram )
 359     [
 360         [ (datagram) |dispose ] keep
 361         [ drop datagram-port <port> ] [ get-local-address ] 2bi
 362         >>addr
 363     ] with-destructors ;
 364
 365 : <raw> ( addrspec -- datagram )
 366     [
 367         [ (raw) |dispose ] keep
 368         [ drop raw-port <port> ] [ get-local-address ] 2bi
 369         >>addr
 370     ] with-destructors ;
 371
 372 : receive-unsafe ( n buf datagram -- count addrspec )
 373     check-receive
 374     [ (receive) ] [ addr>> ] bi parse-sockaddr ; inline
 375
 376 CONSTANT: datagram-size 65536
 377
 378 :: receive ( datagram -- packet addrspec )
 379     datagram-size (byte-array) :> buf
 380     datagram-size buf datagram
 381     receive-unsafe :> ( count addrspec )
 382     count buf resize addrspec ; inline
 383
 384 :: receive-into ( buf datagram -- buf-slice addrspec )
 385     buf length :> n
 386     n buf datagram receive-unsafe :> ( count addrspec )
 387     buf count head-slice addrspec ; inline
 388
 389 : send ( packet addrspec datagram -- )
 390     check-send (send) ; inline
 391
 392 MEMO: ipv6-supported? ( -- ? )
 393     [ "::1" 0 <inet6> binary <server> dispose t ] [ drop f ] recover ;
 394
 395 [ \ ipv6-supported? reset-memoized ]
 396 "io.sockets:ipv6-supported?" add-startup-hook
 397
 398 GENERIC: resolve-host ( addrspec -- seq )
 399
 400 HOOK: resolve-localhost os ( -- obj )
 401
 402 TUPLE: hostname { host ?string read-only } ;
 403
 404 TUPLE: inet < hostname port ;
 405
 406 M: inet present
 407     [ host>> ] [ port>> number>string ] bi ":" glue ;
 408
 409 C: <inet> inet
 410
 411 M: string resolve-host
 412     f prepare-addrinfo f void* <ref>
 413     [ getaddrinfo addrinfo-error ] keep void* deref addrinfo memory>struct
 414     [ parse-addrinfo-list ] keep freeaddrinfo ;
 415
 416 M: string with-port <inet> ;
 417
 418 M: hostname resolve-host
 419     host>> resolve-host ;
 420
 421 M: hostname with-port
 422     [ host>> ] dip <inet> ;
 423
 424 M: inet resolve-host
 425     [ call-next-method ] [ port>> ] bi '[ _ with-port ] map ;
 426
 427 M: inet4 resolve-host 1array ;
 428
 429 M: inet6 resolve-host 1array ;
 430
 431 M: local resolve-host 1array ;
 432
 433 M: f resolve-host
 434     drop resolve-localhost ;
 435
 436 M: object resolve-localhost
 437     ipv6-supported?
 438     { T{ ipv4 f "0.0.0.0" } T{ ipv6 f "::" } }
 439     { T{ ipv4 f "0.0.0.0" } }
 440     ? ;
 441
 442 : host-name ( -- string )
 443     256 <byte-array> dup dup length gethostname
 444     zero? [ "gethostname failed" throw ] unless
 445     ascii alien>string ;
 446
 447 M: inet (client) resolve-host (client) ;
 448
 449 ERROR: invalid-inet-server addrspec ;
 450
 451 M: invalid-inet-server summary
 452     drop "Cannot use <server> with <inet>; use <inet4> or <inet6> instead" ;
 453
 454 M: inet (server)
 455     invalid-inet-server ;
 456
 457 ERROR: invalid-local-address addrspec ;
 458
 459 M: invalid-local-address summary
 460     drop "Cannot use with-local-address with <inet>; use <inet4> or <inet6> instead" ;
 461
 462 : with-local-address ( addr quot -- )
 463     [
 464         [ ] [ inet4? ] [ inet6? ] tri or
 465         [ bind-local-address ]
 466         [ invalid-local-address ] if
 467     ] dip with-variable ; inline
 468
 469 {
 470     { [ os unix? ] [ "io.sockets.unix" require ] }
 471     { [ os windows? ] [ "io.sockets.windows" require ] }
 472 } cond