basis/libc/libc.factor

   1 ! Copyright (C) 2004, 2005 Mackenzie Straight
   2 ! Copyright (C) 2007, 2009 Slava Pestov
   3 ! Copyright (C) 2007, 2008 Doug Coleman
   4 ! See http://factorcode.org/license.txt for BSD license.
   5 USING: alien assocs continuations alien.destructors kernel
   6 namespaces accessors sets summary ;
   7 IN: libc
   8
   9 : errno ( -- int )
  10     "int" "factor" "err_no" { } alien-invoke ;
  11
  12 : clear-errno ( -- )
  13     "void" "factor" "clear_err_no" { } alien-invoke ;
  14
  15 <PRIVATE
  16
  17 : (malloc) ( size -- alien )
  18     "void*" "libc" "malloc" { "ulong" } alien-invoke ;
  19
  20 : (calloc) ( count size -- alien )
  21     "void*" "libc" "calloc" { "ulong" "ulong" } alien-invoke ;
  22
  23 : (free) ( alien -- )
  24     "void" "libc" "free" { "void*" } alien-invoke ;
  25
  26 : (realloc) ( alien size -- newalien )
  27     "void*" "libc" "realloc" { "void*" "ulong" } alien-invoke ;
  28
  29 : mallocs ( -- assoc )
  30     \ mallocs [ H{ } clone ] initialize-alien ;
  31
  32 PRIVATE>
  33
  34 ERROR: bad-ptr ;
  35
  36 M: bad-ptr summary
  37     drop "Memory allocation failed" ;
  38
  39 : check-ptr ( c-ptr -- c-ptr )
  40     [ bad-ptr ] unless* ;
  41
  42 ERROR: double-free ;
  43
  44 M: double-free summary
  45     drop "Free failed since memory is not allocated" ;
  46
  47 ERROR: realloc-error ptr size ;
  48
  49 M: realloc-error summary
  50     drop "Memory reallocation failed" ;
  51
  52 <PRIVATE
  53
  54 : add-malloc ( alien -- alien )
  55     dup mallocs conjoin ;
  56
  57 : delete-malloc ( alien -- )
  58     [
  59         mallocs delete-at*
  60         [ drop ] [ double-free ] if
  61     ] when* ;
  62
  63 : malloc-exists? ( alien -- ? )
  64     mallocs key? ;
  65
  66 PRIVATE>
  67
  68 : malloc ( size -- alien )
  69     (malloc) check-ptr add-malloc ;
  70
  71 : calloc ( count size -- alien )
  72     (calloc) check-ptr add-malloc ;
  73
  74 : realloc ( alien size -- newalien )
  75     [ >c-ptr ] dip
  76     over malloc-exists? [ realloc-error ] unless
  77     [ drop ] [ (realloc) check-ptr ] 2bi
  78     [ delete-malloc ] [ add-malloc ] bi* ;
  79
  80 : free ( alien -- )
  81     >c-ptr [ delete-malloc ] [ (free) ] bi ;
  82
  83 : memcpy ( dst src size -- )
  84     "void" "libc" "memcpy" { "void*" "void*" "ulong" } alien-invoke ;
  85
  86 : strlen ( alien -- len )
  87     "size_t" "libc" "strlen" { "char*" } alien-invoke ;
  88
  89 DESTRUCTOR: free