basis/lists/lazy/lazy.factor

   1 ! Copyright (C) 2004, 2008 Chris Double, Matthew Willis, James Cash.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel sequences math vectors arrays namespaces make
   4 quotations promises combinators io lists accessors ;
   5 IN: lists.lazy
   6
   7 M: promise car ( promise -- car )
   8     force car ;
   9
  10 M: promise cdr ( promise -- cdr )
  11     force cdr ;
  12
  13 M: promise nil? ( cons -- bool )
  14     force nil? ;
  15
  16 ! Both 'car' and 'cdr' are promises
  17 TUPLE: lazy-cons car cdr ;
  18
  19 : lazy-cons ( car cdr -- promise )
  20     [ promise ] bi@ \ lazy-cons boa
  21     T{ promise f f t f } clone
  22         swap >>value ;
  23
  24 M: lazy-cons car ( lazy-cons -- car )
  25     car>> force ;
  26
  27 M: lazy-cons cdr ( lazy-cons -- cdr )
  28     cdr>> force ;
  29
  30 M: lazy-cons nil? ( lazy-cons -- bool )
  31     nil eq? ;
  32
  33 : 1lazy-list ( a -- lazy-cons )
  34     [ nil ] lazy-cons ;
  35
  36 : 2lazy-list ( a b -- lazy-cons )
  37     1lazy-list 1quotation lazy-cons ;
  38
  39 : 3lazy-list ( a b c -- lazy-cons )
  40     2lazy-list 1quotation lazy-cons ;
  41
  42 TUPLE: memoized-cons original car cdr nil? ;
  43
  44 : not-memoized ( -- obj )
  45     { } ;
  46
  47 : not-memoized? ( obj -- bool )
  48     not-memoized eq? ;
  49
  50 : <memoized-cons> ( cons -- memoized-cons )
  51     not-memoized not-memoized not-memoized
  52     memoized-cons boa ;
  53
  54 M: memoized-cons car ( memoized-cons -- car )
  55     dup car>> not-memoized? [
  56         dup original>> car [ >>car drop ] keep
  57     ] [
  58         car>>
  59     ] if ;
  60
  61 M: memoized-cons cdr ( memoized-cons -- cdr )
  62     dup cdr>> not-memoized? [
  63         dup original>> cdr [ >>cdr drop ] keep
  64     ] [
  65         cdr>>
  66     ] if ;
  67
  68 M: memoized-cons nil? ( memoized-cons -- bool )
  69     dup nil?>> not-memoized? [
  70         dup original>> nil?  [ >>nil? drop ] keep
  71     ] [
  72         nil?>>
  73     ] if ;
  74
  75 TUPLE: lazy-map cons quot ;
  76
  77 C: <lazy-map> lazy-map
  78
  79 : lazy-map ( list quot -- result )
  80     over nil? [ 2drop nil ] [ <lazy-map> <memoized-cons> ] if ;
  81
  82 M: lazy-map car ( lazy-map -- car )
  83     [ cons>> car ] keep
  84     quot>> call( old -- new ) ;
  85
  86 M: lazy-map cdr ( lazy-map -- cdr )
  87     [ cons>> cdr ] keep
  88     quot>> lazy-map ;
  89
  90 M: lazy-map nil? ( lazy-map -- bool )
  91     cons>> nil? ;
  92
  93 TUPLE: lazy-take n cons ;
  94
  95 C: <lazy-take> lazy-take
  96
  97 : ltake ( n list -- result )
  98         over zero? [ 2drop nil ] [ <lazy-take> ] if ;
  99
 100 M: lazy-take car ( lazy-take -- car )
 101     cons>> car ;
 102
 103 M: lazy-take cdr ( lazy-take -- cdr )
 104     [ n>> 1- ] keep
 105     cons>> cdr ltake ;
 106
 107 M: lazy-take nil? ( lazy-take -- bool )
 108     dup n>> zero? [
 109         drop t
 110     ] [
 111         cons>> nil?
 112     ] if ;
 113
 114 TUPLE: lazy-until cons quot ;
 115
 116 C: <lazy-until> lazy-until
 117
 118 : luntil ( list quot -- result )
 119     over nil? [ drop ] [ <lazy-until> ] if ;
 120
 121 M: lazy-until car ( lazy-until -- car )
 122      cons>> car ;
 123
 124 M: lazy-until cdr ( lazy-until -- cdr )
 125      [ cons>> unswons ] keep quot>> tuck call( elt -- ? )
 126      [ 2drop nil ] [ luntil ] if ;
 127
 128 M: lazy-until nil? ( lazy-until -- bool )
 129      drop f ;
 130
 131 TUPLE: lazy-while cons quot ;
 132
 133 C: <lazy-while> lazy-while
 134
 135 : lwhile ( list quot -- result )
 136     over nil? [ drop ] [ <lazy-while> ] if ;
 137
 138 M: lazy-while car ( lazy-while -- car )
 139      cons>> car ;
 140
 141 M: lazy-while cdr ( lazy-while -- cdr )
 142      [ cons>> cdr ] keep quot>> lwhile ;
 143
 144 M: lazy-while nil? ( lazy-while -- bool )
 145      [ car ] keep quot>> call( elt -- ? ) not ;
 146
 147 TUPLE: lazy-filter cons quot ;
 148
 149 C: <lazy-filter> lazy-filter
 150
 151 : lfilter ( list quot -- result )
 152     over nil? [ 2drop nil ] [ <lazy-filter> <memoized-cons> ] if ;
 153
 154 : car-filter? ( lazy-filter -- ? )
 155     [ cons>> car ] [ quot>> ] bi call( elt -- ? ) ;
 156
 157 : skip ( lazy-filter -- )
 158     dup cons>> cdr >>cons drop ;
 159
 160 M: lazy-filter car ( lazy-filter -- car )
 161     dup car-filter? [ cons>> ] [ dup skip ] if car ;
 162
 163 M: lazy-filter cdr ( lazy-filter -- cdr )
 164     dup car-filter? [
 165         [ cons>> cdr ] [ quot>> ] bi lfilter
 166     ] [
 167         dup skip cdr
 168     ] if ;
 169
 170 M: lazy-filter nil? ( lazy-filter -- bool )
 171     dup cons>> nil? [
 172         drop t
 173     ] [
 174         dup car-filter? [
 175             drop f
 176         ] [
 177             dup skip nil?
 178         ] if
 179     ] if ;
 180
 181 : list>vector ( list -- vector )
 182     [ [ , ] leach ] V{ } make ;
 183
 184 : list>array ( list -- array )
 185     [ [ , ] leach ] { } make ;
 186
 187 TUPLE: lazy-append list1 list2 ;
 188
 189 C: <lazy-append> lazy-append
 190
 191 : lappend ( list1 list2 -- result )
 192     over nil? [ nip ] [ <lazy-append> ] if ;
 193
 194 M: lazy-append car ( lazy-append -- car )
 195     list1>> car ;
 196
 197 M: lazy-append cdr ( lazy-append -- cdr )
 198     [ list1>> cdr    ] keep
 199     list2>> lappend ;
 200
 201 M: lazy-append nil? ( lazy-append -- bool )
 202      drop f ;
 203
 204 TUPLE: lazy-from-by n quot ;
 205
 206 C: lfrom-by lazy-from-by ( n quot -- list )
 207
 208 : lfrom ( n -- list )
 209     [ 1+ ] lfrom-by ;
 210
 211 M: lazy-from-by car ( lazy-from-by -- car )
 212     n>> ;
 213
 214 M: lazy-from-by cdr ( lazy-from-by -- cdr )
 215     [ n>> ] keep
 216     quot>> [ call( old -- new ) ] keep lfrom-by ;
 217
 218 M: lazy-from-by nil? ( lazy-from-by -- bool )
 219     drop f ;
 220
 221 TUPLE: lazy-zip list1 list2 ;
 222
 223 C: <lazy-zip> lazy-zip
 224
 225 : lzip ( list1 list2 -- lazy-zip )
 226         over nil? over nil? or
 227         [ 2drop nil ] [ <lazy-zip> ] if ;
 228
 229 M: lazy-zip car ( lazy-zip -- car )
 230         [ list1>> car ] keep list2>> car 2array ;
 231
 232 M: lazy-zip cdr ( lazy-zip -- cdr )
 233         [ list1>> cdr ] keep list2>> cdr lzip ;
 234
 235 M: lazy-zip nil? ( lazy-zip -- bool )
 236         drop f ;
 237
 238 TUPLE: sequence-cons index seq ;
 239
 240 C: <sequence-cons> sequence-cons
 241
 242 : seq>list ( index seq -- list )
 243     2dup length >= [
 244         2drop nil
 245     ] [
 246         <sequence-cons>
 247     ] if ;
 248
 249 M: sequence-cons car ( sequence-cons -- car )
 250     [ index>> ] keep
 251     seq>> nth ;
 252
 253 M: sequence-cons cdr ( sequence-cons -- cdr )
 254     [ index>> 1+ ] keep
 255     seq>> seq>list ;
 256
 257 M: sequence-cons nil? ( sequence-cons -- bool )
 258     drop f ;
 259
 260 : >list ( object -- list )
 261     {
 262         { [ dup sequence? ] [ 0 swap seq>list ] }
 263         { [ dup list?         ] [ ] }
 264         [ "Could not convert object to a list" throw ]
 265     } cond ;
 266
 267 TUPLE: lazy-concat car cdr ;
 268
 269 C: <lazy-concat> lazy-concat
 270
 271 DEFER: lconcat
 272
 273 : (lconcat) ( car cdr -- list )
 274     over nil? [
 275         nip lconcat
 276     ] [
 277         <lazy-concat>
 278     ] if ;
 279
 280 : lconcat ( list -- result )
 281     dup nil? [
 282         drop nil
 283     ] [
 284         uncons (lconcat)
 285     ] if ;
 286
 287 M: lazy-concat car ( lazy-concat -- car )
 288     car>> car ;
 289
 290 M: lazy-concat cdr ( lazy-concat -- cdr )
 291     [ car>> cdr ] keep cdr>> (lconcat) ;
 292
 293 M: lazy-concat nil? ( lazy-concat -- bool )
 294     dup car>> nil? [
 295         cdr>> nil?
 296     ] [
 297         drop f
 298     ] if ;
 299
 300 : lcartesian-product ( list1 list2 -- result )
 301     swap [ swap [ 2array ] with lazy-map  ] with lazy-map  lconcat ;
 302
 303 : lcartesian-product* ( lists -- result )
 304     dup nil? [
 305         drop nil
 306     ] [
 307         [ car ] keep cdr [ car lcartesian-product ] keep cdr list>array swap [
 308             swap [ swap [ suffix ] with lazy-map  ] with lazy-map  lconcat
 309         ] reduce
 310     ] if ;
 311
 312 : lcomp ( list quot -- result )
 313     [ lcartesian-product* ] dip lazy-map ;
 314
 315 : lcomp* ( list guards quot -- result )
 316     [ [ lcartesian-product* ] dip [ lfilter ] each ] dip lazy-map ;
 317
 318 DEFER: lmerge
 319
 320 : (lmerge) ( list1 list2 -- result )
 321     over [ car ] curry -rot
 322     [
 323         dup [ car ] curry -rot
 324         [
 325             [ cdr ] bi@ lmerge
 326         ] 2curry lazy-cons
 327     ] 2curry lazy-cons ;
 328
 329 : lmerge ( list1 list2 -- result )
 330     {
 331         { [ over nil? ] [ nip     ] }
 332         { [ dup nil?    ]    [ drop ] }
 333         { [ t                 ]    [ (lmerge) ] }
 334     } cond ;
 335
 336 TUPLE: lazy-io stream car cdr quot ;
 337
 338 C: <lazy-io> lazy-io
 339
 340 : lcontents ( stream -- result )
 341     f f [ stream-read1 ] <lazy-io> ;
 342
 343 : llines ( stream -- result )
 344     f f [ stream-readln ] <lazy-io> ;
 345
 346 M: lazy-io car ( lazy-io -- car )
 347     dup car>> dup [
 348         nip
 349     ] [
 350         drop dup stream>> over quot>>
 351         call( stream -- value )
 352         >>car
 353     ] if ;
 354
 355 M: lazy-io cdr ( lazy-io -- cdr )
 356     dup cdr>> dup [
 357         nip
 358     ] [
 359         drop dup
 360         [ stream>> ] keep
 361         [ quot>> ] keep
 362         car [
 363             [ f f ] dip <lazy-io> [ >>cdr drop ] keep
 364         ] [
 365             3drop nil
 366         ] if
 367     ] if ;
 368
 369 M: lazy-io nil? ( lazy-io -- bool )
 370     car not ;
 371
 372 INSTANCE: sequence-cons list
 373 INSTANCE: memoized-cons list
 374 INSTANCE: promise list
 375 INSTANCE: lazy-io list
 376 INSTANCE: lazy-concat list
 377 INSTANCE: lazy-cons list
 378 INSTANCE: lazy-map list
 379 INSTANCE: lazy-take list
 380 INSTANCE: lazy-append list
 381 INSTANCE: lazy-from-by list
 382 INSTANCE: lazy-zip list
 383 INSTANCE: lazy-while list
 384 INSTANCE: lazy-until list
 385 INSTANCE: lazy-filter list