basis/math/bitwise/bitwise.factor

   1 ! Copyright (C) 2007, 2008 Slava Pestov, Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: arrays assocs combinators combinators.smart fry kernel
   4 macros math math.bits sequences sequences.private words
   5 byte-arrays alien alien.c-types specialized-arrays ;
   6 SPECIALIZED-ARRAY: uchar
   7 IN: math.bitwise
   8
   9 ! utilities
  10 : clear-bit ( x n -- y ) 2^ bitnot bitand ; inline
  11 : set-bit ( x n -- y ) 2^ bitor ; inline
  12 : bit-clear? ( x n -- ? ) 2^ bitand 0 = ; inline
  13 : unmask ( x n -- ? ) bitnot bitand ; inline
  14 : unmask? ( x n -- ? ) unmask 0 > ; inline
  15 : mask ( x n -- ? ) bitand ; inline
  16 : mask? ( x n -- ? ) mask 0 > ; inline
  17 : wrap ( m n -- m' ) 1 - bitand ; inline
  18 : bits ( m n -- m' ) 2^ wrap ; inline
  19 : mask-bit ( m n -- m' ) 2^ mask ; inline
  20 : on-bits ( m -- n ) 2^ 1 - ; inline
  21 : toggle-bit ( m n -- m' ) 2^ bitxor ; inline
  22 : >signed ( x n -- y ) 2dup neg 1 + shift 1 = [ 2^ - ] [ drop ] if ;
  23 : >odd ( m -- n ) 0 set-bit ; foldable
  24 : >even ( m -- n ) 0 clear-bit ; foldable
  25 : next-even ( m -- n ) >even 2 + ; foldable
  26 : next-odd ( m -- n ) dup even? [ 1 + ] [ 2 + ] if ; foldable
  27 : shift-mod ( m s w -- n ) [ shift ] dip 2^ wrap ; inline
  28
  29 : bitroll ( x s w -- y )
  30     [ wrap ] keep
  31     [ shift-mod ] [ [ - ] keep shift-mod ] 3bi bitor ; inline
  32
  33 : bitroll-32 ( m s -- n ) 32 bitroll ; inline
  34
  35 : bitroll-64 ( m s -- n ) 64 bitroll ; inline
  36
  37 ! 32-bit arithmetic
  38 : w+ ( x y -- z ) + 32 bits ; inline
  39 : w- ( x y -- z ) - 32 bits ; inline
  40 : w* ( x y -- z ) * 32 bits ; inline
  41
  42 ! 64-bit arithmetic
  43 : W+ ( x y -- z ) + 64 bits ; inline
  44 : W- ( x y -- z ) - 64 bits ; inline
  45 : W* ( x y -- z ) * 64 bits ; inline
  46
  47 : symbols>flags ( symbols assoc -- flag-bits )
  48     [ at ] curry map
  49     0 [ bitor ] reduce ;
  50
  51 ! bitfield
  52 <PRIVATE
  53
  54 GENERIC: (bitfield-quot) ( spec -- quot )
  55
  56 M: integer (bitfield-quot) ( spec -- quot )
  57     [ swapd shift bitor ] curry ;
  58
  59 M: pair (bitfield-quot) ( spec -- quot )
  60     first2 over word? [ [ swapd execute ] dip ] [ ] ?
  61     [ shift bitor ] append 2curry ;
  62
  63 PRIVATE>
  64
  65 MACRO: bitfield ( bitspec -- )
  66     [ 0 ] [ (bitfield-quot) compose ] reduce ;
  67
  68 ! bit-count
  69 <PRIVATE
  70
  71 DEFER: byte-bit-count
  72
  73 <<
  74
  75 \ byte-bit-count
  76 256 iota [
  77     8 <bits> 0 [ [ 1 + ] when ] reduce
  78 ] B{ } map-as '[ HEX: ff bitand _ nth-unsafe ]
  79 (( byte -- table )) define-declared
  80
  81 \ byte-bit-count make-inline
  82
  83 >>
  84
  85 GENERIC: (bit-count) ( x -- n )
  86
  87 M: fixnum (bit-count)
  88     0 swap [
  89         dup 0 >
  90     ] [
  91         [ 8 bits byte-bit-count ] [ -8 shift ] bi
  92         [ + ] dip
  93     ] while drop ;
  94
  95 M: bignum (bit-count)
  96     dup 0 = [ drop 0 ] [
  97         [ byte-bit-count ] [ -8 shift (bit-count) ] bi +
  98     ] if ;
  99
 100 : byte-array-bit-count ( byte-array -- n )
 101     0 [ byte-bit-count + ] reduce ; inline
 102
 103 PRIVATE>
 104
 105 ERROR: invalid-bit-count-target object ;
 106
 107 GENERIC: bit-count ( obj -- n )
 108
 109 M: integer bit-count
 110     dup 0 < [ invalid-bit-count-target ] when (bit-count) ; inline
 111
 112 M: byte-array bit-count
 113     byte-array-bit-count ;
 114
 115 M: object bit-count
 116     binary-object <direct-uchar-array> byte-array-bit-count ;
 117
 118 : even-parity? ( obj -- ? ) bit-count even? ;
 119
 120 : odd-parity? ( obj -- ? ) bit-count odd? ;