basis/io/unix/multiplexers/kqueue/kqueue.factor

   1 ! Copyright (C) 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien.c-types combinators destructors
   4 io.unix.backend kernel math.bitwise sequences struct-arrays unix
   5 unix.kqueue unix.time assocs io.unix.multiplexers ;
   6 IN: io.unix.multiplexers.kqueue
   7
   8 TUPLE: kqueue-mx < mx events ;
   9
  10 : max-events ( -- n )
  11     #! We read up to 256 events at a time. This is an arbitrary
  12     #! constant...
  13     256 ; inline
  14
  15 : <kqueue-mx> ( -- mx )
  16     kqueue-mx new-mx
  17         kqueue dup io-error >>fd
  18         max-events "kevent" <struct-array> >>events ;
  19
  20 M: kqueue-mx dispose fd>> close-file ;
  21
  22 : make-kevent ( fd filter flags -- event )
  23     "kevent" <c-object>
  24     [ set-kevent-flags ] keep
  25     [ set-kevent-filter ] keep
  26     [ set-kevent-ident ] keep ;
  27
  28 : register-kevent ( kevent mx -- )
  29     fd>> swap 1 f 0 f kevent io-error ;
  30
  31 M: kqueue-mx add-input-callback ( thread fd mx -- )
  32     [ call-next-method ] [
  33         [ EVFILT_READ { EV_ADD EV_ONESHOT } flags make-kevent ] dip
  34         register-kevent
  35     ] 2bi ;
  36
  37 M: kqueue-mx add-output-callback ( thread fd mx -- )
  38     [ call-next-method ] [
  39         [ EVFILT_WRITE { EV_ADD EV_ONESHOT } flags make-kevent ] dip
  40         register-kevent
  41     ] 2bi ;
  42
  43 M: kqueue-mx remove-input-callbacks ( fd mx -- seq )
  44     2dup reads>> key? [
  45         [ call-next-method ] [
  46             [ EVFILT_READ EV_DELETE make-kevent ] dip
  47             register-kevent
  48         ] 2bi
  49     ] [ 2drop f ] if ;
  50
  51 M: kqueue-mx remove-output-callbacks ( fd mx -- seq )
  52     2dup writes>> key? [
  53         [
  54             [ EVFILT_WRITE EV_DELETE make-kevent ] dip
  55             register-kevent
  56         ] [ call-next-method ] 2bi
  57     ] [ 2drop f ] if ;
  58
  59 : wait-kevent ( mx timespec -- n )
  60     [
  61         [ fd>> f 0 ]
  62         [ events>> [ underlying>> ] [ length ] bi ] bi
  63     ] dip kevent multiplexer-error ;
  64
  65 : handle-kevent ( mx kevent -- )
  66     [ kevent-ident swap ] [ kevent-filter ] bi {
  67         { EVFILT_READ [ input-available ] }
  68         { EVFILT_WRITE [ output-available ] }
  69     } case ;
  70
  71 : handle-kevents ( mx n -- )
  72     [ dup events>> ] dip head-slice [ handle-kevent ] with each ;
  73
  74 M: kqueue-mx wait-for-events ( us mx -- )
  75     swap dup [ make-timespec ] when
  76     dupd wait-kevent handle-kevents ;