basis/math/bitwise/bitwise.factor

   1 ! Copyright (C) 2007, 2008 Slava Pestov, Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: alien alien.c-types alien.data arrays assocs byte-arrays
   4 combinators combinators.short-circuit fry kernel kernel.private
   5 layouts macros math math.bits sequences sequences.private
   6 specialized-arrays words ;
   7 SPECIALIZED-ARRAY: uchar
   8 IN: math.bitwise
   9
  10 ! utilities
  11 : clear-bit ( x n -- y ) 2^ bitnot bitand ; inline
  12 : set-bit ( x n -- y ) 2^ bitor ; inline
  13 : unmask ( x n -- y ) bitnot bitand ; inline
  14 : unmask? ( x n -- ? ) unmask zero? not ; inline
  15 : mask ( x n -- y ) bitand ; inline
  16 : mask? ( x n -- ? ) [ mask ] [ = ] bi ; inline
  17 : wrap ( m n -- m' ) 1 - bitand ; inline
  18 : on-bits ( m -- n ) dup 0 <= [ drop 0 ] [ 2^ 1 - ] if ; inline
  19 : bits ( m n -- m' ) on-bits mask ; inline
  20 : mask-bit ( m n -- m' ) 2^ mask ; inline
  21 : toggle-bit ( m n -- m' ) 2^ bitxor ; inline
  22 : >signed ( x n -- y )
  23     [ bits ] keep 2dup 1 - bit? [ 2^ - ] [ drop ] if ; inline
  24 : >odd ( m -- n ) 0 set-bit ; foldable
  25 : >even ( m -- n ) 0 clear-bit ; foldable
  26 : next-even ( m -- n ) >even 2 + ; foldable
  27 : next-odd ( m -- n ) dup even? [ 1 + ] [ 2 + ] if ; foldable
  28 : shift-mod ( m s w -- n ) [ shift ] dip 2^ wrap ; inline
  29
  30 ERROR: bit-range-error x high low ;
  31 : bit-range ( x high low -- y )
  32     2dup { [ nip 0 < ] [ < ] } 2|| [ throw-bit-range-error ] when
  33     [ nip neg shift ] [ - 1 + ] 2bi bits ; inline
  34
  35 : bitroll ( x s w -- y )
  36     [ wrap ] keep
  37     [ shift-mod ] [ [ - ] keep shift-mod ] 3bi bitor ; inline
  38
  39 : bitroll-32 ( m s -- n ) 32 bitroll ; inline
  40
  41 : bitroll-64 ( m s -- n ) 64 bitroll ; inline
  42
  43 ! 32-bit arithmetic
  44 : w+ ( x y -- z ) + 32 bits ; inline
  45 : w- ( x y -- z ) - 32 bits ; inline
  46 : w* ( x y -- z ) * 32 bits ; inline
  47
  48 ! 64-bit arithmetic
  49 : W+ ( x y -- z ) + 64 bits ; inline
  50 : W- ( x y -- z ) - 64 bits ; inline
  51 : W* ( x y -- z ) * 64 bits ; inline
  52
  53 : symbols>flags ( symbols assoc -- flag-bits )
  54     '[ _ at ] map 0 [ bitor ] reduce ;
  55
  56 ! bitfield
  57 <PRIVATE
  58
  59 GENERIC: (bitfield-quot) ( spec -- quot )
  60
  61 M: integer (bitfield-quot) ( spec -- quot )
  62     '[ _ shift ] ;
  63
  64 M: pair (bitfield-quot) ( spec -- quot )
  65     first2-unsafe over word? [
  66         '[ _ execute _ shift ]
  67     ] [
  68         '[ _ _ shift ]
  69     ] if ;
  70
  71 PRIVATE>
  72
  73 MACRO: bitfield ( bitspec -- quot )
  74     [ [ 0 ] ] [
  75         [ (bitfield-quot) ] [ '[ @ _ dip bitor ] ] map-reduce
  76     ] if-empty ;
  77
  78 ! bit-count
  79 <PRIVATE
  80
  81 DEFER: byte-bit-count
  82
  83 <<
  84
  85 \ byte-bit-count
  86 256 iota [
  87     8 <bits> 0 [ [ 1 + ] when ] reduce
  88 ] B{ } map-as '[ 0xff bitand _ nth-unsafe ]
  89 ( byte -- table ) define-declared
  90
  91 \ byte-bit-count make-inline
  92
  93 >>
  94
  95 GENERIC: (bit-count) ( x -- n )
  96
  97 : fixnum-bit-count ( x -- n )
  98     { fixnum } declare
  99     {
 100         [ byte-bit-count ]
 101         [ -8 shift byte-bit-count + ]
 102         [ -16 shift byte-bit-count + ]
 103         [ -24 shift byte-bit-count + ]
 104         [
 105             cell 8 = [
 106                 {
 107                     [ -32 shift byte-bit-count + ]
 108                     [ -40 shift byte-bit-count + ]
 109                     [ -48 shift byte-bit-count + ]
 110                     [ -56 shift byte-bit-count + ]
 111                 } cleave >fixnum
 112             ] [ drop ] if
 113         ]
 114     } cleave ;
 115
 116 M: fixnum (bit-count)
 117     fixnum-bit-count { fixnum } declare ; inline
 118
 119 M: bignum (bit-count)
 120     [ 0 ] [
 121         [ byte-bit-count ] [ -8 shift (bit-count) ] bi +
 122     ] if-zero ;
 123
 124 : byte-array-bit-count ( byte-array -- n )
 125     [ byte-bit-count ] map-sum ; inline
 126
 127 PRIVATE>
 128
 129 GENERIC: bit-count ( obj -- n )
 130
 131 M: integer bit-count
 132     dup 0 < [ non-negative-integer-expected ] when (bit-count) ; inline
 133
 134 M: byte-array bit-count
 135     byte-array-bit-count ;
 136
 137 M: object bit-count
 138     binary-object uchar <c-direct-array> byte-array-bit-count ;
 139
 140 : bit-length ( x -- n )
 141     dup 0 < [ non-negative-integer-expected ] [
 142         dup 1 > [ log2 1 + ] when
 143     ] if ;
 144
 145 : even-parity? ( obj -- ? ) bit-count even? ;
 146
 147 : odd-parity? ( obj -- ? ) bit-count odd? ;