basis/lists/lazy/lazy.factor

   1 ! Copyright (C) 2004, 2008 Chris Double, Matthew Willis, James Cash.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel sequences math vectors arrays namespaces make
   4 quotations promises combinators io lists accessors ;
   5 IN: lists.lazy
   6
   7 M: promise car ( promise -- car )
   8     force car ;
   9
  10 M: promise cdr ( promise -- cdr )
  11     force cdr ;
  12
  13 M: promise nil? ( cons -- bool )
  14     force nil? ;
  15
  16 ! Both 'car' and 'cdr' are promises
  17 TUPLE: lazy-cons car cdr ;
  18
  19 : lazy-cons ( car cdr -- promise )
  20     [ promise ] bi@ \ lazy-cons boa
  21     T{ promise f f t f } clone
  22         swap >>value ;
  23
  24 M: lazy-cons car ( lazy-cons -- car )
  25     car>> force ;
  26
  27 M: lazy-cons cdr ( lazy-cons -- cdr )
  28     cdr>> force ;
  29
  30 M: lazy-cons nil? ( lazy-cons -- bool )
  31     nil eq? ;
  32
  33 : 1lazy-list ( a -- lazy-cons )
  34     [ nil ] lazy-cons ;
  35
  36 : 2lazy-list ( a b -- lazy-cons )
  37     1lazy-list 1quotation lazy-cons ;
  38
  39 : 3lazy-list ( a b c -- lazy-cons )
  40     2lazy-list 1quotation lazy-cons ;
  41
  42 TUPLE: memoized-cons original car cdr nil? ;
  43
  44 : not-memoized ( -- obj )
  45     { } ;
  46
  47 : not-memoized? ( obj -- bool )
  48     not-memoized eq? ;
  49
  50 : <memoized-cons> ( cons -- memoized-cons )
  51     not-memoized not-memoized not-memoized
  52     memoized-cons boa ;
  53
  54 M: memoized-cons car ( memoized-cons -- car )
  55     dup car>> not-memoized? [
  56         dup original>> car [ >>car drop ] keep
  57     ] [
  58         car>>
  59     ] if ;
  60
  61 M: memoized-cons cdr ( memoized-cons -- cdr )
  62     dup cdr>> not-memoized? [
  63         dup original>> cdr [ >>cdr drop ] keep
  64     ] [
  65         cdr>>
  66     ] if ;
  67
  68 M: memoized-cons nil? ( memoized-cons -- bool )
  69     dup nil?>> not-memoized? [
  70         dup original>> nil?  [ >>nil? drop ] keep
  71     ] [
  72         nil?>>
  73     ] if ;
  74
  75 TUPLE: lazy-map cons quot ;
  76
  77 C: <lazy-map> lazy-map
  78
  79 : lazy-map ( list quot -- result )
  80     over nil? [ 2drop nil ] [ <lazy-map> <memoized-cons> ] if ;
  81
  82 M: lazy-map car ( lazy-map -- car )
  83     [ cons>> car ] keep
  84     quot>> call( old -- new ) ;
  85
  86 M: lazy-map cdr ( lazy-map -- cdr )
  87     [ cons>> cdr ] keep
  88     quot>> lazy-map ;
  89
  90 M: lazy-map nil? ( lazy-map -- bool )
  91     cons>> nil? ;
  92
  93 TUPLE: lazy-take n cons ;
  94
  95 C: <lazy-take> lazy-take
  96
  97 : ltake ( n list -- result )
  98         over zero? [ 2drop nil ] [ <lazy-take> ] if ;
  99
 100 M: lazy-take car ( lazy-take -- car )
 101     cons>> car ;
 102
 103 M: lazy-take cdr ( lazy-take -- cdr )
 104     [ n>> 1- ] keep
 105     cons>> cdr ltake ;
 106
 107 M: lazy-take nil? ( lazy-take -- bool )
 108     dup n>> zero? [
 109         drop t
 110     ] [
 111         cons>> nil?
 112     ] if ;
 113
 114 TUPLE: lazy-until cons quot ;
 115
 116 C: <lazy-until> lazy-until
 117
 118 : luntil ( list quot -- result )
 119     over nil? [ drop ] [ <lazy-until> ] if ;
 120
 121 M: lazy-until car ( lazy-until -- car )
 122      cons>> car ;
 123
 124 M: lazy-until cdr ( lazy-until -- cdr )
 125      [ cons>> unswons ] keep quot>> tuck call( elt -- ? )
 126      [ 2drop nil ] [ luntil ] if ;
 127
 128 M: lazy-until nil? ( lazy-until -- bool )
 129      drop f ;
 130
 131 TUPLE: lazy-while cons quot ;
 132
 133 C: <lazy-while> lazy-while
 134
 135 : lwhile ( list quot -- result )
 136     over nil? [ drop ] [ <lazy-while> ] if ;
 137
 138 M: lazy-while car ( lazy-while -- car )
 139      cons>> car ;
 140
 141 M: lazy-while cdr ( lazy-while -- cdr )
 142      [ cons>> cdr ] keep quot>> lwhile ;
 143
 144 M: lazy-while nil? ( lazy-while -- bool )
 145      [ car ] keep quot>> call( elt -- ? ) not ;
 146
 147 TUPLE: lazy-filter cons quot ;
 148
 149 C: <lazy-filter> lazy-filter
 150
 151 : lfilter ( list quot -- result )
 152     over nil? [ 2drop nil ] [ <lazy-filter> <memoized-cons> ] if ;
 153
 154 : car-filter? ( lazy-filter -- ? )
 155     [ cons>> car ] [ quot>> ] bi call( elt -- ? ) ;
 156
 157 : skip ( lazy-filter -- )
 158     dup cons>> cdr >>cons drop ;
 159
 160 M: lazy-filter car ( lazy-filter -- car )
 161     dup car-filter? [ cons>> ] [ dup skip ] if car ;
 162
 163 M: lazy-filter cdr ( lazy-filter -- cdr )
 164     dup car-filter? [
 165         [ cons>> cdr ] [ quot>> ] bi lfilter
 166     ] [
 167         dup skip cdr
 168     ] if ;
 169
 170 M: lazy-filter nil? ( lazy-filter -- bool )
 171     dup cons>> nil? [
 172         drop t
 173     ] [
 174         dup car-filter? [
 175             drop f
 176         ] [
 177             dup skip nil?
 178         ] if
 179     ] if ;
 180
 181 TUPLE: lazy-append list1 list2 ;
 182
 183 C: <lazy-append> lazy-append
 184
 185 : lappend ( list1 list2 -- result )
 186     over nil? [ nip ] [ <lazy-append> ] if ;
 187
 188 M: lazy-append car ( lazy-append -- car )
 189     list1>> car ;
 190
 191 M: lazy-append cdr ( lazy-append -- cdr )
 192     [ list1>> cdr    ] keep
 193     list2>> lappend ;
 194
 195 M: lazy-append nil? ( lazy-append -- bool )
 196      drop f ;
 197
 198 TUPLE: lazy-from-by n quot ;
 199
 200 C: lfrom-by lazy-from-by
 201
 202 : lfrom ( n -- list )
 203     [ 1+ ] lfrom-by ;
 204
 205 M: lazy-from-by car ( lazy-from-by -- car )
 206     n>> ;
 207
 208 M: lazy-from-by cdr ( lazy-from-by -- cdr )
 209     [ n>> ] keep
 210     quot>> [ call( old -- new ) ] keep lfrom-by ;
 211
 212 M: lazy-from-by nil? ( lazy-from-by -- bool )
 213     drop f ;
 214
 215 TUPLE: lazy-zip list1 list2 ;
 216
 217 C: <lazy-zip> lazy-zip
 218
 219 : lzip ( list1 list2 -- lazy-zip )
 220         over nil? over nil? or
 221         [ 2drop nil ] [ <lazy-zip> ] if ;
 222
 223 M: lazy-zip car ( lazy-zip -- car )
 224         [ list1>> car ] keep list2>> car 2array ;
 225
 226 M: lazy-zip cdr ( lazy-zip -- cdr )
 227         [ list1>> cdr ] keep list2>> cdr lzip ;
 228
 229 M: lazy-zip nil? ( lazy-zip -- bool )
 230         drop f ;
 231
 232 TUPLE: sequence-cons index seq ;
 233
 234 C: <sequence-cons> sequence-cons
 235
 236 : seq>list ( index seq -- list )
 237     2dup length >= [
 238         2drop nil
 239     ] [
 240         <sequence-cons>
 241     ] if ;
 242
 243 M: sequence-cons car ( sequence-cons -- car )
 244     [ index>> ] keep
 245     seq>> nth ;
 246
 247 M: sequence-cons cdr ( sequence-cons -- cdr )
 248     [ index>> 1+ ] keep
 249     seq>> seq>list ;
 250
 251 M: sequence-cons nil? ( sequence-cons -- bool )
 252     drop f ;
 253
 254 : >list ( object -- list )
 255     {
 256         { [ dup sequence? ] [ 0 swap seq>list ] }
 257         { [ dup list?         ] [ ] }
 258         [ "Could not convert object to a list" throw ]
 259     } cond ;
 260
 261 TUPLE: lazy-concat car cdr ;
 262
 263 C: <lazy-concat> lazy-concat
 264
 265 DEFER: lconcat
 266
 267 : (lconcat) ( car cdr -- list )
 268     over nil? [
 269         nip lconcat
 270     ] [
 271         <lazy-concat>
 272     ] if ;
 273
 274 : lconcat ( list -- result )
 275     dup nil? [
 276         drop nil
 277     ] [
 278         uncons (lconcat)
 279     ] if ;
 280
 281 M: lazy-concat car ( lazy-concat -- car )
 282     car>> car ;
 283
 284 M: lazy-concat cdr ( lazy-concat -- cdr )
 285     [ car>> cdr ] keep cdr>> (lconcat) ;
 286
 287 M: lazy-concat nil? ( lazy-concat -- bool )
 288     dup car>> nil? [
 289         cdr>> nil?
 290     ] [
 291         drop f
 292     ] if ;
 293
 294 : lcartesian-product ( list1 list2 -- result )
 295     swap [ swap [ 2array ] with lazy-map  ] with lazy-map  lconcat ;
 296
 297 : lcartesian-product* ( lists -- result )
 298     dup nil? [
 299         drop nil
 300     ] [
 301         [ car ] keep cdr [ car lcartesian-product ] keep cdr list>array swap [
 302             swap [ swap [ suffix ] with lazy-map  ] with lazy-map  lconcat
 303         ] reduce
 304     ] if ;
 305
 306 : lcomp ( list quot -- result )
 307     [ lcartesian-product* ] dip lazy-map ;
 308
 309 : lcomp* ( list guards quot -- result )
 310     [ [ lcartesian-product* ] dip [ lfilter ] each ] dip lazy-map ;
 311
 312 DEFER: lmerge
 313
 314 : (lmerge) ( list1 list2 -- result )
 315     over [ car ] curry -rot
 316     [
 317         dup [ car ] curry -rot
 318         [
 319             [ cdr ] bi@ lmerge
 320         ] 2curry lazy-cons
 321     ] 2curry lazy-cons ;
 322
 323 : lmerge ( list1 list2 -- result )
 324     {
 325         { [ over nil? ] [ nip     ] }
 326         { [ dup nil?    ]    [ drop ] }
 327         { [ t                 ]    [ (lmerge) ] }
 328     } cond ;
 329
 330 TUPLE: lazy-io stream car cdr quot ;
 331
 332 C: <lazy-io> lazy-io
 333
 334 : lcontents ( stream -- result )
 335     f f [ stream-read1 ] <lazy-io> ;
 336
 337 : llines ( stream -- result )
 338     f f [ stream-readln ] <lazy-io> ;
 339
 340 M: lazy-io car ( lazy-io -- car )
 341     dup car>> dup [
 342         nip
 343     ] [
 344         drop dup stream>> over quot>>
 345         call( stream -- value )
 346         >>car
 347     ] if ;
 348
 349 M: lazy-io cdr ( lazy-io -- cdr )
 350     dup cdr>> dup [
 351         nip
 352     ] [
 353         drop dup
 354         [ stream>> ] keep
 355         [ quot>> ] keep
 356         car [
 357             [ f f ] dip <lazy-io> [ >>cdr drop ] keep
 358         ] [
 359             3drop nil
 360         ] if
 361     ] if ;
 362
 363 M: lazy-io nil? ( lazy-io -- bool )
 364     car not ;
 365
 366 INSTANCE: sequence-cons list
 367 INSTANCE: memoized-cons list
 368 INSTANCE: promise list
 369 INSTANCE: lazy-io list
 370 INSTANCE: lazy-concat list
 371 INSTANCE: lazy-cons list
 372 INSTANCE: lazy-map list
 373 INSTANCE: lazy-take list
 374 INSTANCE: lazy-append list
 375 INSTANCE: lazy-from-by list
 376 INSTANCE: lazy-zip list
 377 INSTANCE: lazy-while list
 378 INSTANCE: lazy-until list
 379 INSTANCE: lazy-filter list