basis/io/sockets/sockets.factor

   1 ! Copyright (C) 2007, 2011 Slava Pestov, Doug Coleman,
   2 ! Daniel Ehrenberg.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: accessors alien.c-types alien.data alien.strings arrays
   5 assocs byte-arrays classes classes.struct combinators
   6 combinators.short-circuit continuations destructors fry generic
   7 grouping init io.backend io.pathnames io.binary io.encodings
   8 io.encodings.ascii io.encodings.binary io.ports
   9 io.streams.duplex kernel math math.parser memoize namespaces
  10 parser present sequences splitting strings summary system
  11 vocabs.loader vocabs.parser ;
  12 IN: io.sockets
  13
  14 << {
  15     { [ os windows? ] [ "windows.winsock" ] }
  16     { [ os unix? ] [ "unix.ffi" ] }
  17 } cond use-vocab >>
  18
  19 GENERIC# with-port 1 ( addrspec port -- addrspec )
  20
  21 ! Addressing
  22 <PRIVATE
  23
  24 UNION: ?string string POSTPONE: f ;
  25
  26 GENERIC: protocol ( addrspec -- n )
  27
  28 GENERIC: protocol-family ( addrspec -- af )
  29
  30 GENERIC: sockaddr-size ( addrspec -- n )
  31
  32 GENERIC: make-sockaddr ( addrspec -- sockaddr )
  33
  34 GENERIC: empty-sockaddr ( addrspec -- sockaddr )
  35
  36 GENERIC: address-size ( addrspec -- n )
  37
  38 GENERIC: inet-ntop ( data addrspec -- str )
  39
  40 GENERIC: inet-pton ( str addrspec -- data )
  41
  42 : make-sockaddr/size ( addrspec -- sockaddr size )
  43     [ make-sockaddr ] [ sockaddr-size ] bi ;
  44
  45 : empty-sockaddr/size ( addrspec -- sockaddr size )
  46     [ empty-sockaddr ] [ sockaddr-size ] bi ;
  47
  48 GENERIC: parse-sockaddr ( sockaddr addrspec -- newaddrspec )
  49
  50 M: f parse-sockaddr nip ;
  51
  52 HOOK: sockaddr-of-family os ( alien af -- sockaddr )
  53
  54 HOOK: addrspec-of-family os ( af -- addrspec )
  55
  56 PRIVATE>
  57
  58 TUPLE: local { path string read-only } ;
  59
  60 : <local> ( path -- addrspec )
  61     absolute-path local boa ;
  62
  63 M: local present path>> "Unix domain socket: " prepend ;
  64
  65 M: local protocol drop 0 ;
  66
  67 SLOT: port
  68
  69 TUPLE: ipv4 { host ?string read-only } ;
  70
  71 <PRIVATE
  72
  73 ERROR: invalid-ipv4 string reason ;
  74
  75 M: invalid-ipv4 summary drop "Invalid IPv4 address" ;
  76
  77 ERROR: malformed-ipv4 sequence ;
  78
  79 ERROR: bad-ipv4-component string ;
  80
  81 : parse-ipv4 ( string -- seq )
  82     [ f ] [
  83         "." split dup length 4 = [ malformed-ipv4 ] unless
  84         [ dup string>number [ ] [ bad-ipv4-component ] ?if ] B{ } map-as
  85     ] if-empty ;
  86
  87 : check-ipv4 ( string -- )
  88     [ parse-ipv4 drop ] [ invalid-ipv4 ] recover ;
  89
  90 PRIVATE>
  91
  92 : <ipv4> ( host -- ipv4 ) dup check-ipv4 ipv4 boa ;
  93
  94 M: ipv4 inet-ntop ( data addrspec -- str )
  95     drop 4 memory>byte-array [ number>string ] { } map-as "." join ;
  96
  97 M: ipv4 inet-pton ( str addrspec -- data )
  98     drop [ parse-ipv4 ] [ invalid-ipv4 ] recover ;
  99
 100 M: ipv4 address-size drop 4 ;
 101
 102 M: ipv4 protocol-family drop PF_INET ;
 103
 104 M: ipv4 sockaddr-size drop sockaddr-in heap-size ;
 105
 106 M: ipv4 empty-sockaddr drop sockaddr-in <struct> ;
 107
 108 M: ipv4 make-sockaddr ( inet -- sockaddr )
 109     sockaddr-in <struct>
 110         AF_INET >>family
 111         swap
 112         [ port>> htons >>port ]
 113         [ host>> "0.0.0.0" or ]
 114         [ inet-pton uint deref >>addr ] tri ;
 115
 116 M: ipv4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
 117     [ addr>> uint <ref> ] dip inet-ntop <ipv4> ;
 118
 119 TUPLE: inet4 < ipv4 { port integer read-only } ;
 120
 121 : <inet4> ( host port -- inet4 )
 122     over check-ipv4 inet4 boa ;
 123
 124 M: ipv4 with-port [ host>> ] dip <inet4> ;
 125
 126 M: inet4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
 127     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 128
 129 M: inet4 present
 130     [ host>> ] [ port>> number>string ] bi ":" glue ;
 131
 132 M: inet4 protocol drop 0 ;
 133
 134 TUPLE: ipv6
 135 { host ?string read-only }
 136 { scope-id integer read-only } ;
 137
 138 <PRIVATE
 139
 140 ERROR: invalid-ipv6 host reason ;
 141
 142 M: invalid-ipv6 summary drop "Invalid IPv6 address" ;
 143
 144 ERROR: bad-ipv6-component obj ;
 145
 146 ERROR: bad-ipv4-embedded-prefix obj ;
 147
 148 ERROR: more-than-8-components ;
 149
 150 : parse-ipv6-component ( seq -- seq' )
 151     [ dup hex> [ nip ] [ bad-ipv6-component ] if* ] { } map-as ;
 152
 153 : parse-ipv6 ( string -- seq )
 154     [ f ] [
 155         ":" split CHAR: . over last member? [
 156             unclip-last
 157             [ parse-ipv6-component ] [ parse-ipv4 ] bi* append
 158         ] [
 159             parse-ipv6-component
 160         ] if
 161     ] if-empty ;
 162
 163 : check-ipv6 ( string -- )
 164     [ "::" split1 [ parse-ipv6 ] bi@ 2drop ] [ invalid-ipv6 ] recover ;
 165
 166 PRIVATE>
 167
 168 : <ipv6> ( host -- ipv6 ) dup check-ipv6 0 ipv6 boa ;
 169
 170 M: ipv6 inet-ntop ( data addrspec -- str )
 171     drop 16 memory>byte-array 2 <groups> [ be> >hex ] map ":" join ;
 172
 173 <PRIVATE
 174
 175 : pad-ipv6 ( string1 string2 -- seq )
 176     2dup [ length ] bi@ + 8 swap -
 177     dup 0 < [ more-than-8-components ] when
 178     <byte-array> glue ;
 179
 180 : ipv6-bytes ( seq -- bytes )
 181     [ 2 >be ] { } map-as B{ } concat-as ;
 182
 183 PRIVATE>
 184
 185 M: ipv6 inet-pton ( str addrspec -- data )
 186     drop
 187     [ "::" split1 [ parse-ipv6 ] bi@ pad-ipv6 ipv6-bytes ]
 188     [ invalid-ipv6 ]
 189     recover ;
 190
 191 M: ipv6 address-size drop 16 ;
 192
 193 M: ipv6 protocol-family drop PF_INET6 ;
 194
 195 M: ipv6 sockaddr-size drop sockaddr-in6 heap-size ;
 196
 197 M: ipv6 empty-sockaddr drop sockaddr-in6 <struct> ;
 198
 199 M: ipv6 make-sockaddr ( inet -- sockaddr )
 200     sockaddr-in6 <struct>
 201         AF_INET6 >>family
 202         swap
 203         [ port>> htons >>port ]
 204         [ [ host>> "::" or ] keep inet-pton >>addr ]
 205         [ scope-id>> >>scopeid ]
 206         tri ;
 207
 208 M: ipv6 parse-sockaddr
 209     [ [ addr>> ] dip inet-ntop ] [ drop scopeid>> ] 2bi
 210     ipv6 boa ;
 211
 212 M: ipv6 present
 213     [ host>> ] [ scope-id>> ] bi
 214     [ number>string "%" glue ] unless-zero ;
 215
 216 TUPLE: inet6 < ipv6 { port integer read-only } ;
 217
 218 : <inet6> ( host port -- inet6 )
 219     [ dup check-ipv6 0 ] dip inet6 boa ;
 220
 221 M: ipv6 with-port
 222     [ [ host>> ] [ scope-id>> ] bi ] dip
 223     inet6 boa ;
 224
 225 M: inet6 parse-sockaddr
 226     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 227
 228 M: inet6 present
 229     [ call-next-method ] [ port>> number>string ] bi ":" glue ;
 230
 231 M: inet6 protocol drop 0 ;
 232
 233 <PRIVATE
 234
 235 GENERIC: (get-local-address) ( handle remote -- sockaddr )
 236
 237 : get-local-address ( handle remote -- local )
 238     [ (get-local-address) ] keep parse-sockaddr ;
 239
 240 GENERIC: (get-remote-address) ( handle remote -- sockaddr )
 241
 242 : get-remote-address ( handle local -- remote )
 243     [ (get-remote-address) ] keep parse-sockaddr ;
 244
 245 : <ports> ( handle -- input-port output-port )
 246     [
 247         [ <input-port> |dispose ] [ <output-port> |dispose ] bi
 248     ] with-destructors ;
 249
 250 SYMBOL: bind-local-address
 251
 252 GENERIC: establish-connection ( client-out remote -- )
 253
 254 GENERIC: ((client)) ( remote -- handle )
 255
 256 GENERIC: (client) ( remote -- client-in client-out local )
 257
 258 M: array (client) [ (client) 3array ] attempt-all first3 ;
 259
 260 M: object (client) ( remote -- client-in client-out local )
 261     [
 262         [ ((client)) ] keep
 263         [
 264             [ <ports> [ |dispose ] bi@ dup ] dip
 265             establish-connection
 266         ]
 267         [ get-local-address ]
 268         2bi
 269     ] with-destructors ;
 270
 271 TUPLE: server-port < port addr encoding ;
 272
 273 : check-server-port ( port -- port )
 274     dup check-disposed
 275     dup server-port? [ "Not a server port" throw ] unless ; inline
 276
 277 GENERIC: (server) ( addrspec -- handle )
 278
 279 GENERIC: (accept) ( server addrspec -- handle sockaddr )
 280
 281 TUPLE: datagram-port < port addr ;
 282
 283 HOOK: (datagram) io-backend ( addr -- datagram )
 284
 285 TUPLE: raw-port < port addr ;
 286
 287 HOOK: (raw) io-backend ( addr -- raw )
 288
 289 HOOK: (receive) io-backend ( datagram -- packet addrspec )
 290
 291 ERROR: invalid-port object ;
 292
 293 : check-port ( packet addrspec port -- packet addrspec port )
 294     2dup addr>> [ class ] bi@ assert=
 295     pick class byte-array assert= ;
 296
 297 : check-connectionless-port ( port -- port )
 298     dup { [ datagram-port? ] [ raw-port? ] } 1|| [ invalid-port ] unless ;
 299
 300 : check-send ( packet addrspec port -- packet addrspec port )
 301     check-connectionless-port dup check-disposed check-port ;
 302
 303 : check-receive ( port -- port )
 304     check-connectionless-port dup check-disposed ;
 305
 306 HOOK: (send) io-backend ( packet addrspec datagram -- )
 307
 308 : addrinfo>addrspec ( addrinfo -- addrspec )
 309     [ [ addr>> ] [ family>> ] bi sockaddr-of-family ]
 310     [ family>> addrspec-of-family ] bi
 311     parse-sockaddr ;
 312
 313 : parse-addrinfo-list ( addrinfo -- seq )
 314     [ next>> ] follow
 315     [ addrinfo>addrspec ] map
 316     sift ;
 317
 318 HOOK: addrinfo-error io-backend ( n -- )
 319
 320 : prepare-addrinfo ( -- addrinfo )
 321     addrinfo <struct>
 322         PF_UNSPEC >>family
 323         IPPROTO_TCP >>protocol ;
 324
 325 PRIVATE>
 326
 327 : <client> ( remote encoding -- stream local )
 328     [ (client) ] dip swap [ <encoder-duplex> ] dip ;
 329
 330 SYMBOL: local-address
 331
 332 SYMBOL: remote-address
 333
 334 : with-client ( remote encoding quot -- )
 335     [
 336         [
 337             over remote-address set
 338             <client> local-address set
 339         ] dip with-stream
 340     ] with-scope ; inline
 341
 342 : <server> ( addrspec encoding -- server )
 343     [
 344         [ (server) ] keep
 345         [ drop server-port <port> ] [ get-local-address ] 2bi
 346         >>addr
 347     ] dip >>encoding ;
 348
 349 : accept ( server -- client remote )
 350     [
 351         dup addr>>
 352         [ (accept) ] keep
 353         parse-sockaddr swap
 354         <ports>
 355     ] keep encoding>> <encoder-duplex> swap ;
 356
 357 : <datagram> ( addrspec -- datagram )
 358     [
 359         [ (datagram) |dispose ] keep
 360         [ drop datagram-port <port> ] [ get-local-address ] 2bi
 361         >>addr
 362     ] with-destructors ;
 363
 364 : <raw> ( addrspec -- datagram )
 365     [
 366         [ (raw) |dispose ] keep
 367         [ drop raw-port <port> ] [ get-local-address ] 2bi
 368         >>addr
 369     ] with-destructors ;
 370
 371 : receive ( datagram -- packet addrspec )
 372     check-receive
 373     [ (receive) ] [ addr>> ] bi parse-sockaddr ;
 374
 375 : send ( packet addrspec datagram -- )
 376     check-send (send) ;
 377
 378 MEMO: ipv6-supported? ( -- ? )
 379     [ "::1" 0 <inet6> binary <server> dispose t ] [ drop f ] recover ;
 380
 381 [ \ ipv6-supported? reset-memoized ] "io.sockets" add-startup-hook
 382
 383 GENERIC: resolve-host ( addrspec -- seq )
 384
 385 HOOK: resolve-localhost os ( -- obj )
 386
 387 TUPLE: hostname { host ?string read-only } ;
 388
 389 TUPLE: inet < hostname port ;
 390
 391 M: inet present
 392     [ host>> ] [ port>> number>string ] bi ":" glue ;
 393
 394 C: <inet> inet
 395
 396 M: string resolve-host
 397     f prepare-addrinfo f void* <ref>
 398     [ getaddrinfo addrinfo-error ] keep void* deref addrinfo memory>struct
 399     [ parse-addrinfo-list ] keep freeaddrinfo ;
 400
 401 M: string with-port <inet> ;
 402
 403 M: hostname resolve-host
 404     host>> resolve-host ;
 405
 406 M: hostname with-port
 407     [ host>> ] dip <inet> ;
 408
 409 M: inet resolve-host
 410     [ call-next-method ] [ port>> ] bi '[ _ with-port ] map ;
 411
 412 M: inet4 resolve-host 1array ;
 413
 414 M: inet6 resolve-host 1array ;
 415
 416 M: local resolve-host 1array ;
 417
 418 M: f resolve-host
 419     drop resolve-localhost ;
 420
 421 M: object resolve-localhost
 422     ipv6-supported?
 423     { T{ ipv4 f "0.0.0.0" } T{ ipv6 f "::" } }
 424     { T{ ipv4 f "0.0.0.0" } }
 425     ? ;
 426
 427 : host-name ( -- string )
 428     256 <byte-array> dup dup length gethostname
 429     zero? [ "gethostname failed" throw ] unless
 430     ascii alien>string ;
 431
 432 M: inet (client) resolve-host (client) ;
 433
 434 ERROR: invalid-inet-server addrspec ;
 435
 436 M: invalid-inet-server summary
 437     drop "Cannot use <server> with <inet>; use <inet4> or <inet6> instead" ;
 438
 439 M: inet (server)
 440     invalid-inet-server ;
 441
 442 ERROR: invalid-local-address addrspec ;
 443
 444 M: invalid-local-address summary
 445     drop "Cannot use with-local-address with <inet>; use <inet4> or <inet6> instead" ;
 446
 447 : with-local-address ( addr quot -- )
 448     [
 449         [ ] [ inet4? ] [ inet6? ] tri or
 450         [ bind-local-address ]
 451         [ invalid-local-address ] if
 452     ] dip with-variable ; inline
 453
 454 {
 455     { [ os unix? ] [ "io.sockets.unix" require ] }
 456     { [ os windows? ] [ "io.sockets.windows" require ] }
 457 } cond