basis/io/sockets/sockets.factor

   1 ! Copyright (C) 2007, 2011 Slava Pestov, Doug Coleman,
   2 ! Daniel Ehrenberg.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: accessors alien.c-types alien.data alien.strings arrays
   5 assocs byte-arrays classes classes.struct combinators
   6 combinators.short-circuit continuations destructors fry generic
   7 grouping init io.backend io.pathnames io.binary io.encodings
   8 io.encodings.ascii io.encodings.binary io.ports
   9 io.streams.duplex kernel math math.parser memoize namespaces
  10 parser present sequences splitting strings summary system
  11 vocabs.loader vocabs.parser ;
  12 IN: io.sockets
  13
  14 << {
  15     { [ os windows? ] [ "windows.winsock" ] }
  16     { [ os unix? ] [ "unix.ffi" ] }
  17 } cond use-vocab >>
  18
  19 GENERIC# with-port 1 ( addrspec port -- addrspec )
  20
  21 ! Addressing
  22 <PRIVATE
  23
  24 UNION: ?string string POSTPONE: f ;
  25
  26 GENERIC: protocol ( addrspec -- n )
  27
  28 GENERIC: protocol-family ( addrspec -- af )
  29
  30 GENERIC: sockaddr-size ( addrspec -- n )
  31
  32 GENERIC: make-sockaddr ( addrspec -- sockaddr )
  33
  34 GENERIC: empty-sockaddr ( addrspec -- sockaddr )
  35
  36 GENERIC: address-size ( addrspec -- n )
  37
  38 GENERIC: inet-ntop ( data addrspec -- str )
  39
  40 GENERIC: inet-pton ( str addrspec -- data )
  41
  42 : make-sockaddr/size ( addrspec -- sockaddr size )
  43     [ make-sockaddr ] [ sockaddr-size ] bi ;
  44
  45 : empty-sockaddr/size ( addrspec -- sockaddr size )
  46     [ empty-sockaddr ] [ sockaddr-size ] bi ;
  47
  48 GENERIC: parse-sockaddr ( sockaddr addrspec -- newaddrspec )
  49
  50 M: f parse-sockaddr nip ;
  51
  52 HOOK: sockaddr-of-family os ( alien af -- sockaddr )
  53
  54 HOOK: addrspec-of-family os ( af -- addrspec )
  55
  56 PRIVATE>
  57
  58 TUPLE: local { path string read-only } ;
  59
  60 : <local> ( path -- addrspec )
  61     absolute-path local boa ;
  62
  63 M: local present path>> "Unix domain socket: " prepend ;
  64
  65 M: local protocol drop 0 ;
  66
  67 SLOT: port
  68
  69 TUPLE: ipv4 { host ?string read-only } ;
  70
  71 C: <ipv4> ipv4
  72
  73 M: ipv4 inet-ntop ( data addrspec -- str )
  74     drop 4 memory>byte-array [ number>string ] { } map-as "." join ;
  75
  76 <PRIVATE
  77
  78 ERROR: malformed-ipv4 sequence ;
  79
  80 ERROR: bad-ipv4-component string ;
  81
  82 : parse-ipv4 ( string -- seq )
  83     "." split dup length 4 = [ malformed-ipv4 ] unless
  84     [ dup string>number [ ] [ bad-ipv4-component ] ?if ] B{ } map-as ;
  85
  86 ERROR: invalid-ipv4 string reason ;
  87
  88 M: invalid-ipv4 summary drop "Invalid IPv4 address" ;
  89
  90 PRIVATE>
  91
  92 M: ipv4 inet-pton ( str addrspec -- data )
  93     drop [ parse-ipv4 ] [ invalid-ipv4 ] recover ;
  94
  95 M: ipv4 address-size drop 4 ;
  96
  97 M: ipv4 protocol-family drop PF_INET ;
  98
  99 M: ipv4 sockaddr-size drop sockaddr-in heap-size ;
 100
 101 M: ipv4 empty-sockaddr drop sockaddr-in <struct> ;
 102
 103 M: ipv4 make-sockaddr ( inet -- sockaddr )
 104     sockaddr-in <struct>
 105         AF_INET >>family
 106         swap
 107         [ port>> htons >>port ]
 108         [ host>> "0.0.0.0" or ]
 109         [ inet-pton uint deref >>addr ] tri ;
 110
 111 M: ipv4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
 112     [ addr>> uint <ref> ] dip inet-ntop <ipv4> ;
 113
 114 TUPLE: inet4 < ipv4 { port integer read-only } ;
 115
 116 C: <inet4> inet4
 117
 118 M: ipv4 with-port [ host>> ] dip <inet4> ;
 119
 120 M: inet4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
 121     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 122
 123 M: inet4 present
 124     [ host>> ] [ port>> number>string ] bi ":" glue ;
 125
 126 M: inet4 protocol drop 0 ;
 127
 128 TUPLE: ipv6
 129 { host ?string read-only }
 130 { scope-id integer read-only } ;
 131
 132 : <ipv6> ( host -- ipv6 ) 0 ipv6 boa ;
 133
 134 M: ipv6 inet-ntop ( data addrspec -- str )
 135     drop 16 memory>byte-array 2 <groups> [ be> >hex ] map ":" join ;
 136
 137 ERROR: invalid-ipv6 string reason ;
 138
 139 <PRIVATE
 140
 141 ERROR: bad-ipv6-component obj ;
 142
 143 ERROR: bad-ipv4-embedded-prefix obj ;
 144
 145 ERROR: more-than-8-components ;
 146
 147 : parse-ipv6-component ( seq -- seq' )
 148     [ dup hex> [ nip ] [ bad-ipv6-component ] if* ] { } map-as ;
 149
 150 : parse-ipv6 ( string -- seq )
 151     [ f ] [
 152         ":" split CHAR: . over last member? [
 153             unclip-last
 154             [ parse-ipv6-component ] [ parse-ipv4 ] bi* append
 155         ] [
 156             parse-ipv6-component
 157         ] if
 158     ] if-empty ;
 159
 160 : pad-ipv6 ( string1 string2 -- seq )
 161     2dup [ length ] bi@ + 8 swap -
 162     dup 0 < [ more-than-8-components ] when
 163     <byte-array> glue ;
 164
 165 : ipv6-bytes ( seq -- bytes )
 166     [ 2 >be ] { } map-as B{ } concat-as ;
 167
 168 PRIVATE>
 169
 170 M: ipv6 inet-pton ( str addrspec -- data )
 171     drop
 172     [ "::" split1 [ parse-ipv6 ] bi@ pad-ipv6 ipv6-bytes ]
 173     [ invalid-ipv6 ]
 174     recover ;
 175
 176 M: ipv6 address-size drop 16 ;
 177
 178 M: ipv6 protocol-family drop PF_INET6 ;
 179
 180 M: ipv6 sockaddr-size drop sockaddr-in6 heap-size ;
 181
 182 M: ipv6 empty-sockaddr drop sockaddr-in6 <struct> ;
 183
 184 M: ipv6 make-sockaddr ( inet -- sockaddr )
 185     sockaddr-in6 <struct>
 186         AF_INET6 >>family
 187         swap
 188         [ port>> htons >>port ]
 189         [ [ host>> "::" or ] keep inet-pton >>addr ]
 190         [ scope-id>> >>scopeid ]
 191         tri ;
 192
 193 M: ipv6 parse-sockaddr
 194     [ [ addr>> ] dip inet-ntop ] [ drop scopeid>> ] 2bi
 195     ipv6 boa ;
 196
 197 M: ipv6 present
 198     [ host>> ] [ scope-id>> ] bi
 199     [ number>string "%" glue ] unless-zero ;
 200
 201 TUPLE: inet6 < ipv6 { port integer read-only } ;
 202
 203 : <inet6> ( host port -- inet6 ) [ 0 ] dip inet6 boa ;
 204
 205 M: ipv6 with-port
 206     [ [ host>> ] [ scope-id>> ] bi ] dip
 207     inet6 boa ;
 208
 209 M: inet6 parse-sockaddr
 210     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 211
 212 M: inet6 present
 213     [ call-next-method ] [ port>> number>string ] bi ":" glue ;
 214
 215 M: inet6 protocol drop 0 ;
 216
 217 <PRIVATE
 218
 219 GENERIC: (get-local-address) ( handle remote -- sockaddr )
 220
 221 : get-local-address ( handle remote -- local )
 222     [ (get-local-address) ] keep parse-sockaddr ;
 223
 224 GENERIC: (get-remote-address) ( handle remote -- sockaddr )
 225
 226 : get-remote-address ( handle local -- remote )
 227     [ (get-remote-address) ] keep parse-sockaddr ;
 228
 229 : <ports> ( handle -- input-port output-port )
 230     [
 231         [ <input-port> |dispose ] [ <output-port> |dispose ] bi
 232     ] with-destructors ;
 233
 234 SYMBOL: bind-local-address
 235
 236 GENERIC: establish-connection ( client-out remote -- )
 237
 238 GENERIC: ((client)) ( remote -- handle )
 239
 240 GENERIC: (client) ( remote -- client-in client-out local )
 241
 242 M: array (client) [ (client) 3array ] attempt-all first3 ;
 243
 244 M: object (client) ( remote -- client-in client-out local )
 245     [
 246         [ ((client)) ] keep
 247         [
 248             [ <ports> [ |dispose ] bi@ dup ] dip
 249             establish-connection
 250         ]
 251         [ get-local-address ]
 252         2bi
 253     ] with-destructors ;
 254
 255 TUPLE: server-port < port addr encoding ;
 256
 257 : check-server-port ( port -- port )
 258     dup check-disposed
 259     dup server-port? [ "Not a server port" throw ] unless ; inline
 260
 261 GENERIC: (server) ( addrspec -- handle )
 262
 263 GENERIC: (accept) ( server addrspec -- handle sockaddr )
 264
 265 TUPLE: datagram-port < port addr ;
 266
 267 HOOK: (datagram) io-backend ( addr -- datagram )
 268
 269 TUPLE: raw-port < port addr ;
 270
 271 HOOK: (raw) io-backend ( addr -- raw )
 272
 273 HOOK: (receive) io-backend ( datagram -- packet addrspec )
 274
 275 ERROR: invalid-port object ;
 276
 277 : check-port ( packet addrspec port -- packet addrspec port )
 278     2dup addr>> [ class ] bi@ assert=
 279     pick class byte-array assert= ;
 280
 281 : check-connectionless-port ( port -- port )
 282     dup { [ datagram-port? ] [ raw-port? ] } 1|| [ invalid-port ] unless ;
 283
 284 : check-send ( packet addrspec port -- packet addrspec port )
 285     check-connectionless-port dup check-disposed check-port ;
 286
 287 : check-receive ( port -- port )
 288     check-connectionless-port dup check-disposed ;
 289
 290 HOOK: (send) io-backend ( packet addrspec datagram -- )
 291
 292 : addrinfo>addrspec ( addrinfo -- addrspec )
 293     [ [ addr>> ] [ family>> ] bi sockaddr-of-family ]
 294     [ family>> addrspec-of-family ] bi
 295     parse-sockaddr ;
 296
 297 : parse-addrinfo-list ( addrinfo -- seq )
 298     [ next>> ] follow
 299     [ addrinfo>addrspec ] map
 300     sift ;
 301
 302 HOOK: addrinfo-error io-backend ( n -- )
 303
 304 : prepare-addrinfo ( -- addrinfo )
 305     addrinfo <struct>
 306         PF_UNSPEC >>family
 307         IPPROTO_TCP >>protocol ;
 308
 309 PRIVATE>
 310
 311 : <client> ( remote encoding -- stream local )
 312     [ (client) ] dip swap [ <encoder-duplex> ] dip ;
 313
 314 SYMBOL: local-address
 315
 316 SYMBOL: remote-address
 317
 318 : with-client ( remote encoding quot -- )
 319     [
 320         [
 321             over remote-address set
 322             <client> local-address set
 323         ] dip with-stream
 324     ] with-scope ; inline
 325
 326 : <server> ( addrspec encoding -- server )
 327     [
 328         [ (server) ] keep
 329         [ drop server-port <port> ] [ get-local-address ] 2bi
 330         >>addr
 331     ] dip >>encoding ;
 332
 333 : accept ( server -- client remote )
 334     [
 335         dup addr>>
 336         [ (accept) ] keep
 337         parse-sockaddr swap
 338         <ports>
 339     ] keep encoding>> <encoder-duplex> swap ;
 340
 341 : <datagram> ( addrspec -- datagram )
 342     [
 343         [ (datagram) |dispose ] keep
 344         [ drop datagram-port <port> ] [ get-local-address ] 2bi
 345         >>addr
 346     ] with-destructors ;
 347
 348 : <raw> ( addrspec -- datagram )
 349     [
 350         [ (raw) |dispose ] keep
 351         [ drop raw-port <port> ] [ get-local-address ] 2bi
 352         >>addr
 353     ] with-destructors ;
 354
 355 : receive ( datagram -- packet addrspec )
 356     check-receive
 357     [ (receive) ] [ addr>> ] bi parse-sockaddr ;
 358
 359 : send ( packet addrspec datagram -- )
 360     check-send (send) ;
 361
 362 MEMO: ipv6-supported? ( -- ? )
 363     [ "::1" 0 <inet6> binary <server> dispose t ] [ drop f ] recover ;
 364
 365 [ \ ipv6-supported? reset-memoized ] "io.sockets" add-startup-hook
 366
 367 GENERIC: resolve-host ( addrspec -- seq )
 368
 369 HOOK: resolve-localhost os ( -- obj )
 370
 371 TUPLE: hostname { host ?string read-only } ;
 372
 373 TUPLE: inet < hostname port ;
 374
 375 M: inet present
 376     [ host>> ] [ port>> number>string ] bi ":" glue ;
 377
 378 C: <inet> inet
 379
 380 M: string resolve-host
 381     f prepare-addrinfo f void* <ref>
 382     [ getaddrinfo addrinfo-error ] keep void* deref addrinfo memory>struct
 383     [ parse-addrinfo-list ] keep freeaddrinfo ;
 384
 385 M: string with-port <inet> ;
 386
 387 M: hostname resolve-host
 388     host>> resolve-host ;
 389
 390 M: hostname with-port
 391     [ host>> ] dip <inet> ;
 392
 393 M: inet resolve-host
 394     [ call-next-method ] [ port>> ] bi '[ _ with-port ] map ;
 395
 396 M: inet4 resolve-host 1array ;
 397
 398 M: inet6 resolve-host 1array ;
 399
 400 M: local resolve-host 1array ;
 401
 402 M: f resolve-host
 403     drop resolve-localhost ;
 404
 405 M: object resolve-localhost
 406     ipv6-supported?
 407     { T{ ipv4 f "0.0.0.0" } T{ ipv6 f "::" } }
 408     { T{ ipv4 f "0.0.0.0" } }
 409     ? ;
 410
 411 : host-name ( -- string )
 412     256 <byte-array> dup dup length gethostname
 413     zero? [ "gethostname failed" throw ] unless
 414     ascii alien>string ;
 415
 416 M: inet (client) resolve-host (client) ;
 417
 418 ERROR: invalid-inet-server addrspec ;
 419
 420 M: invalid-inet-server summary
 421     drop "Cannot use <server> with <inet>; use <inet4> or <inet6> instead" ;
 422
 423 M: inet (server)
 424     invalid-inet-server ;
 425
 426 ERROR: invalid-local-address addrspec ;
 427
 428 M: invalid-local-address summary
 429     drop "Cannot use with-local-address with <inet>; use <inet4> or <inet6> instead" ;
 430
 431 : with-local-address ( addr quot -- )
 432     [
 433         [ ] [ inet4? ] [ inet6? ] tri or
 434         [ bind-local-address ]
 435         [ invalid-local-address ] if
 436     ] dip with-variable ; inline
 437
 438 {
 439     { [ os unix? ] [ "io.sockets.unix" require ] }
 440     { [ os windows? ] [ "io.sockets.windows" require ] }
 441 } cond