basis/json/writer/writer.factor

   1 ! Copyright (C) 2006 Chris Double.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel io.streams.string io strings splitting sequences math
   4        math.parser assocs classes words namespaces prettyprint
   5        hashtables mirrors tr ;
   6 IN: json.writer
   7
   8 #! Writes the object out to a stream in JSON format
   9 GENERIC: json-print ( obj -- )
  10
  11 : >json ( obj -- string )
  12   #! Returns a string representing the factor object in JSON format
  13   [ json-print ] with-string-writer ;
  14
  15 M: f json-print ( f -- )
  16   drop "false" write ;
  17
  18 M: string json-print ( obj -- )
  19   CHAR: " write1 "\"" split "\\\"" join CHAR: \r swap remove "\n" split "\\r\\n" join write CHAR: " write1 ;
  20
  21 M: number json-print ( num -- )
  22   number>string write ;
  23
  24 M: sequence json-print ( array -- )
  25   CHAR: [ write1 [ >json ] map "," join write CHAR: ] write1 ;
  26
  27 TR: jsvar-encode "-" "_" ;
  28
  29 : tuple>fields ( object -- seq )
  30   <mirror> [
  31     [ swap jsvar-encode >json % " : " % >json % ] "" make
  32   ] { } assoc>map ;
  33
  34 M: tuple json-print ( tuple -- )
  35   CHAR: { write1 tuple>fields "," join write CHAR: } write1 ;
  36
  37 M: hashtable json-print ( hashtable -- )
  38   CHAR: { write1
  39   [ [ swap jsvar-encode >json % CHAR: : , >json % ] "" make ]
  40   { } assoc>map "," join write
  41   CHAR: } write1 ;
  42
  43 M: object json-print ( object -- )
  44     unparse json-print ;