basis/io/sockets/sockets.factor

   1 ! Copyright (C) 2007, 2008 Slava Pestov, Doug Coleman,
   2 ! Daniel Ehrenberg.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: generic kernel io.backend namespaces continuations sequences
   5 arrays io.encodings io.ports io.streams.duplex io.encodings.ascii
   6 alien.strings io.binary accessors destructors classes byte-arrays
   7 parser alien.c-types math.parser splitting grouping math assocs
   8 summary system vocabs.loader combinators present fry vocabs.parser
   9 classes.struct alien.data ;
  10 IN: io.sockets
  11
  12 << {
  13     { [ os windows? ] [ "windows.winsock" ] }
  14     { [ os unix? ] [ "unix.ffi" ] }
  15 } cond use-vocab >>
  16
  17 ! Addressing
  18 <PRIVATE
  19
  20 GENERIC: protocol-family ( addrspec -- af )
  21
  22 GENERIC: sockaddr-size ( addrspec -- n )
  23
  24 GENERIC: make-sockaddr ( addrspec -- sockaddr )
  25
  26 GENERIC: empty-sockaddr ( addrspec -- sockaddr )
  27
  28 GENERIC: address-size ( addrspec -- n )
  29
  30 GENERIC: inet-ntop ( data addrspec -- str )
  31
  32 GENERIC: inet-pton ( str addrspec -- data )
  33
  34 : make-sockaddr/size ( addrspec -- sockaddr size )
  35     [ make-sockaddr ] [ sockaddr-size ] bi ;
  36
  37 : empty-sockaddr/size ( addrspec -- sockaddr size )
  38     [ empty-sockaddr ] [ sockaddr-size ] bi ;
  39
  40 GENERIC: parse-sockaddr ( sockaddr addrspec -- newaddrspec )
  41
  42 HOOK: sockaddr-of-family os ( alien af -- sockaddr )
  43
  44 HOOK: addrspec-of-family os ( af -- addrspec )
  45
  46 PRIVATE>
  47
  48 TUPLE: abstract-inet host port ;
  49
  50 M: abstract-inet present
  51     [ host>> ":" ] [ port>> number>string ] bi 3append ;
  52
  53 TUPLE: local path ;
  54
  55 : <local> ( path -- addrspec )
  56     normalize-path local boa ;
  57
  58 M: local present path>> "Unix domain socket: " prepend ;
  59
  60 TUPLE: inet4 < abstract-inet ;
  61
  62 C: <inet4> inet4
  63
  64 M: inet4 inet-ntop ( data addrspec -- str )
  65     drop 4 memory>byte-array [ number>string ] { } map-as "." join ;
  66
  67 ERROR: malformed-inet4 sequence ;
  68 ERROR: bad-inet4-component string ;
  69
  70 : parse-inet4 ( string -- seq )
  71     "." split dup length 4 = [
  72         malformed-inet4
  73     ] unless
  74     [
  75         string>number
  76         [ "Dotted component not a number" throw ] unless*
  77     ] B{ } map-as ;
  78
  79 ERROR: invalid-inet4 string reason ;
  80
  81 M: invalid-inet4 summary drop "Invalid IPv4 address" ;
  82
  83 M: inet4 inet-pton ( str addrspec -- data )
  84     drop
  85     [ parse-inet4 ] [ invalid-inet4 ] recover ;
  86
  87 M: inet4 address-size drop 4 ;
  88
  89 M: inet4 protocol-family drop PF_INET ;
  90
  91 M: inet4 sockaddr-size drop sockaddr-in heap-size ;
  92
  93 M: inet4 empty-sockaddr drop sockaddr-in <struct> ;
  94
  95 M: inet4 make-sockaddr ( inet -- sockaddr )
  96     sockaddr-in <struct>
  97         AF_INET >>family
  98         swap [ port>> htons >>port ]
  99             [ host>> "0.0.0.0" or ]
 100             [ inet-pton *uint >>addr ] tri ;
 101
 102 M: inet4 parse-sockaddr ( sockaddr-in addrspec -- newaddrspec )
 103     [ [ addr>> <uint> ] dip inet-ntop ]
 104     [ drop port>> ntohs ] 2bi <inet4> ;
 105
 106 TUPLE: inet6 < abstract-inet ;
 107
 108 C: <inet6> inet6
 109
 110 M: inet6 inet-ntop ( data addrspec -- str )
 111     drop 16 memory>byte-array 2 <groups> [ be> >hex ] map ":" join ;
 112
 113 ERROR: invalid-inet6 string reason ;
 114
 115 M: invalid-inet6 summary drop "Invalid IPv6 address" ;
 116
 117 <PRIVATE
 118
 119 ERROR: bad-ipv6-component obj ;
 120
 121 ERROR: bad-ipv4-embedded-prefix obj ;
 122
 123 : ensure-zero-prefix ( seq -- seq )
 124     dup [ hex> ] map
 125     [ { f 0 } swap member? ] all? [ bad-ipv4-embedded-prefix ] unless ;
 126
 127 : parse-inet6 ( string -- seq )
 128     [ f ] [
 129         ":" split CHAR: . over last member? [
 130             unclip-last
 131             [ ensure-zero-prefix drop ] [ parse-inet4 ] bi*
 132         ] [
 133             [
 134                 dup hex> [ nip ] [ bad-ipv6-component ] if*
 135             ] { } map-as
 136         ] if
 137     ] if-empty ;
 138
 139 : pad-inet6 ( string1 string2 -- seq )
 140     2dup [ length ] bi@ + 8 swap -
 141     dup 0 < [ "More than 8 components" throw ] when
 142     <byte-array> glue ;
 143
 144 : inet6-bytes ( seq -- bytes )
 145     [ 2 >be ] { } map-as B{ } concat-as ;
 146
 147 PRIVATE>
 148
 149 M: inet6 inet-pton ( str addrspec -- data )
 150     drop
 151     [
 152         "::" split1 [ parse-inet6 ] bi@ pad-inet6 inet6-bytes
 153     ] [ invalid-inet6 ] recover ;
 154
 155 M: inet6 address-size drop 16 ;
 156
 157 M: inet6 protocol-family drop PF_INET6 ;
 158
 159 M: inet6 sockaddr-size drop sockaddr-in6 heap-size ;
 160
 161 M: inet6 empty-sockaddr drop sockaddr-in6 <struct> ;
 162
 163 M: inet6 make-sockaddr ( inet -- sockaddr )
 164     sockaddr-in6 <struct>
 165         AF_INET6 >>family
 166         swap [ port>> htons >>port ]
 167             [ host>> "::" or ]
 168             [ inet-pton >>addr ] tri ;
 169
 170 M: inet6 parse-sockaddr
 171     [ [ addr>> ] dip inet-ntop ]
 172     [ drop port>> ntohs ] 2bi <inet6> ;
 173
 174 M: f parse-sockaddr nip ;
 175
 176 <PRIVATE
 177
 178 GENERIC: (get-local-address) ( handle remote -- sockaddr )
 179
 180 : get-local-address ( handle remote -- local )
 181     [ (get-local-address) ] keep parse-sockaddr ;
 182
 183 GENERIC: (get-remote-address) ( handle remote -- sockaddr )
 184
 185 : get-remote-address ( handle local -- remote )
 186     [ (get-remote-address) ] keep parse-sockaddr ;
 187
 188 : <ports> ( handle -- input-port output-port )
 189     [
 190         [ <input-port> |dispose ] [ <output-port> |dispose ] bi
 191     ] with-destructors ;
 192
 193 SYMBOL: bind-local-address
 194
 195 GENERIC: establish-connection ( client-out remote -- )
 196
 197 GENERIC: ((client)) ( remote -- handle )
 198
 199 GENERIC: (client) ( remote -- client-in client-out local )
 200
 201 M: array (client) [ (client) 3array ] attempt-all first3 ;
 202
 203 M: object (client) ( remote -- client-in client-out local )
 204     [
 205         [ ((client)) ] keep
 206         [
 207             [ <ports> [ |dispose ] bi@ dup ] dip
 208             establish-connection
 209         ]
 210         [ get-local-address ]
 211         2bi
 212     ] with-destructors ;
 213
 214 TUPLE: server-port < port addr encoding ;
 215
 216 : check-server-port ( port -- port )
 217     dup check-disposed
 218     dup server-port? [ "Not a server port" throw ] unless ; inline
 219
 220 GENERIC: (server) ( addrspec -- handle )
 221
 222 GENERIC: (accept) ( server addrspec -- handle sockaddr )
 223
 224 TUPLE: datagram-port < port addr ;
 225
 226 HOOK: (datagram) io-backend ( addr -- datagram )
 227
 228 : check-datagram-port ( port -- port )
 229     dup check-disposed
 230     dup datagram-port? [ "Not a datagram port" throw ] unless ; inline
 231
 232 HOOK: (receive) io-backend ( datagram -- packet addrspec )
 233
 234 : check-datagram-send ( packet addrspec port -- packet addrspec port )
 235     check-datagram-port
 236     2dup addr>> [ class ] bi@ assert=
 237     pick class byte-array assert= ;
 238
 239 HOOK: (send) io-backend ( packet addrspec datagram -- )
 240
 241 : addrinfo>addrspec ( addrinfo -- addrspec )
 242     [ [ addr>> ] [ family>> ] bi sockaddr-of-family ]
 243     [ family>> addrspec-of-family ] bi
 244     parse-sockaddr ;
 245
 246 : parse-addrinfo-list ( addrinfo -- seq )
 247     [ next>> dup [ addrinfo memory>struct ] when ] follow
 248     [ addrinfo>addrspec ] map
 249     sift ;
 250
 251 HOOK: addrinfo-error io-backend ( n -- )
 252
 253 : resolve-passive-host ( -- addrspecs )
 254     { T{ inet6 f "::" f } T{ inet4 f "0.0.0.0" f } } [ clone ] map ;
 255
 256 : prepare-addrinfo ( -- addrinfo )
 257     addrinfo <struct>
 258         PF_UNSPEC >>family
 259         IPPROTO_TCP >>protocol ;
 260
 261 : fill-in-ports ( addrspecs port -- addrspecs )
 262     '[ _ >>port ] map ;
 263
 264 PRIVATE>
 265
 266 : <client> ( remote encoding -- stream local )
 267     [ (client) ] dip swap [ <encoder-duplex> ] dip ;
 268
 269 SYMBOL: local-address
 270
 271 SYMBOL: remote-address
 272
 273 : with-client ( remote encoding quot -- )
 274     [
 275         [
 276             over remote-address set
 277             <client> local-address set
 278         ] dip with-stream
 279     ] with-scope ; inline
 280
 281 : <server> ( addrspec encoding -- server )
 282     [
 283         [ (server) ] keep
 284         [ drop server-port <port> ] [ get-local-address ] 2bi
 285         >>addr
 286     ] dip >>encoding ;
 287
 288 : accept ( server -- client remote )
 289     [
 290         dup addr>>
 291         [ (accept) ] keep
 292         parse-sockaddr swap
 293         <ports>
 294     ] keep encoding>> <encoder-duplex> swap ;
 295
 296 : <datagram> ( addrspec -- datagram )
 297     [
 298         [ (datagram) |dispose ] keep
 299         [ drop datagram-port <port> ] [ get-local-address ] 2bi
 300         >>addr
 301     ] with-destructors ;
 302
 303 : receive ( datagram -- packet addrspec )
 304     check-datagram-port
 305     [ (receive) ] [ addr>> ] bi parse-sockaddr ;
 306
 307 : send ( packet addrspec datagram -- )
 308     check-datagram-send (send) ;
 309
 310 GENERIC: resolve-host ( addrspec -- seq )
 311
 312 TUPLE: inet < abstract-inet ;
 313
 314 C: <inet> inet
 315
 316 M: inet resolve-host
 317     [ port>> ] [ host>> ] bi [
 318         f prepare-addrinfo f <void*>
 319         [ getaddrinfo addrinfo-error ] keep *void* addrinfo memory>struct
 320         [ parse-addrinfo-list ] keep freeaddrinfo
 321     ] [ resolve-passive-host ] if*
 322     swap fill-in-ports ;
 323
 324 M: f resolve-host drop { } ;
 325
 326 M: object resolve-host 1array ;
 327
 328 : host-name ( -- string )
 329     256 <byte-array> dup dup length gethostname
 330     zero? [ "gethostname failed" throw ] unless
 331     ascii alien>string ;
 332
 333 M: inet (client) resolve-host (client) ;
 334
 335 ERROR: invalid-inet-server addrspec ;
 336
 337 M: invalid-inet-server summary
 338     drop "Cannot use <server> with <inet>; use <inet4> or <inet6> instead" ;
 339
 340 M: inet (server)
 341     invalid-inet-server ;
 342
 343 ERROR: invalid-local-address addrspec ;
 344
 345 M: invalid-local-address summary
 346     drop "Cannot use with-local-address with <inet>; use <inet4> or <inet6> instead" ;
 347
 348 : with-local-address ( addr quot -- )
 349     [
 350         [ ] [ inet4? ] [ inet6? ] tri or
 351         [ bind-local-address ]
 352         [ invalid-local-address ] if
 353     ] dip with-variable ; inline
 354
 355 {
 356     { [ os unix? ] [ "io.sockets.unix" require ] }
 357     { [ os winnt? ] [ "io.sockets.windows.nt" require ] }
 358 } cond