basis/libc/libc.factor

   1 ! Copyright (C) 2004, 2005 Mackenzie Straight
   2 ! Copyright (C) 2007, 2010 Slava Pestov
   3 ! Copyright (C) 2007, 2008 Doug Coleman
   4 ! See http://factorcode.org/license.txt for BSD license.
   5 USING: accessors alien alien.c-types alien.destructors alien.syntax assocs
   6 combinators continuations destructors destructors.private kernel math
   7 namespaces prettyprint sequences sets summary system vocabs vocabs.parser ;
   8 IN: libc
   9
  10 << "libc." os unparse append require >>
  11
  12 LIBRARY: factor
  13
  14 FUNCTION-ALIAS: errno
  15     int err_no ( ) ;
  16
  17 FUNCTION-ALIAS: set-errno
  18     void set_err_no ( int err-no ) ;
  19
  20 : clear-errno ( -- )
  21     0 set-errno ;
  22
  23 : preserve-errno ( quot -- )
  24     errno [ call ] dip set-errno ; inline
  25
  26 LIBRARY: libc
  27
  28 FUNCTION-ALIAS: (malloc)
  29     void* malloc ( size_t size ) ;
  30
  31 FUNCTION-ALIAS: (calloc)
  32     void* calloc ( size_t count,  size_t size ) ;
  33
  34 FUNCTION-ALIAS: (free)
  35     void free ( void* alien ) ;
  36
  37 FUNCTION-ALIAS: (realloc)
  38     void* realloc ( void* alien, size_t size ) ;
  39
  40 HOOK: strerror os ( errno -- str )
  41
  42 FUNCTION: int strerror_r ( int errno, char* buf, size_t buflen ) ;
  43
  44 ERROR: libc-error errno message ;
  45
  46 : (io-error) ( -- * ) errno dup strerror libc-error ;
  47
  48 : io-error ( n -- ) 0 < [ (io-error) ] when ;
  49
  50 <PRIVATE
  51
  52 ! We stick malloc-ptr instances in the global disposables set
  53 TUPLE: malloc-ptr value continuation ;
  54
  55 M: malloc-ptr hashcode* value>> hashcode* ;
  56
  57 M: malloc-ptr equal?
  58     over malloc-ptr? [ [ value>> ] same? ] [ 2drop f ] if ;
  59
  60 : <malloc-ptr> ( value -- malloc-ptr )
  61     malloc-ptr new swap >>value ;
  62
  63 PRIVATE>
  64
  65 ERROR: bad-ptr ;
  66
  67 M: bad-ptr summary
  68     drop "Memory allocation failed" ;
  69
  70 : check-ptr ( c-ptr -- c-ptr )
  71     [ bad-ptr ] unless* ;
  72
  73 ERROR: realloc-error ptr size ;
  74
  75 M: realloc-error summary
  76     drop "Memory reallocation failed" ;
  77
  78 <PRIVATE
  79
  80 : add-malloc ( alien -- alien )
  81     dup <malloc-ptr> register-disposable ;
  82
  83 : delete-malloc ( alien -- )
  84     [ <malloc-ptr> unregister-disposable ] when* ;
  85
  86 : malloc-exists? ( alien -- ? )
  87     <malloc-ptr> disposables get in? ;
  88
  89 PRIVATE>
  90
  91 : malloc ( size -- alien )
  92     (malloc) check-ptr add-malloc ;
  93
  94 : calloc ( count size -- alien )
  95     (calloc) check-ptr add-malloc ;
  96
  97 : realloc ( alien size -- newalien )
  98     [ >c-ptr ] dip
  99     over malloc-exists? [ realloc-error ] unless
 100     [ drop ] [ (realloc) check-ptr ] 2bi
 101     [ delete-malloc ] [ add-malloc ] bi* ;
 102
 103 : free ( alien -- )
 104     >c-ptr [ delete-malloc ] [ (free) ] bi ;
 105
 106 FUNCTION: void memset ( void* buf, int char, size_t size ) ;
 107
 108 FUNCTION: void memcpy ( void* dst, void* src, ulong size ) ;
 109
 110 FUNCTION: int memcmp ( void* a, void* b, ulong size ) ;
 111
 112 : memory= ( a b size -- ? ) memcmp 0 = ; inline
 113
 114 FUNCTION: size_t strlen ( c-string alien ) ;
 115
 116 FUNCTION: int system ( c-string command ) ;
 117
 118 DESTRUCTOR: free
 119 DESTRUCTOR: (free)