basis/io/sockets/unix/unix.factor

   1 ! Copyright (C) 2004, 2008 Slava Pestov, Ivan Tikhonov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: alien alien.c-types alien.strings generic kernel math
   4 threads sequences byte-arrays io.binary io.backend.unix
   5 io.streams.duplex io.backend io.pathnames io.sockets.private
   6 io.files.private io.encodings.utf8 math.parser continuations
   7 libc combinators system accessors destructors unix locals init
   8 classes.struct alien.data ;
   9
  10 EXCLUDE: namespaces => bind ;
  11 EXCLUDE: io => read write ;
  12 EXCLUDE: io.sockets => accept ;
  13
  14 IN: io.sockets.unix
  15
  16 : socket-fd ( domain type -- fd )
  17     0 socket dup io-error <fd> init-fd |dispose ;
  18
  19 : set-socket-option ( fd level opt -- )
  20     [ handle-fd ] 2dip 1 <int> "int" heap-size setsockopt io-error ;
  21
  22 M: unix addrinfo-error ( n -- )
  23     [ gai_strerror throw ] unless-zero ;
  24
  25 M: unix sockaddr-of-family ( alien af -- addrspec )
  26     {
  27         { AF_INET [ sockaddr-in memory>struct ] }
  28         { AF_INET6 [ sockaddr-in6 memory>struct ] }
  29         { AF_UNIX [ sockaddr-un memory>struct ] }
  30         [ 2drop f ]
  31     } case ;
  32
  33 M: unix addrspec-of-family ( af -- addrspec )
  34     {
  35         { AF_INET [ T{ inet4 } ] }
  36         { AF_INET6 [ T{ inet6 } ] }
  37         { AF_UNIX [ T{ local } ] }
  38         [ drop f ]
  39     } case ;
  40
  41 ! Client sockets - TCP and Unix domain
  42 M: object (get-local-address) ( handle remote -- sockaddr )
  43     [ handle-fd ] dip empty-sockaddr/size <int>
  44     [ getsockname io-error ] 2keep drop ;
  45
  46 M: object (get-remote-address) ( handle local -- sockaddr )
  47     [ handle-fd ] dip empty-sockaddr/size <int>
  48     [ getpeername io-error ] 2keep drop ;
  49
  50 : init-client-socket ( fd -- )
  51     SOL_SOCKET SO_OOBINLINE set-socket-option ;
  52
  53 : wait-to-connect ( port -- )
  54     dup handle>> handle-fd f 0 write
  55     {
  56         { [ 0 = ] [ drop ] }
  57         { [ errno EAGAIN = ] [ dup +output+ wait-for-port wait-to-connect ] }
  58         { [ errno EINTR = ] [ wait-to-connect ] }
  59         [ (io-error) ]
  60     } cond ;
  61
  62 M: object establish-connection ( client-out remote -- )
  63     [ drop ] [ [ handle>> handle-fd ] [ make-sockaddr/size ] bi* connect ] 2bi
  64     {
  65         { [ 0 = ] [ drop ] }
  66         { [ errno EINPROGRESS = ] [
  67             [ +output+ wait-for-port ] [ wait-to-connect ] bi
  68         ] }
  69         [ (io-error) ]
  70     } cond ;
  71
  72 M: object ((client)) ( addrspec -- fd )
  73     protocol-family SOCK_STREAM socket-fd dup init-client-socket ;
  74
  75 ! Server sockets - TCP and Unix domain
  76 : init-server-socket ( fd -- )
  77     SOL_SOCKET SO_REUSEADDR set-socket-option ;
  78
  79 : server-socket-fd ( addrspec type -- fd )
  80     [ dup protocol-family ] dip socket-fd
  81     [ init-server-socket ] keep
  82     [ handle-fd swap make-sockaddr/size bind io-error ] keep ;
  83
  84 M: object (server) ( addrspec -- handle )
  85     [
  86         SOCK_STREAM server-socket-fd
  87         dup handle-fd 128 listen io-error
  88     ] with-destructors ;
  89
  90 : do-accept ( server addrspec -- fd sockaddr )
  91     [ handle>> handle-fd ] [ empty-sockaddr/size <int> ] bi*
  92     [ accept ] 2keep drop ; inline
  93
  94 M: object (accept) ( server addrspec -- fd sockaddr )
  95     2dup do-accept
  96     {
  97         { [ over 0 >= ] [ [ 2nip <fd> init-fd ] dip ] }
  98         { [ errno EINTR = ] [ 2drop (accept) ] }
  99         { [ errno EAGAIN = ] [
 100             2drop
 101             [ drop +input+ wait-for-port ]
 102             [ (accept) ]
 103             2bi
 104         ] }
 105         [ (io-error) ]
 106     } cond ;
 107
 108 ! Datagram sockets - UDP and Unix domain
 109 M: unix (datagram)
 110     [ SOCK_DGRAM server-socket-fd ] with-destructors ;
 111
 112 SYMBOL: receive-buffer
 113
 114 CONSTANT: packet-size 65536
 115
 116 [ packet-size malloc &free receive-buffer set-global ] "io.sockets.unix" add-startup-hook
 117
 118 :: do-receive ( port -- packet sockaddr )
 119     port addr>> empty-sockaddr/size :> len :> sockaddr
 120     port handle>> handle-fd ! s
 121     receive-buffer get-global ! buf
 122     packet-size ! nbytes
 123     0 ! flags
 124     sockaddr ! from
 125     len <int> ! fromlen
 126     recvfrom dup 0 >=
 127     [ receive-buffer get-global swap memory>byte-array sockaddr ]
 128     [ drop f f ]
 129     if ;
 130
 131 M: unix (receive) ( datagram -- packet sockaddr )
 132     dup do-receive dup [ [ drop ] 2dip ] [
 133         2drop [ +input+ wait-for-port ] [ (receive) ] bi
 134     ] if ;
 135
 136 :: do-send ( packet sockaddr len socket datagram -- )
 137     socket handle-fd packet dup length 0 sockaddr len sendto
 138     0 < [
 139         errno EINTR = [
 140             packet sockaddr len socket datagram do-send
 141         ] [
 142             errno EAGAIN = [
 143                 datagram +output+ wait-for-port
 144                 packet sockaddr len socket datagram do-send
 145             ] [
 146                 (io-error)
 147             ] if
 148         ] if
 149     ] when ;
 150
 151 M: unix (send) ( packet addrspec datagram -- )
 152     [ make-sockaddr/size ] [ [ handle>> ] keep ] bi* do-send ;
 153
 154 ! Unix domain sockets
 155 M: local protocol-family drop PF_UNIX ;
 156
 157 M: local sockaddr-size drop sockaddr-un heap-size ;
 158
 159 M: local empty-sockaddr drop sockaddr-un <struct> ;
 160
 161 M: local make-sockaddr
 162     path>> (normalize-path)
 163     dup length 1 + max-un-path > [ "Path too long" throw ] when
 164     sockaddr-un <struct>
 165         AF_UNIX >>family
 166         swap utf8 string>alien >>path ;
 167
 168 M: local parse-sockaddr
 169     drop
 170     path>> utf8 alien>string <local> ;