basis/macros/macros.factor

   1 ! Copyright (C) 2007, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: parser kernel sequences words effects combinators assocs
   4 definitions quotations namespaces memoize accessors
   5 compiler.units ;
   6 IN: macros
   7
   8 <PRIVATE
   9
  10 : real-macro-effect ( effect -- effect' )
  11     in>> { "quot" } <effect> ;
  12
  13 PRIVATE>
  14
  15 : define-macro ( word definition effect -- )
  16     real-macro-effect {
  17         [ [ memoize-quot [ call ] append ] keep define-declared ]
  18         [ drop "macro" set-word-prop ]
  19         [ 2drop changed-effect ]
  20     } 3cleave ;
  21
  22 SYNTAX: MACRO: (:) define-macro ;
  23
  24 PREDICATE: macro < word "macro" word-prop >boolean ;
  25
  26 M: macro make-inline cannot-be-inline ;
  27
  28 M: macro definer drop \ MACRO: \ ; ;
  29
  30 M: macro definition "macro" word-prop ;
  31
  32 M: macro reset-word
  33     [ call-next-method ] [ f "macro" set-word-prop ] bi ;
  34
  35 M: macro always-bump-effect-counter? drop t ;