basis/logging/server/server.factor

   1 ! Copyright (C) 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: assocs calendar calendar.format combinators
   4 concurrency.messaging continuations debugger destructors init io
   5 io.directories io.encodings.utf8 io.files io.pathnames kernel
   6 locals math math.parser ranges namespaces sequences
   7 strings threads ;
   8 IN: logging.server
   9
  10 : log-root ( -- string )
  11     \ log-root get-global [ "logs" resource-path ] unless* ;
  12
  13 : log-path ( service -- path )
  14     log-root prepend-path ;
  15
  16 : log# ( path n -- path' )
  17     number>string ".log" append append-path ;
  18
  19 SYMBOL: log-files
  20
  21 : open-log-stream ( service -- stream )
  22     log-path
  23     [ make-directories ]
  24     [ 1 log# utf8 <file-appender> ] bi ;
  25
  26 : log-stream ( service -- stream )
  27     log-files get [ open-log-stream ] cache ;
  28
  29 : close-log-streams ( -- )
  30     log-files get [ values dispose-each ] [ clear-assoc ] bi ;
  31
  32 :: with-log-root ( path quot -- )
  33     [ close-log-streams path \ log-root set-global quot call ]
  34     \ log-root get-global
  35     [ \ log-root set-global close-log-streams ] curry
  36     finally ; inline
  37
  38 : timestamp-header. ( -- )
  39     "[" write now write-rfc3339 "] " write ;
  40
  41 : multiline-header ( -- str ) 20 CHAR: - <string> ; foldable
  42
  43 : multiline-header. ( -- )
  44     "[" write multiline-header write "] " write ;
  45
  46 :: write-message ( msg word-name level -- )
  47     msg harvest [
  48         timestamp-header.
  49         [ multiline-header. ]
  50         [ level write bl word-name write ": " write print ]
  51         interleave
  52     ] unless-empty ;
  53
  54 : (log-message) ( msg -- )
  55     ! msg: { msg word-name level service }
  56     first4 log-stream [ write-message flush ] with-output-stream* ;
  57
  58 : try-dispose ( obj -- )
  59     [ dispose ] curry [ error. ] recover ;
  60
  61 : close-log ( service -- )
  62     log-files get delete-at*
  63     [ try-dispose ] [ drop ] if ;
  64
  65 : (close-logs) ( -- )
  66     log-files get
  67     [ values [ try-dispose ] each ] [ clear-assoc ] bi ;
  68
  69 CONSTANT: keep-logs 10
  70
  71 : delete-oldest ( service -- )
  72     keep-logs log# ?delete-file ;
  73
  74 : ?move-file ( old new -- )
  75     over file-exists? [ move-file ] [ 2drop ] if ;
  76
  77 : advance-log ( path n -- )
  78     [ 1 - log# ] 2keep log# ?move-file ;
  79
  80 : rotate-log ( service -- )
  81     [ close-log ]
  82     [
  83         log-path
  84         [ delete-oldest ]
  85         [ keep-logs 1 [a..b] [ advance-log ] with each ] bi
  86     ] bi ;
  87
  88 : (rotate-logs) ( -- )
  89     (close-logs)
  90     log-root directory-files [ rotate-log ] each ;
  91
  92 : log-server-loop ( -- )
  93     receive unclip {
  94         { "log-message" [ (log-message) ] }
  95         { "rotate-logs" [ drop (rotate-logs) ] }
  96         { "close-logs" [ drop (close-logs) ] }
  97     } case log-server-loop ;
  98
  99 : log-server ( -- )
 100     [
 101         init-namespaces
 102         [ log-server-loop ]
 103         [ error. (close-logs) ]
 104         recover t
 105     ]
 106     "Log server" spawn-server
 107     "log-server" set-global ;
 108
 109 [
 110     H{ } clone log-files set-global
 111     log-server
 112 ] "logging" add-startup-hook