basis/linked-sets/linked-sets.factor

   1 ! Copyright (C) 2016 John Benediktsson
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs deques dlists hashtables kernel sets ;
   4 IN: linked-sets
   5
   6 TUPLE: linked-set { assoc hashtable read-only } { dlist dlist read-only } ;
   7
   8 : <linked-set> ( capacity -- linked-set )
   9     <hashtable> <dlist> linked-set boa ;
  10
  11 M: linked-set in? assoc>> key? ;
  12
  13 M: linked-set clear-set
  14     [ assoc>> clear-assoc ] [ dlist>> clear-deque ] bi ;
  15
  16 <PRIVATE
  17
  18 : (delete-at) ( key assoc dlist -- )
  19     '[ at [ _ delete-node ] when* ] [ delete-at ] 2bi ; inline
  20
  21 PRIVATE>
  22
  23 M: linked-set delete
  24     [ assoc>> ] [ dlist>> ] bi (delete-at) ;
  25
  26 M: linked-set cardinality assoc>> assoc-size ;
  27
  28 M: linked-set adjoin
  29     [ assoc>> ] [ dlist>> ] bi
  30     '[ _ 2over key? [ 3dup (delete-at) ] when nip push-back* ]
  31     [ set-at ] 2bi ;
  32
  33 M: linked-set members
  34     dlist>> dlist>sequence ;
  35
  36 M: linked-set clone
  37     [ assoc>> clone ] [ dlist>> clone ] bi linked-set boa ;
  38
  39 M: linked-set equal?
  40     over linked-set? [ [ dlist>> ] bi@ = ] [ 2drop f ] if ;
  41
  42 : >linked-set ( set -- linked-set )
  43     [ 0 <linked-set> ] dip union! ;
  44
  45 INSTANCE: linked-set set
  46
  47 M: linked-set set-like
  48     drop dup linked-set? [ >linked-set ] unless ;