basis/libc/libc.factor

   1 ! Copyright (C) 2004, 2005 Mackenzie Straight
   2 ! Copyright (C) 2007, 2010 Slava Pestov
   3 ! Copyright (C) 2007, 2008 Doug Coleman
   4 ! See http://factorcode.org/license.txt for BSD license.
   5 USING: accessors alien alien.c-types alien.destructors alien.syntax assocs
   6 combinators continuations destructors destructors.private kernel math
   7 namespaces prettyprint sequences sets summary system vocabs vocabs.parser ;
   8 IN: libc
   9
  10 << "libc." os unparse append use-vocab >>
  11
  12 LIBRARY: factor
  13
  14 FUNCTION-ALIAS: errno
  15     int err_no ( ) ;
  16
  17 FUNCTION-ALIAS: set-errno
  18     void set_err_no ( int err-no ) ;
  19
  20 : clear-errno ( -- )
  21     0 set-errno ;
  22
  23 : preserve-errno ( quot -- )
  24     errno [ call ] dip set-errno ; inline
  25
  26 LIBRARY: libc
  27
  28 FUNCTION: c-string strerror ( int errno ) ;
  29
  30 ERROR: libc-error errno message ;
  31
  32 : (io-error) ( -- * ) errno dup strerror libc-error ;
  33
  34 : io-error ( n -- ) 0 < [ (io-error) ] when ;
  35
  36 FUNCTION-ALIAS: (malloc)
  37     void* malloc ( size_t size ) ;
  38
  39 FUNCTION-ALIAS: (calloc)
  40     void* calloc ( size_t count,  size_t size ) ;
  41
  42 FUNCTION-ALIAS: (free)
  43     void free ( void* alien ) ;
  44
  45 FUNCTION-ALIAS: (realloc)
  46     void* realloc ( void* alien, size_t size ) ;
  47
  48 <PRIVATE
  49
  50 ! We stick malloc-ptr instances in the global disposables set
  51 TUPLE: malloc-ptr value continuation ;
  52
  53 M: malloc-ptr hashcode* value>> hashcode* ;
  54
  55 M: malloc-ptr equal?
  56     over malloc-ptr? [ [ value>> ] same? ] [ 2drop f ] if ;
  57
  58 : <malloc-ptr> ( value -- malloc-ptr )
  59     malloc-ptr new swap >>value ;
  60
  61 PRIVATE>
  62
  63 ERROR: bad-ptr ;
  64
  65 M: bad-ptr summary
  66     drop "Memory allocation failed" ;
  67
  68 : check-ptr ( c-ptr -- c-ptr )
  69     [ bad-ptr ] unless* ;
  70
  71 ERROR: realloc-error ptr size ;
  72
  73 M: realloc-error summary
  74     drop "Memory reallocation failed" ;
  75
  76 <PRIVATE
  77
  78 : add-malloc ( alien -- alien )
  79     dup <malloc-ptr> register-disposable ;
  80
  81 : delete-malloc ( alien -- )
  82     [ <malloc-ptr> unregister-disposable ] when* ;
  83
  84 : malloc-exists? ( alien -- ? )
  85     <malloc-ptr> disposables get in? ;
  86
  87 PRIVATE>
  88
  89 : malloc ( size -- alien )
  90     (malloc) check-ptr add-malloc ;
  91
  92 : calloc ( count size -- alien )
  93     (calloc) check-ptr add-malloc ;
  94
  95 : realloc ( alien size -- newalien )
  96     [ >c-ptr ] dip
  97     over malloc-exists? [ realloc-error ] unless
  98     [ drop ] [ (realloc) check-ptr ] 2bi
  99     [ delete-malloc ] [ add-malloc ] bi* ;
 100
 101 : free ( alien -- )
 102     >c-ptr [ delete-malloc ] [ (free) ] bi ;
 103
 104 FUNCTION: void memset ( void* buf, int char, size_t size ) ;
 105
 106 FUNCTION: void memcpy ( void* dst, void* src, ulong size ) ;
 107
 108 FUNCTION: int memcmp ( void* a, void* b, ulong size ) ;
 109
 110 : memory= ( a b size -- ? ) memcmp 0 = ; inline
 111
 112 FUNCTION: size_t strlen ( c-string alien ) ;
 113
 114 FUNCTION: int system ( c-string command ) ;
 115
 116 DESTRUCTOR: free
 117 DESTRUCTOR: (free)