basis/libc/libc.factor

   1 ! Copyright (C) 2004, 2005 Mackenzie Straight
   2 ! Copyright (C) 2007, 2010 Slava Pestov
   3 ! Copyright (C) 2007, 2008 Doug Coleman
   4 ! See http://factorcode.org/license.txt for BSD license.
   5 USING: accessors alien alien.c-types alien.destructors
   6 alien.syntax destructors destructors.private kernel math
   7 namespaces prettyprint sequences sets summary system vocabs ;
   8 IN: libc
   9
  10 HOOK: strerror os ( errno -- str )
  11
  12 LIBRARY: factor
  13
  14 FUNCTION-ALIAS: errno
  15     int err_no ( ) ;
  16
  17 FUNCTION-ALIAS: set-errno
  18     void set_err_no ( int err-no ) ;
  19
  20 : clear-errno ( -- )
  21     0 set-errno ;
  22
  23 : preserve-errno ( quot -- )
  24     errno [ call ] dip set-errno ; inline
  25
  26 LIBRARY: libc
  27
  28 FUNCTION-ALIAS: (malloc)
  29     void* malloc ( size_t size ) ;
  30
  31 FUNCTION-ALIAS: (calloc)
  32     void* calloc ( size_t count,  size_t size ) ;
  33
  34 FUNCTION-ALIAS: (free)
  35     void free ( void* alien ) ;
  36
  37 FUNCTION-ALIAS: (realloc)
  38     void* realloc ( void* alien, size_t size ) ;
  39
  40 FUNCTION-ALIAS: strerror_unsafe
  41     char* strerror ( int errno ) ;
  42
  43 ! Add a default strerror even though it's not threadsafe
  44 M: object strerror strerror_unsafe ;
  45
  46 ERROR: libc-error errno message ;
  47
  48 : (io-error) ( -- * ) errno dup strerror libc-error ;
  49
  50 : io-error ( n -- ) 0 < [ (io-error) ] when ;
  51
  52 <PRIVATE
  53
  54 ! We stick malloc-ptr instances in the global disposables set
  55 TUPLE: malloc-ptr value continuation ;
  56
  57 M: malloc-ptr hashcode* value>> hashcode* ;
  58
  59 M: malloc-ptr equal?
  60     over malloc-ptr? [ [ value>> ] same? ] [ 2drop f ] if ;
  61
  62 : <malloc-ptr> ( value -- malloc-ptr )
  63     malloc-ptr new swap >>value ;
  64
  65 PRIVATE>
  66
  67 ERROR: bad-ptr ;
  68
  69 M: bad-ptr summary
  70     drop "Memory allocation failed" ;
  71
  72 : check-ptr ( c-ptr -- c-ptr )
  73     [ bad-ptr ] unless* ;
  74
  75 ERROR: realloc-error ptr size ;
  76
  77 M: realloc-error summary
  78     drop "Memory reallocation failed" ;
  79
  80 <PRIVATE
  81
  82 : add-malloc ( alien -- alien )
  83     dup <malloc-ptr> register-disposable ;
  84
  85 : delete-malloc ( alien -- )
  86     [ <malloc-ptr> unregister-disposable ] when* ;
  87
  88 : malloc-exists? ( alien -- ? )
  89     <malloc-ptr> disposables get in? ;
  90
  91 PRIVATE>
  92
  93 : malloc ( size -- alien )
  94     (malloc) check-ptr add-malloc ;
  95
  96 : calloc ( count size -- alien )
  97     (calloc) check-ptr add-malloc ;
  98
  99 : realloc ( alien size -- newalien )
 100     [ >c-ptr ] dip
 101     over malloc-exists? [ realloc-error ] unless
 102     [ drop ] [ (realloc) check-ptr ] 2bi
 103     [ delete-malloc ] [ add-malloc ] bi* ;
 104
 105 : free ( alien -- )
 106     >c-ptr [ delete-malloc ] [ (free) ] bi ;
 107
 108 FUNCTION: void memset ( void* buf, int char, size_t size ) ;
 109
 110 FUNCTION: void memcpy ( void* dst, void* src, ulong size ) ;
 111
 112 FUNCTION: int memcmp ( void* a, void* b, ulong size ) ;
 113
 114 : memory= ( a b size -- ? ) memcmp 0 = ; inline
 115
 116 FUNCTION: size_t strlen ( c-string alien ) ;
 117
 118 FUNCTION: int system ( c-string command ) ;
 119
 120 DESTRUCTOR: free
 121 DESTRUCTOR: (free)
 122
 123 ! For libc.linux, libc.windows, libc.macosx...
 124 << "libc." os unparse append require >>