basis/math/bitwise/bitwise.factor

   1 ! Copyright (C) 2007, 2008 Slava Pestov, Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: arrays assocs combinators combinators.smart fry kernel
   4 macros math math.bits sequences sequences.private words
   5 byte-arrays alien alien.c-types specialized-arrays ;
   6 SPECIALIZED-ARRAY: uchar
   7 IN: math.bitwise
   8
   9 ! utilities
  10 : clear-bit ( x n -- y ) 2^ bitnot bitand ; inline
  11 : set-bit ( x n -- y ) 2^ bitor ; inline
  12 : bit-clear? ( x n -- ? ) 2^ bitand 0 = ; inline
  13 : unmask ( x n -- ? ) bitnot bitand ; inline
  14 : unmask? ( x n -- ? ) unmask 0 > ; inline
  15 : mask ( x n -- ? ) bitand ; inline
  16 : mask? ( x n -- ? ) mask 0 > ; inline
  17 : wrap ( m n -- m' ) 1 - bitand ; inline
  18 : bits ( m n -- m' ) 2^ wrap ; inline
  19 : mask-bit ( m n -- m' ) 2^ mask ; inline
  20 : on-bits ( m -- n ) 2^ 1 - ; inline
  21 : toggle-bit ( m n -- m' ) 2^ bitxor ; inline
  22 : >signed ( x n -- y ) 2dup neg 1 + shift 1 = [ 2^ - ] [ drop ] if ;
  23 : >odd ( m -- n ) 0 set-bit ; foldable
  24 : >even ( m -- n ) 0 clear-bit ; foldable
  25 : next-even ( m -- n ) >even 2 + ; foldable
  26 : next-odd ( m -- n ) dup even? [ 1 + ] [ 2 + ] if ; foldable
  27 : shift-mod ( m s w -- n ) [ shift ] dip 2^ wrap ; inline
  28
  29 : bitroll ( x s w -- y )
  30     [ wrap ] keep
  31     [ shift-mod ] [ [ - ] keep shift-mod ] 3bi bitor ; inline
  32
  33 : bitroll-32 ( m s -- n ) 32 bitroll ; inline
  34
  35 : bitroll-64 ( m s -- n ) 64 bitroll ; inline
  36
  37 ! 32-bit arithmetic
  38 : w+ ( x y -- z ) + 32 bits ; inline
  39 : w- ( x y -- z ) - 32 bits ; inline
  40 : w* ( x y -- z ) * 32 bits ; inline
  41
  42 ! 64-bit arithmetic
  43 : W+ ( x y -- z ) + 64 bits ; inline
  44 : W- ( x y -- z ) - 64 bits ; inline
  45 : W* ( x y -- z ) * 64 bits ; inline
  46
  47 ! flags
  48 MACRO: flags ( values -- )
  49     [ 0 ] [ [ ?execute bitor ] curry compose ] reduce ;
  50
  51 : symbols>flags ( symbols assoc -- flag-bits )
  52     [ at ] curry map
  53     0 [ bitor ] reduce ;
  54
  55 ! bitfield
  56 <PRIVATE
  57
  58 GENERIC: (bitfield-quot) ( spec -- quot )
  59
  60 M: integer (bitfield-quot) ( spec -- quot )
  61     [ swapd shift bitor ] curry ;
  62
  63 M: pair (bitfield-quot) ( spec -- quot )
  64     first2 over word? [ [ swapd execute ] dip ] [ ] ?
  65     [ shift bitor ] append 2curry ;
  66
  67 PRIVATE>
  68
  69 MACRO: bitfield ( bitspec -- )
  70     [ 0 ] [ (bitfield-quot) compose ] reduce ;
  71
  72 ! bit-count
  73 <PRIVATE
  74
  75 DEFER: byte-bit-count
  76
  77 <<
  78
  79 \ byte-bit-count
  80 256 iota [
  81     8 <bits> 0 [ [ 1 + ] when ] reduce
  82 ] B{ } map-as '[ HEX: ff bitand _ nth-unsafe ]
  83 (( byte -- table )) define-declared
  84
  85 \ byte-bit-count make-inline
  86
  87 >>
  88
  89 GENERIC: (bit-count) ( x -- n )
  90
  91 M: fixnum (bit-count)
  92     0 swap [
  93         dup 0 >
  94     ] [
  95         [ 8 bits byte-bit-count ] [ -8 shift ] bi
  96         [ + ] dip
  97     ] while drop ;
  98
  99 M: bignum (bit-count)
 100     dup 0 = [ drop 0 ] [
 101         [ byte-bit-count ] [ -8 shift (bit-count) ] bi +
 102     ] if ;
 103
 104 : byte-array-bit-count ( byte-array -- n )
 105     0 [ byte-bit-count + ] reduce ; inline
 106
 107 PRIVATE>
 108
 109 ERROR: invalid-bit-count-target object ;
 110
 111 GENERIC: bit-count ( obj -- n )
 112
 113 M: integer bit-count
 114     dup 0 < [ invalid-bit-count-target ] when (bit-count) ; inline
 115
 116 M: byte-array bit-count
 117     byte-array-bit-count ;
 118
 119 M: object bit-count
 120     binary-object <direct-uchar-array> byte-array-bit-count ;
 121
 122 : even-parity? ( obj -- ? ) bit-count even? ;
 123
 124 : odd-parity? ( obj -- ? ) bit-count odd? ;