basis/io/sockets/sockets.factor

   1 ! Copyright (C) 2007, 2011 Slava Pestov, Doug Coleman,
   2 ! Daniel Ehrenberg.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: accessors alien.c-types alien.data alien.strings arrays
   5 byte-arrays classes classes.struct combinators
   6 combinators.short-circuit continuations destructors fry
   7 grouping init io.backend io.binary io.encodings.ascii
   8 io.encodings.binary io.pathnames io.ports io.streams.duplex
   9 kernel locals math math.parser memoize namespaces present
  10 sequences sequences.private splitting strings summary system
  11 vocabs vocabs.parser ip-parser ip-parser.private ;
  12 IN: io.sockets
  13
  14 << {
  15     { [ os windows? ] [ "windows.winsock" ] }
  16     { [ os unix? ] [ "unix.ffi" ] }
  17 } cond use-vocab >>
  18
  19 GENERIC# with-port 1 ( addrspec port -- addrspec )
  20
  21 ! Addressing
  22 <PRIVATE
  23
  24 GENERIC: protocol ( addrspec -- n )
  25
  26 GENERIC: protocol-family ( addrspec -- af )
  27
  28 GENERIC: sockaddr-size ( addrspec -- n )
  29
  30 GENERIC: make-sockaddr ( addrspec -- sockaddr )
  31
  32 GENERIC: empty-sockaddr ( addrspec -- sockaddr )
  33
  34 GENERIC: address-size ( addrspec -- n )
  35
  36 GENERIC: inet-ntop ( data addrspec -- str )
  37
  38 GENERIC: inet-pton ( str addrspec -- data )
  39
  40 : make-sockaddr/size ( addrspec -- sockaddr size )
  41     [ make-sockaddr ] [ sockaddr-size ] bi ;
  42
  43 : empty-sockaddr/size ( addrspec -- sockaddr size )
  44     [ empty-sockaddr ] [ sockaddr-size ] bi ;
  45
  46 GENERIC: parse-sockaddr ( sockaddr addrspec -- newaddrspec )
  47
  48 M: f parse-sockaddr nip ;
  49
  50 HOOK: sockaddr-of-family os ( alien af -- sockaddr )
  51
  52 HOOK: addrspec-of-family os ( af -- addrspec )
  53
  54 PRIVATE>
  55
  56 TUPLE: local { path string read-only } ;
  57
  58 : <local> ( path -- addrspec )
  59     absolute-path local boa ;
  60
  61 M: local present path>> "Unix domain socket: " prepend ;
  62
  63 M: local protocol drop 0 ;
  64
  65 SLOT: port
  66
  67 TUPLE: ipv4 { host maybe{ string } read-only } ;
  68
  69 <PRIVATE
  70
  71 ERROR: invalid-ipv4 host reason ;
  72
  73 M: invalid-ipv4 summary drop "Invalid IPv4 address" ;
  74
  75 : ?parse-ipv4 ( string -- seq/f )
  76     [ f ] [ parse-ipv4 ] if-empty ;
  77
  78 : check-ipv4 ( host -- )
  79     [ ?parse-ipv4 drop ] [ invalid-ipv4 ] recover ;
  80
  81 PRIVATE>
  82
  83 : <ipv4> ( host -- ipv4 ) dup check-ipv4 ipv4 boa ;
  84
  85 M: ipv4 inet-ntop ( data addrspec -- str )
  86     drop 4 memory>byte-array join-ipv4 ;
  87
  88 M: ipv4 inet-pton ( str addrspec -- data )
  89     drop [ ?parse-ipv4 ] [ invalid-ipv4 ] recover ;
  90
  91 M: ipv4 address-size drop 4 ;
  92
  93 M: ipv4 protocol-family drop PF_INET ;
  94
  95 M: ipv4 sockaddr-size drop sockaddr-in heap-size ;
  96
  97 M: ipv4 empty-sockaddr drop sockaddr-in <struct> ;
  98
  99 M: ipv4 make-sockaddr ( inet -- sockaddr )
 100     sockaddr-in <struct>
 101         AF_INET >>family
 102         swap
 103         [ port>> htons >>port ]
 104         [ host>> "0.0.0.0" or ]
 105         [ inet-pton uint deref >>addr ] tri ;
 106
 107 M: ipv4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
 108     [ addr>> uint <ref> ] dip inet-ntop <ipv4> ;
 109
 110 TUPLE: inet4 < ipv4 { port integer read-only } ;
 111
 112 : <inet4> ( host port -- inet4 )
 113     over check-ipv4 inet4 boa ;
 114
 115 : <random-local-inet4> ( -- inet4 ) f 0 <inet4> ;
 116
 117 M: ipv4 with-port [ host>> ] dip <inet4> ;
 118
 119 M: inet4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
 120     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 121
 122 M: inet4 present
 123     [ host>> ] [ port>> number>string ] bi ":" glue ;
 124
 125 M: inet4 protocol drop 0 ;
 126
 127 TUPLE: ipv6
 128 { host maybe{ string } read-only }
 129 { scope-id integer read-only } ;
 130
 131 <PRIVATE
 132
 133 ERROR: invalid-ipv6 host reason ;
 134
 135 M: invalid-ipv6 summary drop "Invalid IPv6 address" ;
 136
 137 : check-ipv6 ( host -- )
 138     [ parse-ipv6 drop ] [ invalid-ipv6 ] recover ;
 139
 140 PRIVATE>
 141
 142 : <ipv6> ( host -- ipv6 ) dup check-ipv6 0 ipv6 boa ;
 143
 144 M: ipv6 inet-ntop ( data addrspec -- str )
 145     drop 16 memory>byte-array 2 <groups> [ be> >hex ] map ":" join ;
 146
 147 <PRIVATE
 148
 149 : ipv6-bytes ( seq -- bytes )
 150     [ 2 >be ] { } map-as B{ } concat-as ;
 151
 152 PRIVATE>
 153
 154 M: ipv6 inet-pton ( str addrspec -- data )
 155     drop [ parse-ipv6 ipv6-bytes ] [ invalid-ipv6 ] recover ;
 156
 157 M: ipv6 address-size drop 16 ;
 158
 159 M: ipv6 protocol-family drop PF_INET6 ;
 160
 161 M: ipv6 sockaddr-size drop sockaddr-in6 heap-size ;
 162
 163 M: ipv6 empty-sockaddr drop sockaddr-in6 <struct> ;
 164
 165 M: ipv6 make-sockaddr ( inet -- sockaddr )
 166     sockaddr-in6 <struct>
 167         AF_INET6 >>family
 168         swap
 169         [ port>> htons >>port ]
 170         [ [ host>> "::" or ] keep inet-pton >>addr ]
 171         [ scope-id>> >>scopeid ]
 172         tri ;
 173
 174 M: ipv6 parse-sockaddr
 175     [ [ addr>> ] dip inet-ntop ] [ drop scopeid>> ] 2bi
 176     ipv6 boa ;
 177
 178 M: ipv6 present
 179     [ host>> ] [ scope-id>> ] bi
 180     [ number>string "%" glue ] unless-zero ;
 181
 182 TUPLE: inet6 < ipv6 { port integer read-only } ;
 183
 184 : <inet6> ( host port -- inet6 )
 185     [ dup check-ipv6 0 ] dip inet6 boa ;
 186
 187 M: ipv6 with-port
 188     [ [ host>> ] [ scope-id>> ] bi ] dip
 189     inet6 boa ;
 190
 191 M: inet6 parse-sockaddr
 192     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 193
 194 M: inet6 present
 195     [ call-next-method ] [ port>> number>string ] bi ":" glue ;
 196
 197 M: inet6 protocol drop 0 ;
 198
 199 ERROR: addrinfo-error n string ;
 200
 201 <PRIVATE
 202
 203 GENERIC: (get-local-address) ( handle remote -- sockaddr )
 204
 205 : get-local-address ( handle remote -- local )
 206     [ (get-local-address) ] keep parse-sockaddr ;
 207
 208 GENERIC: (get-remote-address) ( handle remote -- sockaddr )
 209
 210 : get-remote-address ( handle local -- remote )
 211     [ (get-remote-address) ] keep parse-sockaddr ;
 212
 213 : <ports> ( handle -- input-port output-port )
 214     [
 215         [ <input-port> |dispose ] [ <output-port> |dispose ] bi
 216     ] with-destructors ;
 217
 218 SYMBOL: bind-local-address
 219
 220 GENERIC: establish-connection ( client-out remote -- )
 221
 222 GENERIC: ((client)) ( remote -- handle )
 223
 224 GENERIC: (client) ( remote -- client-in client-out local )
 225
 226 M: array (client) [ (client) 3array ] attempt-all first3 ;
 227
 228 M: object (client) ( remote -- client-in client-out local )
 229     [
 230         [ ((client)) ] keep
 231         [
 232             [ <ports> [ |dispose ] bi@ dup ] dip
 233             establish-connection
 234         ]
 235         [ get-local-address ]
 236         2bi
 237     ] with-destructors ;
 238
 239 TUPLE: server-port < port addr encoding ;
 240
 241 GENERIC: (server) ( addrspec -- handle )
 242
 243 GENERIC: (accept) ( server addrspec -- handle sockaddr )
 244
 245 TUPLE: datagram-port < port addr ;
 246
 247 HOOK: (datagram) io-backend ( addr -- datagram )
 248
 249 TUPLE: raw-port < port addr ;
 250
 251 HOOK: (raw) io-backend ( addr -- raw )
 252
 253 HOOK: (broadcast) io-backend ( datagram -- datagram )
 254
 255 HOOK: (receive-unsafe) io-backend ( n buf datagram -- count addrspec )
 256
 257 ERROR: invalid-port object ;
 258
 259 : check-port ( bytes addrspec port -- bytes addrspec port )
 260     2dup addr>> [ class-of ] bi@ assert=
 261     pick class-of byte-array assert= ;
 262
 263 : check-connectionless-port ( port -- port )
 264     dup { [ datagram-port? ] [ raw-port? ] } 1|| [ invalid-port ] unless ;
 265
 266 : check-send ( bytes addrspec port -- bytes addrspec port )
 267     check-connectionless-port check-disposed check-port ;
 268
 269 : check-receive ( port -- port )
 270     check-connectionless-port check-disposed ;
 271
 272 HOOK: (send) io-backend ( bytes addrspec datagram -- )
 273
 274 : addrinfo>addrspec ( addrinfo -- addrspec )
 275     [ [ addr>> ] [ family>> ] bi sockaddr-of-family ]
 276     [ family>> addrspec-of-family ] bi
 277     parse-sockaddr ;
 278
 279 : parse-addrinfo-list ( addrinfo -- seq )
 280     [ next>> ] follow
 281     [ addrinfo>addrspec ] map
 282     sift ;
 283
 284 HOOK: addrinfo-error-string io-backend ( n -- string )
 285
 286 : prepare-addrinfo ( -- addrinfo )
 287     addrinfo <struct>
 288         PF_UNSPEC >>family
 289         IPPROTO_TCP >>protocol ;
 290
 291 PRIVATE>
 292
 293 : <client> ( remote encoding -- stream local )
 294     [ (client) ] dip swap [ <encoder-duplex> ] dip ;
 295
 296 SYMBOL: local-address
 297
 298 SYMBOL: remote-address
 299
 300 : with-client ( remote encoding quot -- )
 301     [
 302         [
 303             over remote-address set
 304             <client> local-address set
 305         ] dip with-stream
 306     ] with-scope ; inline
 307
 308 : <server> ( addrspec encoding -- server )
 309     [
 310         [ (server) ] keep
 311         [ drop server-port <port> ] [ get-local-address ] 2bi
 312         >>addr
 313     ] dip >>encoding ;
 314
 315 : accept ( server -- client remote )
 316     [
 317         dup addr>>
 318         [ (accept) ] keep
 319         parse-sockaddr swap
 320         <ports>
 321     ] [ encoding>> ] bi <encoder-duplex> swap ;
 322
 323 : <datagram> ( addrspec -- datagram )
 324     [
 325         [ (datagram) |dispose ] keep
 326         [ drop datagram-port <port> ] [ get-local-address ] 2bi
 327         >>addr
 328     ] with-destructors ;
 329
 330 : <raw> ( addrspec -- datagram )
 331     [
 332         [ (raw) |dispose ] keep
 333         [ drop raw-port <port> ] [ get-local-address ] 2bi
 334         >>addr
 335     ] with-destructors ;
 336
 337 : <broadcast> ( addrspec -- datagram )
 338     <datagram> (broadcast) ;
 339
 340 : receive-unsafe ( n buf datagram -- count addrspec )
 341     check-receive
 342     [ (receive-unsafe) ] [ addr>> ] bi parse-sockaddr ; inline
 343
 344 CONSTANT: datagram-size 65536
 345
 346 :: receive ( datagram -- bytes addrspec )
 347     datagram-size (byte-array) :> buf
 348     datagram-size buf datagram
 349     receive-unsafe :> ( count addrspec )
 350     count buf resize addrspec ; inline
 351
 352 :: receive-into ( buf datagram -- buf-slice addrspec )
 353     buf length :> n
 354     n buf datagram receive-unsafe :> ( count addrspec )
 355     buf count head-slice addrspec ; inline
 356
 357 : send ( bytes addrspec datagram -- )
 358     check-send (send) ; inline
 359
 360 : <random-local-datagram> ( -- datagram )
 361     <random-local-inet4> <datagram> ;
 362
 363 : <random-local-broadcast> ( -- datagram )
 364     <random-local-inet4> <broadcast> ;
 365
 366 : with-random-local-datagram ( quot -- )
 367     [ <random-local-datagram> ] dip with-disposal ; inline
 368
 369 : with-random-local-broadcast ( quot -- )
 370     [ <random-local-broadcast> ] dip with-disposal ; inline
 371
 372 : send-once ( bytes addrspec -- )
 373     [ send ] with-random-local-datagram ;
 374
 375 : broadcast-once ( bytes addrspec -- )
 376     [ send ] with-random-local-broadcast ;
 377
 378 MEMO: ipv6-supported? ( -- ? )
 379     [ "::1" 0 <inet6> binary <server> dispose t ] [ drop f ] recover ;
 380
 381 [ \ ipv6-supported? reset-memoized ]
 382 "io.sockets:ipv6-supported?" add-startup-hook
 383
 384 GENERIC: resolve-host ( addrspec -- seq )
 385
 386 HOOK: resolve-localhost os ( -- obj )
 387
 388 TUPLE: hostname { host maybe{ string } read-only } ;
 389
 390 TUPLE: inet < hostname port ;
 391
 392 M: inet present
 393     [ host>> ] [ port>> number>string ] bi ":" glue ;
 394
 395 C: <inet> inet
 396
 397 M: string resolve-host
 398     f prepare-addrinfo f void* <ref> [
 399         getaddrinfo [
 400             dup addrinfo-error-string addrinfo-error
 401         ] unless-zero
 402     ] keep void* deref addrinfo memory>struct
 403     [ parse-addrinfo-list ] keep freeaddrinfo ;
 404
 405 M: string with-port <inet> ;
 406
 407 M: hostname resolve-host
 408     host>> resolve-host ;
 409
 410 M: hostname with-port
 411     [ host>> ] dip <inet> ;
 412
 413 M: inet resolve-host
 414     [ call-next-method ] [ port>> ] bi '[ _ with-port ] map ;
 415
 416 M: inet4 resolve-host 1array ;
 417
 418 M: inet6 resolve-host 1array ;
 419
 420 M: local resolve-host 1array ;
 421
 422 M: f resolve-host
 423     drop resolve-localhost ;
 424
 425 M: object resolve-localhost
 426     ipv6-supported?
 427     { T{ ipv4 f "0.0.0.0" } T{ ipv6 f "::" } }
 428     { T{ ipv4 f "0.0.0.0" } }
 429     ? ;
 430
 431 HOOK: host-name os ( -- string )
 432
 433 M: inet (client) resolve-host (client) ;
 434
 435 ERROR: invalid-inet-server addrspec ;
 436
 437 M: invalid-inet-server summary
 438     drop "Cannot use <server> with <inet>; use <inet4> or <inet6> instead" ;
 439
 440 M: inet (server)
 441     invalid-inet-server ;
 442
 443 ERROR: invalid-local-address addrspec ;
 444
 445 M: invalid-local-address summary
 446     drop "Cannot use with-local-address with <inet>; use <inet4> or <inet6> instead" ;
 447
 448 : with-local-address ( addr quot -- )
 449     [
 450         [ ] [ inet4? ] [ inet6? ] tri or
 451         [ bind-local-address ]
 452         [ invalid-local-address ] if
 453     ] dip with-variable ; inline
 454
 455 : protocol-port ( protocol -- port )
 456     [ f getservbyname [ port>> htons ] [ f ] if* ] [ f ] if* ;
 457
 458 {
 459     { [ os unix? ] [ "io.sockets.unix" require ] }
 460     { [ os windows? ] [ "io.sockets.windows" require ] }
 461 } cond