basis/math/bitwise/bitwise.factor

   1 ! Copyright (C) 2007, 2008 Slava Pestov, Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: arrays assocs combinators combinators.smart fry kernel
   4 macros math math.bits sequences sequences.private words
   5 byte-arrays alien alien.c-types specialized-arrays ;
   6 SPECIALIZED-ARRAY: uchar
   7 IN: math.bitwise
   8
   9 ! utilities
  10 : clear-bit ( x n -- y ) 2^ bitnot bitand ; inline
  11 : set-bit ( x n -- y ) 2^ bitor ; inline
  12 : bit-clear? ( x n -- ? ) 2^ bitand 0 = ; inline
  13 : unmask ( x n -- ? ) bitnot bitand ; inline
  14 : unmask? ( x n -- ? ) unmask 0 > ; inline
  15 : mask ( x n -- ? ) bitand ; inline
  16 : mask? ( x n -- ? ) mask 0 > ; inline
  17 : wrap ( m n -- m' ) 1 - bitand ; inline
  18 : bits ( m n -- m' ) 2^ wrap ; inline
  19 : mask-bit ( m n -- m' ) 2^ mask ; inline
  20 : on-bits ( n -- m ) 2^ 1 - ; inline
  21 : toggle-bit ( m n -- m' ) 2^ bitxor ; inline
  22
  23 : shift-mod ( n s w -- n )
  24     [ shift ] dip 2^ wrap ; inline
  25
  26 : bitroll ( x s w -- y )
  27     [ wrap ] keep
  28     [ shift-mod ] [ [ - ] keep shift-mod ] 3bi bitor ; inline
  29
  30 : bitroll-32 ( n s -- n' ) 32 bitroll ; inline
  31
  32 : bitroll-64 ( n s -- n' ) 64 bitroll ; inline
  33
  34 ! 32-bit arithmetic
  35 : w+ ( int int -- int ) + 32 bits ; inline
  36 : w- ( int int -- int ) - 32 bits ; inline
  37 : w* ( int int -- int ) * 32 bits ; inline
  38
  39 ! 64-bit arithmetic
  40 : W+ ( int int -- int ) + 64 bits ; inline
  41 : W- ( int int -- int ) - 64 bits ; inline
  42 : W* ( int int -- int ) * 64 bits ; inline
  43
  44 ! flags
  45 MACRO: flags ( values -- )
  46     [ 0 ] [ [ ?execute bitor ] curry compose ] reduce ;
  47
  48 : symbols>flags ( symbols assoc -- flag-bits )
  49     [ at ] curry map
  50     0 [ bitor ] reduce ;
  51
  52 ! bitfield
  53 <PRIVATE
  54
  55 GENERIC: (bitfield-quot) ( spec -- quot )
  56
  57 M: integer (bitfield-quot) ( spec -- quot )
  58     [ swapd shift bitor ] curry ;
  59
  60 M: pair (bitfield-quot) ( spec -- quot )
  61     first2 over word? [ [ swapd execute ] dip ] [ ] ?
  62     [ shift bitor ] append 2curry ;
  63
  64 PRIVATE>
  65
  66 MACRO: bitfield ( bitspec -- )
  67     [ 0 ] [ (bitfield-quot) compose ] reduce ;
  68
  69 ! bit-count
  70 <PRIVATE
  71
  72 DEFER: byte-bit-count
  73
  74 <<
  75
  76 \ byte-bit-count
  77 256 iota [
  78     8 <bits> 0 [ [ 1 + ] when ] reduce
  79 ] B{ } map-as '[ HEX: ff bitand _ nth-unsafe ]
  80 (( byte -- table )) define-declared
  81
  82 \ byte-bit-count make-inline
  83
  84 >>
  85
  86 GENERIC: (bit-count) ( x -- n )
  87
  88 M: fixnum (bit-count)
  89     0 swap [
  90         dup 0 >
  91     ] [
  92         [ 8 bits byte-bit-count ] [ -8 shift ] bi
  93         [ + ] dip
  94     ] while drop ;
  95
  96 M: bignum (bit-count)
  97     dup 0 = [ drop 0 ] [
  98         [ byte-bit-count ] [ -8 shift (bit-count) ] bi +
  99     ] if ;
 100
 101 : byte-array-bit-count ( byte-array -- n )
 102     0 [ byte-bit-count + ] reduce ;
 103
 104 PRIVATE>
 105
 106 ERROR: invalid-bit-count-target object ;
 107
 108 GENERIC: bit-count ( obj -- n )
 109
 110 M: integer bit-count
 111     dup 0 < [ invalid-bit-count-target ] when (bit-count) ; inline
 112
 113 M: byte-array bit-count
 114     byte-array-bit-count ;
 115
 116 M: object bit-count
 117     [ >c-ptr ] [ byte-length ] bi <direct-uchar-array>
 118     byte-array-bit-count ;
 119
 120 : >signed ( x n -- y )
 121     2dup neg 1 + shift 1 = [ 2^ - ] [ drop ] if ;
 122
 123 : >odd ( n -- int ) 0 set-bit ; foldable
 124
 125 : >even ( n -- int ) 0 clear-bit ; foldable
 126
 127 : next-even ( m -- n ) >even 2 + ; foldable
 128
 129 : next-odd ( m -- n ) dup even? [ 1 + ] [ 2 + ] if ; foldable
 130
 131 : even-parity? ( obj -- ? ) bit-count even? ;
 132
 133 : odd-parity? ( obj -- ? ) bit-count odd? ;