basis/math/bitwise/bitwise.factor

   1 ! Copyright (C) 2007, 2008 Slava Pestov, Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: arrays assocs combinators combinators.smart fry kernel
   4 macros math math.bits sequences sequences.private words
   5 byte-arrays alien alien.c-types alien.data specialized-arrays ;
   6 SPECIALIZED-ARRAY: uchar
   7 IN: math.bitwise
   8
   9 ! utilities
  10 : clear-bit ( x n -- y ) 2^ bitnot bitand ; inline
  11 : set-bit ( x n -- y ) 2^ bitor ; inline
  12 : bit-clear? ( x n -- ? ) 2^ bitand 0 = ; inline
  13 : unmask ( x n -- ? ) bitnot bitand ; inline
  14 : unmask? ( x n -- ? ) unmask 0 > ; inline
  15 : mask ( x n -- ? ) bitand ; inline
  16 : mask? ( x n -- ? ) mask 0 > ; inline
  17 : wrap ( m n -- m' ) 1 - bitand ; inline
  18 : on-bits ( m -- n ) 2^ 1 - ; inline
  19 : bits ( m n -- m' ) on-bits mask ; inline
  20 : mask-bit ( m n -- m' ) 2^ mask ; inline
  21 : toggle-bit ( m n -- m' ) 2^ bitxor ; inline
  22 : >signed ( x n -- y )
  23     [ bits ] keep 2dup neg 1 + shift 1 = [ 2^ - ] [ drop ] if ;
  24 : >odd ( m -- n ) 0 set-bit ; foldable
  25 : >even ( m -- n ) 0 clear-bit ; foldable
  26 : next-even ( m -- n ) >even 2 + ; foldable
  27 : next-odd ( m -- n ) dup even? [ 1 + ] [ 2 + ] if ; foldable
  28 : shift-mod ( m s w -- n ) [ shift ] dip 2^ wrap ; inline
  29
  30 : bitroll ( x s w -- y )
  31     [ wrap ] keep
  32     [ shift-mod ] [ [ - ] keep shift-mod ] 3bi bitor ; inline
  33
  34 : bitroll-32 ( m s -- n ) 32 bitroll ; inline
  35
  36 : bitroll-64 ( m s -- n ) 64 bitroll ; inline
  37
  38 ! 32-bit arithmetic
  39 : w+ ( x y -- z ) + 32 bits ; inline
  40 : w- ( x y -- z ) - 32 bits ; inline
  41 : w* ( x y -- z ) * 32 bits ; inline
  42
  43 ! 64-bit arithmetic
  44 : W+ ( x y -- z ) + 64 bits ; inline
  45 : W- ( x y -- z ) - 64 bits ; inline
  46 : W* ( x y -- z ) * 64 bits ; inline
  47
  48 : symbols>flags ( symbols assoc -- flag-bits )
  49     [ at ] curry map
  50     0 [ bitor ] reduce ;
  51
  52 ! bitfield
  53 <PRIVATE
  54
  55 GENERIC: (bitfield-quot) ( spec -- quot )
  56
  57 M: integer (bitfield-quot) ( spec -- quot )
  58     [ swapd shift bitor ] curry ;
  59
  60 M: pair (bitfield-quot) ( spec -- quot )
  61     first2 over word? [ [ swapd execute ] dip ] [ ] ?
  62     [ shift bitor ] append 2curry ;
  63
  64 PRIVATE>
  65
  66 MACRO: bitfield ( bitspec -- )
  67     [ 0 ] [ (bitfield-quot) compose ] reduce ;
  68
  69 ! bit-count
  70 <PRIVATE
  71
  72 DEFER: byte-bit-count
  73
  74 <<
  75
  76 \ byte-bit-count
  77 256 iota [
  78     8 <bits> 0 [ [ 1 + ] when ] reduce
  79 ] B{ } map-as '[ HEX: ff bitand _ nth-unsafe ]
  80 ( byte -- table ) define-declared
  81
  82 \ byte-bit-count make-inline
  83
  84 >>
  85
  86 GENERIC: (bit-count) ( x -- n )
  87
  88 : fixnum-bit-count ( x -- n )
  89     0 swap [
  90         dup 0 >
  91     ] [
  92         [ 8 bits byte-bit-count ] [ -8 shift ] bi
  93         [ + ] dip
  94     ] while drop ;
  95
  96 M: fixnum (bit-count)
  97     fixnum-bit-count ; inline
  98
  99 M: bignum (bit-count)
 100     dup 0 = [ drop 0 ] [
 101         [ byte-bit-count ] [ -8 shift (bit-count) ] bi +
 102     ] if ;
 103
 104 : byte-array-bit-count ( byte-array -- n )
 105     0 [ byte-bit-count + ] reduce ; inline
 106
 107 PRIVATE>
 108
 109 ERROR: invalid-bit-count-target object ;
 110
 111 GENERIC: bit-count ( obj -- n )
 112
 113 M: integer bit-count
 114     dup 0 < [ invalid-bit-count-target ] when (bit-count) ; inline
 115
 116 M: byte-array bit-count
 117     byte-array-bit-count ;
 118
 119 M: object bit-count
 120     binary-object uchar <c-direct-array> byte-array-bit-count ;
 121
 122 : even-parity? ( obj -- ? ) bit-count even? ;
 123
 124 : odd-parity? ( obj -- ? ) bit-count odd? ;