basis/locals/locals.factor

   1 ! Copyright (C) 2007, 2008 Slava Pestov, Eduardo Cavazos.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel namespaces make sequences sequences.private assocs
   4 math vectors strings classes.tuple generalizations parser words
   5 quotations debugger macros arrays macros splitting combinators
   6 prettyprint.backend definitions prettyprint hashtables
   7 prettyprint.sections sets sequences.private effects
   8 effects.parser generic generic.parser compiler.units accessors
   9 locals.backend memoize macros.expander lexer classes
  10 stack-checker.known-words ;
  11 IN: locals
  12
  13 ! Inspired by
  14 ! http://cat-language.googlecode.com/svn/trunk/CatPointFreeForm.cs
  15
  16 <PRIVATE
  17
  18 TUPLE: lambda vars body ;
  19
  20 C: <lambda> lambda
  21
  22 TUPLE: binding-form bindings body ;
  23
  24 TUPLE: let < binding-form ;
  25
  26 C: <let> let
  27
  28 TUPLE: let* < binding-form ;
  29
  30 C: <let*> let*
  31
  32 TUPLE: wlet < binding-form ;
  33
  34 C: <wlet> wlet
  35
  36 M: lambda expand-macros clone [ expand-macros ] change-body ;
  37
  38 M: binding-form expand-macros
  39     clone
  40         [ [ expand-macros ] assoc-map ] change-bindings
  41         [ expand-macros ] change-body ;
  42
  43 PREDICATE: local < word "local?" word-prop ;
  44
  45 : <local> ( name -- word )
  46     #! Create a local variable identifier
  47     f <word>
  48     dup t "local?" set-word-prop
  49     dup { } { object } define-primitive ;
  50
  51 PREDICATE: local-word < word "local-word?" word-prop ;
  52
  53 : <local-word> ( name -- word )
  54     f <word> dup t "local-word?" set-word-prop ;
  55
  56 PREDICATE: local-reader < word "local-reader?" word-prop ;
  57
  58 : <local-reader> ( name -- word )
  59     f <word>
  60     dup t "local-reader?" set-word-prop
  61     dup { } { object } define-primitive ;
  62
  63 PREDICATE: local-writer < word "local-writer?" word-prop ;
  64
  65 : <local-writer> ( reader -- word )
  66     dup name>> "!" append f <word> {
  67         [ nip { object } { } define-primitive ]
  68         [ nip t "local-writer?" set-word-prop ]
  69         [ swap "local-reader" set-word-prop ]
  70         [ "local-writer" set-word-prop ]
  71         [ nip ]
  72     } 2cleave ;
  73
  74 TUPLE: quote local ;
  75
  76 C: <quote> quote
  77
  78 : local-index ( obj args -- n )
  79     [ dup quote? [ local>> ] when eq? ] with find drop ;
  80
  81 : read-local-quot ( obj args -- quot )
  82     local-index 1+ [ get-local ] curry ;
  83
  84 : localize-writer ( obj args -- quot )
  85     >r "local-reader" word-prop r>
  86     read-local-quot [ set-local-value ] append ;
  87
  88 : localize ( obj args -- quot )
  89     {
  90         { [ over local? ]        [ read-local-quot ] }
  91         { [ over quote? ]        [ >r local>> r> read-local-quot ] }
  92         { [ over local-word? ]   [ read-local-quot [ call ] append ] }
  93         { [ over local-reader? ] [ read-local-quot [ local-value ] append ] }
  94         { [ over local-writer? ] [ localize-writer ] }
  95         { [ over \ lambda eq? ]  [ 2drop [ ] ] }
  96         { [ t ]                  [ drop 1quotation ] }
  97     } cond ;
  98
  99 UNION: special local quote local-word local-reader local-writer ;
 100
 101 : load-locals-quot ( args -- quot )
 102     [
 103         [ ]
 104     ] [
 105         dup [ local-reader? ] contains? [
 106             <reversed> [
 107                 local-reader? [ 1array >r ] [ >r ] ?
 108             ] map concat
 109         ] [
 110             length [ load-locals ] curry >quotation
 111         ] if
 112     ] if-empty ;
 113
 114 : drop-locals-quot ( args -- quot )
 115     [ [ ] ] [ length [ drop-locals ] curry ] if-empty ;
 116
 117 : point-free-body ( quot args -- newquot )
 118     >r but-last-slice r> [ localize ] curry map concat ;
 119
 120 : point-free-end ( quot args -- newquot )
 121     over peek special?
 122     [ dup drop-locals-quot >r >r peek r> localize r> append ]
 123     [ dup drop-locals-quot nip swap peek suffix ]
 124     if ;
 125
 126 : (point-free) ( quot args -- newquot )
 127     [ nip load-locals-quot ]
 128     [ point-free-body ]
 129     [ point-free-end ]
 130     2tri 3append >quotation ;
 131
 132 : point-free ( quot args -- newquot )
 133     over empty?
 134     [ nip length \ drop <repetition> >quotation ]
 135     [ (point-free) ] if ;
 136
 137 UNION: lexical local local-reader local-writer local-word ;
 138
 139 GENERIC: free-vars* ( form -- )
 140
 141 : free-vars ( form -- vars )
 142     [ free-vars* ] { } make prune ;
 143
 144 : add-if-free ( object -- )
 145   {
 146       { [ dup local-writer? ] [ "local-reader" word-prop , ] }
 147       { [ dup lexical? ]      [ , ] }
 148       { [ dup quote? ]        [ local>> , ] }
 149       { [ t ]                 [ free-vars* ] }
 150   } cond ;
 151
 152 M: object free-vars* drop ;
 153
 154 M: quotation free-vars* [ add-if-free ] each ;
 155
 156 M: lambda free-vars*
 157     [ vars>> ] [ body>> ] bi free-vars swap diff % ;
 158
 159 GENERIC: lambda-rewrite* ( obj -- )
 160
 161 GENERIC: local-rewrite* ( obj -- )
 162
 163 : lambda-rewrite ( form -- form' )
 164     expand-macros
 165     [ local-rewrite* ] [ ] make
 166     [ [ lambda-rewrite* ] each ] [ ] make ;
 167
 168 UNION: block callable lambda ;
 169
 170 GENERIC: block-vars ( block -- seq )
 171
 172 GENERIC: block-body ( block -- quot )
 173
 174 M: callable block-vars drop { } ;
 175
 176 M: callable block-body ;
 177
 178 M: callable local-rewrite*
 179     [ [ local-rewrite* ] each ] [ ] make , ;
 180
 181 M: lambda block-vars vars>> ;
 182
 183 M: lambda block-body body>> ;
 184
 185 M: lambda local-rewrite*
 186     [ vars>> ] [ body>> ] bi
 187     [ [ local-rewrite* ] each ] [ ] make <lambda> , ;
 188
 189 M: block lambda-rewrite*
 190     #! Turn free variables into bound variables, curry them
 191     #! onto the body
 192     dup free-vars [ <quote> ] map dup % [
 193         over block-vars prepend
 194         swap block-body [ [ lambda-rewrite* ] each ] [ ] make
 195         swap point-free ,
 196     ] keep length \ curry <repetition> % ;
 197
 198 GENERIC: rewrite-element ( obj -- )
 199
 200 : rewrite-elements ( seq -- )
 201     [ rewrite-element ] each ;
 202
 203 : rewrite-sequence ( seq -- )
 204     [ rewrite-elements ] [ length , ] [ , ] tri \ nsequence , ;
 205
 206 M: array rewrite-element rewrite-sequence ;
 207
 208 M: vector rewrite-element rewrite-sequence ;
 209
 210 M: hashtable rewrite-element >alist rewrite-sequence \ >hashtable , ;
 211
 212 M: tuple rewrite-element
 213     [ tuple-slots rewrite-elements ] [ class , ] bi \ boa , ;
 214
 215 M: local rewrite-element , ;
 216
 217 M: word rewrite-element literalize , ;
 218
 219 M: object rewrite-element , ;
 220
 221 M: array local-rewrite* rewrite-element ;
 222
 223 M: vector local-rewrite* rewrite-element ;
 224
 225 M: tuple local-rewrite* rewrite-element ;
 226
 227 M: hashtable local-rewrite* rewrite-element ;
 228
 229 M: object lambda-rewrite* , ;
 230
 231 M: object local-rewrite* , ;
 232
 233 : make-local ( name -- word )
 234     "!" ?tail [
 235         <local-reader>
 236         dup <local-writer> dup name>> set
 237     ] [ <local> ] if
 238     dup dup name>> set ;
 239
 240 : make-locals ( seq -- words assoc )
 241     [ [ make-local ] map ] H{ } make-assoc ;
 242
 243 : make-local-word ( name -- word )
 244     <local-word> dup dup name>> set ;
 245
 246 : push-locals ( assoc -- )
 247     use get push ;
 248
 249 : pop-locals ( assoc -- )
 250     use get delete ;
 251
 252 SYMBOL: in-lambda?
 253
 254 : (parse-lambda) ( assoc end -- quot )
 255     t in-lambda? [ parse-until ] with-variable
 256     >quotation swap pop-locals ;
 257
 258 : parse-lambda ( -- lambda )
 259     "|" parse-tokens make-locals dup push-locals
 260     \ ] (parse-lambda) <lambda> ;
 261
 262 : parse-binding ( -- pair/f )
 263     scan dup "|" = [
 264         drop f
 265     ] [
 266         scan {
 267             { "[" [ \ ] parse-until >quotation ] }
 268             { "[|" [ parse-lambda ] }
 269         } case 2array
 270     ] if ;
 271
 272 : (parse-bindings) ( -- )
 273     parse-binding [
 274         first2 >r make-local r> 2array ,
 275         (parse-bindings)
 276     ] when* ;
 277
 278 : parse-bindings ( -- bindings vars )
 279     [
 280         [ (parse-bindings) ] H{ } make-assoc
 281         dup push-locals
 282     ] { } make swap ;
 283
 284 : parse-bindings* ( -- words assoc )
 285     [
 286         [
 287             namespace push-locals
 288
 289             (parse-bindings)
 290         ] { } make-assoc
 291     ] { } make swap ;
 292
 293 : (parse-wbindings) ( -- )
 294     parse-binding [
 295         first2 >r make-local-word r> 2array ,
 296         (parse-wbindings)
 297     ] when* ;
 298
 299 : parse-wbindings ( -- bindings vars )
 300     [
 301         [ (parse-wbindings) ] H{ } make-assoc
 302         dup push-locals
 303     ] { } make swap ;
 304
 305 : let-rewrite ( body bindings -- )
 306     <reversed> [
 307         >r 1array r> spin <lambda> [ call ] curry compose
 308     ] assoc-each local-rewrite* \ call , ;
 309
 310 M: let local-rewrite*
 311     [ body>> ] [ bindings>> ] bi let-rewrite ;
 312
 313 M: let* local-rewrite*
 314     [ body>> ] [ bindings>> ] bi let-rewrite ;
 315
 316 M: wlet local-rewrite*
 317     [ body>> ] [ bindings>> ] bi
 318     [ [ ] curry ] assoc-map
 319     let-rewrite ;
 320
 321 : parse-locals ( -- vars assoc )
 322     ")" parse-effect
 323     word [ over "declared-effect" set-word-prop ] when*
 324     in>> [ dup pair? [ first ] when ] map make-locals dup push-locals ;
 325
 326 : parse-locals-definition ( word -- word quot )
 327     scan "(" assert= parse-locals \ ; (parse-lambda) <lambda>
 328     2dup "lambda" set-word-prop
 329     lambda-rewrite first ;
 330
 331 : (::) ( -- word def ) CREATE-WORD parse-locals-definition ;
 332
 333 : (M::) ( -- word def )
 334     CREATE-METHOD
 335     [ parse-locals-definition ] with-method-definition ;
 336
 337 : parsed-lambda ( accum form -- accum )
 338     in-lambda? get [ parsed ] [ lambda-rewrite over push-all ] if ;
 339
 340 PRIVATE>
 341
 342 : [| parse-lambda parsed-lambda ; parsing
 343
 344 : [let
 345     scan "|" assert= parse-bindings
 346     \ ] (parse-lambda) <let> parsed-lambda ; parsing
 347
 348 : [let*
 349     scan "|" assert= parse-bindings*
 350     \ ] (parse-lambda) <let*> parsed-lambda ; parsing
 351
 352 : [wlet
 353     scan "|" assert= parse-wbindings
 354     \ ] (parse-lambda) <wlet> parsed-lambda ; parsing
 355
 356 : :: (::) define ; parsing
 357
 358 : M:: (M::) define ; parsing
 359
 360 : MACRO:: (::) define-macro ; parsing
 361
 362 : MEMO:: (::) define-memoized ; parsing
 363
 364 <PRIVATE
 365
 366 ! Pretty-printing locals
 367 SYMBOL: |
 368
 369 : pprint-var ( var -- )
 370     #! Prettyprint a read/write local as its writer, just like
 371     #! in the input syntax: [| x! | ... x 3 + x! ]
 372     dup local-reader? [
 373         "local-writer" word-prop
 374     ] when pprint-word ;
 375
 376 : pprint-vars ( vars -- ) [ pprint-var ] each ;
 377
 378 M: lambda pprint*
 379     <flow
 380     \ [| pprint-word
 381     dup vars>> pprint-vars
 382     \ | pprint-word
 383     f <inset body>> pprint-elements block>
 384     \ ] pprint-word
 385     block> ;
 386
 387 : pprint-let ( let word -- )
 388     pprint-word
 389     [ body>> ] [ bindings>> ] bi
 390     \ | pprint-word
 391     t <inset
 392     <block
 393     [ <block >r pprint-var r> pprint* block> ] assoc-each
 394     block>
 395     \ | pprint-word
 396     <block pprint-elements block>
 397     block>
 398     \ ] pprint-word ;
 399
 400 M: let pprint* \ [let pprint-let ;
 401
 402 M: wlet pprint* \ [wlet pprint-let ;
 403
 404 M: let* pprint* \ [let* pprint-let ;
 405
 406 PREDICATE: lambda-word < word "lambda" word-prop >boolean ;
 407
 408 M: lambda-word definer drop \ :: \ ; ;
 409
 410 M: lambda-word definition
 411     "lambda" word-prop body>> ;
 412
 413 M: lambda-word reset-word
 414     [ call-next-method ] [ f "lambda" set-word-prop ] bi ;
 415
 416 INTERSECTION: lambda-macro macro lambda-word ;
 417
 418 M: lambda-macro definer drop \ MACRO:: \ ; ;
 419
 420 M: lambda-macro definition
 421     "lambda" word-prop body>> ;
 422
 423 M: lambda-macro reset-word
 424     [ f "lambda" set-word-prop ] [ call-next-method ] bi ;
 425
 426 INTERSECTION: lambda-method method-body lambda-word ;
 427
 428 M: lambda-method definer drop \ M:: \ ; ;
 429
 430 M: lambda-method definition
 431     "lambda" word-prop body>> ;
 432
 433 M: lambda-method reset-word
 434     [ f "lambda" set-word-prop ] [ call-next-method ] bi ;
 435
 436 INTERSECTION: lambda-memoized memoized lambda-word ;
 437
 438 M: lambda-memoized definer drop \ MEMO:: \ ; ;
 439
 440 M: lambda-memoized definition
 441     "lambda" word-prop body>> ;
 442
 443 M: lambda-memoized reset-word
 444     [ f "lambda" set-word-prop ] [ call-next-method ] bi ;
 445
 446 : method-stack-effect ( method -- effect )
 447     dup "lambda" word-prop vars>>
 448     swap "method-generic" word-prop stack-effect
 449     dup [ out>> ] when
 450     <effect> ;
 451
 452 M: lambda-method synopsis*
 453     dup dup dup definer.
 454     "method-class" word-prop pprint-word
 455     "method-generic" word-prop pprint-word
 456     method-stack-effect effect>string comment. ;
 457
 458 PRIVATE>